www-client/opera-beta: Version 63.0.3368.51

Package-Manager: Portage-2.3.73, Repoman-2.3.17
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index ea75f90d02d30f1f501cfbbe241ef59c0cc90119..40fc469142f120eda1eec2262c1df27ea35bd025 100644 (file)
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1 +1,2 @@
 DIST opera-beta_63.0.3368.33_amd64.deb 60993852 BLAKE2B ebc7ef2bc0281a24be4b67bed32078f20d15736a8030f17a7c42dfd7559b540076559287ba9a3bd613b33b2e3df766f1fc7e39b73af1655a7182571aab3b8944 SHA512 d50171df199f804fb5178ce7afc83b79413be528171837039b41b6f345277aa855ecc1b710ba4c4905a560b0f9e7efbc3ecf6351e90c332e04746c3879a7052e
+DIST opera-beta_63.0.3368.51_amd64.deb 61177834 BLAKE2B 7b31da9a59dbacfc4f98fd56ffc6f50c45e7c05677ade30ca0c9b83777090326b4bda83d1458da637f419045bd3a00b1caca012366395a5d9c9620e9d07adee5 SHA512 a6d8d45025fd2c985f8004c1327de3f29f50cee1f4b6976b157524230ea90aee9afc89e6522e677277df8c90ac6b08d81ae541705a458fa9d1702a8c0a669836

diff --git a/www-client/opera-beta/opera-beta-63.0.3368.51.ebuild b/www-client/opera-beta/opera-beta-63.0.3368.51.ebuild
new file mode 100644 (file)
index 0000000..59a8587
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-63.0.3368.51.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+       be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+       ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+       zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+       https://download1.operacdn.com/pub/
+       https://download2.operacdn.com/pub/
+       https://download3.operacdn.com/pub/
+       https://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+       "${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+       dev-libs/expat
+       dev-libs/glib:2
+       dev-libs/nspr
+       dev-libs/nss
+       gnome-base/gconf:2
+       media-libs/alsa-lib
+       media-libs/fontconfig
+       media-libs/freetype
+       net-misc/curl
+       net-print/cups
+       sys-apps/dbus
+       x11-libs/cairo
+       x11-libs/gdk-pixbuf
+       x11-libs/gtk+:3
+       x11-libs/libX11
+       x11-libs/libXScrnSaver
+       x11-libs/libXcomposite
+       x11-libs/libXcursor
+       x11-libs/libXdamage
+       x11-libs/libXext
+       x11-libs/libXfixes
+       x11-libs/libXi
+       x11-libs/libXrandr
+       x11-libs/libXrender
+       x11-libs/libXtst
+       x11-libs/libnotify
+       x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+pkg_setup() {
+       OPERA_HOME="usr/$(get_libdir)/${PN}"
+}
+
+src_unpack() {
+       unpack_deb ${A}
+}
+
+src_prepare() {
+       default
+
+       case ${ARCH} in
+               amd64)
+                       mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+                       rm -r usr/lib || die
+                       ;;
+               x86)
+                       mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+                       ;;
+       esac
+
+       mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+       gunzip usr/share/doc/${PF}/changelog.gz || die
+
+       rm usr/bin/${PN} || die
+
+       pushd "${OPERA_HOME}/localization" > /dev/null || die
+       chromium_remove_language_paks
+       popd > /dev/null || die
+
+       sed -i \
+               -e 's|^TargetEnvironment|X-&|g' \
+               usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+       mv * "${D}" || die
+       dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+       fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}
+
+pkg_postrm() {
+       xdg_desktop_database_update
+       xdg_icon_cache_update
+       xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+       xdg_desktop_database_update
+       xdg_icon_cache_update
+       xdg_mimeinfo_database_update
+}