app-text/ansifilter: version bump 2.14

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Michael Palimaka <kensington@gentoo.org>

diff --git a/app-text/ansifilter/Manifest b/app-text/ansifilter/Manifest
index 1e7b317ef694c942311654fb0a6f9e75189f4544..716b00cc91107e35c8cc93169b64c290c6b2703d 100644 (file)
--- a/app-text/ansifilter/Manifest
+++ b/app-text/ansifilter/Manifest
@@ -1 +1,2 @@
 DIST ansifilter-2.13.tar.bz2 439681 BLAKE2B 4f23bfd05647046f9cb739f9ce0820b5b3ccad397a80558ecd5ca584c695dc4f942c1db3edd2f1b2d5a78b2c1e1b043677b1be3486ff7237090c27072e15f0fb SHA512 0d74607d2155f1cd0f66cf6470d1d83889d27c62475e366518a78b310c9681307e2fe662fea67078f95e6b9ce28e6f15656ab1ffc9e9e825d680808c673b7bfe
+DIST ansifilter-2.14.tar.bz2 441884 BLAKE2B 90b3b0330866da11c00b105aa79164178aebecf39131f5c8d8e373091f53d2d8bbced54472c975a61857d594a9fa92ce08d018523f471fde445d4548d48b949b SHA512 a0b7f12ea5b9ef9b5845a03484a2e238a9f60e0e49f8eddca8bf24b47faba48aa0b55f922678b3bf1b3f08857bbe9a8285b3f318f2adec84673bc502e21b6802

diff --git a/app-text/ansifilter/ansifilter-2.14.ebuild b/app-text/ansifilter/ansifilter-2.14.ebuild
new file mode 100644 (file)
index 0000000..e993d7b
--- /dev/null
+++ b/app-text/ansifilter/ansifilter-2.14.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs qmake-utils
+
+DESCRIPTION="Handles text files containing ANSI terminal escape codes"
+HOMEPAGE="http://www.andre-simon.de/"
+SRC_URI="http://www.andre-simon.de/zip/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="qt5"
+
+RDEPEND="
+       qt5? (
+               dev-qt/qtcore:5
+               dev-qt/qtgui:5
+               dev-qt/qtwidgets:5
+       )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+       default
+
+       # bug 431452
+       rm src/qt-gui/moc_mydialog.cpp || die
+}
+
+src_configure() {
+       if use qt5 ; then
+               pushd src/qt-gui > /dev/null || die
+               eqmake5
+               popd > /dev/null || die
+       fi
+}
+
+src_compile() {
+       emake -f makefile CC="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS} -DNDEBUG -std=c++11"
+
+       if use qt5 ; then
+               pushd src/qt-gui > /dev/null || die
+               emake
+               popd > /dev/null || die
+       fi
+}
+
+src_install() {
+       dobin src/${PN}
+       use qt5 && dobin src/qt-gui/${PN}-gui
+
+       gunzip man/${PN}.1.gz
+       doman man/${PN}.1
+       einstalldocs
+}