DomainKey-Signature: a=rsa-sha1; c=nofws; d=googlemail.com; s=gamma;
	h=from:to:cc:subject:date:message-id:x-mailer;
	b=pCD17xYBJls8Qd609X6NKMmVMpLTdp56UsBpBePF/16cYe1K1YoECgJ6kdKdNUBq5Z
	NT8LxBj8RdY0e+MBhQ7dw03TuEsQp6B/9lGdCI0YuuXr7uE3DdwYXuSusOMIMCEkTLTw
	zHE3mL0CbS/qwNvnWYNL5fFLMI+GAIv8RodwM=
From: Daniel Schoepe <daniel.schoepe@googlemail.com>
To: notmuch@notmuchmail.org
Subject: [PATCH] emacs: Tab completion for notmuch-search and
	notmuch-search-filter
Date: Sat,  4 Jun 2011 14:19:30 +0200
Message-Id: <1307189970-728-1-git-send-email-daniel.schoepe@googlemail.com>
Precedence: list

This patch adds completion with <tab> in the minibuffer for
notmuch-search and notmuch-search-filter.
---
 emacs/notmuch.el |   33 +++++++++++++++++++++++++++++++--
 1 files changed, 31 insertions(+), 2 deletions(-)

diff --git a/emacs/notmuch.el b/emacs/notmuch.el
index 3311fe8..49a82be 100644
--- a/emacs/notmuch.el
+++ b/emacs/notmuch.el
@@ -882,6 +882,35 @@ characters as well as `_.+-'.
 	   (concat "*notmuch-search-" query "*"))
 	  )))
 
+(defun notmuch-query-completions (compls string)
+  "Return possible completions for STRING.
+
+COMPLS should be a list of possibilities for an individual word."
+  (cond
+   ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
+    (mapcar (lambda (compl)
+	      (concat (match-string-no-properties 1 string) compl))
+	    (all-completions (match-string-no-properties 2 string)
+			     compls)))
+   (t (list string))))
+
+(defun notmuch-read-query (prompt)
+  "Read a notmuch-query from the minibuffer with completion.
+
+PROMPT is the string to prompt with."
+  (let* ((keymap (copy-keymap minibuffer-local-map))
+	 (all-compls (append (list "folder:" "thread:" "id:" "date:" "from:"
+				   "to:" "subject:" "attachment:")
+			     (mapcar (lambda (tag)
+				       (concat "tag:" tag))
+				     (process-lines "notmuch" "search-tags")))
+	 (minibuffer-completion-table (completion-table-dynamic
+				       `(lambda (s) (notmuch-query-completions
+						(quote ,all-compls) s)))))
+    ;; ^ emulate a closure to avoid recomputing the completion list each time
+    (define-key keymap (kbd "<tab>") 'minibuffer-complete)
+    (read-from-minibuffer prompt nil keymap nil minibuffer-history nil nil)))
+
 ;;;###autoload
 (defun notmuch-search (query &optional oldest-first target-thread target-line continuation)
   "Run \"notmuch search\" with the given query string and display results.
@@ -893,7 +922,7 @@ The optional parameters are used as follows:
                  current if it appears in the search results.
   target-line: The line number to move to if the target thread does not
                appear in the search results."
-  (interactive "sNotmuch search: ")
+  (interactive (notmuch-read-query "Notmuch search: "))
   (let ((buffer (get-buffer-create (notmuch-search-buffer-title query))))
     (switch-to-buffer buffer)
     (notmuch-search-mode)
@@ -991,7 +1020,7 @@ search."
 
 Runs a new search matching only messages that match both the
 current search results AND the additional query string provided."
-  (interactive "sFilter search: ")
+  (interactive (notmuch-read-query "Filter search: "))
   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 			   (concat "( " query " )")
 			 query)))
-- 
1.7.5.3