From 1fa8b8fd1097460603f3bc025d94bc623c18531b Mon Sep 17 00:00:00 2001
From: "W. Trevor King" <wking@tremily.us>
Date: Sat, 30 Aug 2014 09:32:57 -0700
Subject: [PATCH] dev-python/flask-cors: Add this docker-registry dependency

---
 dev-python/flask-cors/Manifest                |  1 +
 dev-python/flask-cors/flask-cors-1.8.0.ebuild |  1 +
 dev-python/flask-cors/flask-cors-9999.ebuild  | 56 +++++++++++++++++++
 3 files changed, 58 insertions(+)
 create mode 100644 dev-python/flask-cors/Manifest
 create mode 120000 dev-python/flask-cors/flask-cors-1.8.0.ebuild
 create mode 100644 dev-python/flask-cors/flask-cors-9999.ebuild

diff --git a/dev-python/flask-cors/Manifest b/dev-python/flask-cors/Manifest
new file mode 100644
index 0000000..0b39580
--- /dev/null
+++ b/dev-python/flask-cors/Manifest
@@ -0,0 +1 @@
+DIST flask-cors-1.8.0.tar.gz 17368 SHA256 da01f3ecf6d3d5c9c45ccdd95e6f93bc04a31f403ff5e4ad2e6c0fca99eb2cf1 SHA512 185a4e5785223d547373ff40d18dee2112a8da2dec2ecb39cb7b7c394e9220551e46302590870393c35902dd12e58d3d7cd4fb8fa052828b21d4107457a080fa WHIRLPOOL 1631d5c8e4521a31adcf061a6fbb21b9019835d3718ff02d16d2fe48af57d23d6cef01d740887d6b592ee420ba0c74ccb27a3a402547257823bc7a894793373a
diff --git a/dev-python/flask-cors/flask-cors-1.8.0.ebuild b/dev-python/flask-cors/flask-cors-1.8.0.ebuild
new file mode 120000
index 0000000..f806d10
--- /dev/null
+++ b/dev-python/flask-cors/flask-cors-1.8.0.ebuild
@@ -0,0 +1 @@
+flask-cors-9999.ebuild
\ No newline at end of file
diff --git a/dev-python/flask-cors/flask-cors-9999.ebuild b/dev-python/flask-cors/flask-cors-9999.ebuild
new file mode 100644
index 0000000..5bc0f95
--- /dev/null
+++ b/dev-python/flask-cors/flask-cors-9999.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-Cors"
+MY_P="${MY_PN}-${PV}"
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://github.com/wcdolphin/${PN}.git"
+	SRC_URI=""
+else
+	SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
+fi
+
+DESCRIPTION="A Flask extension for Cross Origin Resource Sharing (CORS)"
+HOMEPAGE="https://github.com/wcdolphin/flask-cors https://pypi.python.org/pypi/Flask-Cors"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		${RDEPEND}
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}
-- 
2.26.2