media-sound/qjackctl: Fix configure w/ Qt 5.7, drop USE=qt5, EAPI 6

Fix DESCRIPTION length while at it to make repoman a bit happier.

Gentoo-bug: 595488

Package-Manager: portage-2.3.0
Closes: https://github.com/gentoo/gentoo/pull/2625

Signed-off-by: David Seifert <soap@gentoo.org>

diff --git a/media-sound/qjackctl/qjackctl-0.4.3-r1.ebuild b/media-sound/qjackctl/qjackctl-0.4.3-r1.ebuild
new file mode 100644 (file)
index 0000000..34b55a5
--- /dev/null
+++ b/media-sound/qjackctl/qjackctl-0.4.3-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit flag-o-matic qmake-utils
+
+DESCRIPTION="Qt GUI to control the JACK Audio Connection Kit and ALSA sequencer connections"
+HOMEPAGE="http://qjackctl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qjackctl/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="alsa dbus debug portaudio"
+
+RDEPEND="
+       dev-qt/qtcore:5
+       dev-qt/qtgui:5
+       dev-qt/qtwidgets:5
+       dev-qt/qtx11extras:5
+       dev-qt/qtxml:5
+       virtual/jack
+       alsa? ( media-libs/alsa-lib )
+       dbus? ( dev-qt/qtdbus:5 )
+       portaudio? ( media-libs/portaudio )"
+DEPEND="${RDEPEND}
+       dev-qt/linguist-tools:5"
+
+src_configure() {
+       append-cxxflags -std=c++11
+       econf \
+               --with-qt5="$(qt5_get_bindir)/.." \
+               $(use_enable alsa alsa-seq) \
+               $(use_enable dbus) \
+               $(use_enable debug) \
+               $(use_enable portaudio)
+
+       eqmake5 ${PN}.pro -o ${PN}.mak
+}
+
+src_compile() {
+       emake -f ${PN}.mak
+}