sys-auth/rtkit: depend on acct-{user,group}/rtkit

Signed-off-by: Marek Szuba <marecki@gentoo.org>
Package-Manager: Portage-2.3.66, Repoman-2.3.11

diff --git a/sys-auth/rtkit/rtkit-0.11-r3.ebuild b/sys-auth/rtkit/rtkit-0.11-r3.ebuild
new file mode 100644 (file)
index 0000000..72a36d7
--- /dev/null
+++ b/sys-auth/rtkit/rtkit-0.11-r3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit eutils systemd autotools linux-info
+
+DESCRIPTION="Realtime Policy and Watchdog Daemon"
+HOMEPAGE="http://0pointer.de/blog/projects/rtkit"
+SRC_URI="http://0pointer.de/public/${P}.tar.xz"
+
+LICENSE="GPL-3 BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+IUSE=""
+
+RDEPEND="acct-group/rtkit
+       acct-user/rtkit
+       sys-apps/dbus
+       sys-auth/polkit
+       sys-libs/libcap
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+       # Fedora patches
+       "${FILESDIR}/${P}-polkit.patch"
+       "${FILESDIR}/${P}-gettime.patch"
+       "${FILESDIR}/${P}-controlgroup.patch"
+)
+
+pkg_pretend() {
+       if use kernel_linux; then
+               CONFIG_CHECK="~!RT_GROUP_SCHED"
+               ERROR_RT_GROUP_SCHED="CONFIG_RT_GROUP_SCHED is enabled. rtkit-daemon (or any other "
+               ERROR_RT_GROUP_SCHED+="real-time task) will not work unless run as root. Please consider "
+               ERROR_RT_GROUP_SCHED+="unsetting this option."
+               check_extra_config
+       fi
+}
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+}
+
+src_install() {
+       default
+
+       ./rtkit-daemon --introspect > org.freedesktop.RealtimeKit1.xml
+       insinto /usr/share/dbus-1/interfaces
+       doins org.freedesktop.RealtimeKit1.xml
+}