ikiwiki

   1 #!/usr/bin/perl -T
   2
   3 use warnings;
   4 use strict;
   5 use File::Find;
   6 use Memoize;
   7 use File::Spec;
   8
   9 $ENV{PATH}="/usr/local/bin:/usr/bin:/bin";
  10
  11 BEGIN {
  12         $blosxom::version="is a proper perl module too much to ask?";
  13         do "/usr/bin/markdown";
  14 }
  15
  16 my ($srcdir, $destdir, %links, %oldlinks, %oldpagemtime, %renderedfiles,
  17     %pagesources);
  18 my $wiki_link_regexp=qr/\[\[([^\s]+)\]\]/;
  19 my $wiki_file_regexp=qr/(^[-A-Za-z0-9_.:\/+]+$)/;
  20 my $wiki_file_prune_regexp=qr!((^|/).svn/|\.\.|^\.|\/\.|\.html?$)!;
  21 my $verbose=0;
  22 my $wikiname="wiki";
  23 my $default_pagetype=".mdwn";
  24 my $cgi=0;
  25 my $url="";
  26 my $cgiurl="";
  27 my $svn=1;
  28
  29 sub usage {
  30         die "usage: ikiwiki [options] source dest\n";
  31 }
  32
  33 sub error ($) {
  34         if ($cgi) {
  35                 print "Content-type: text/html\n\n";
  36                 print "Error: @_\n";
  37                 exit 1;
  38         }
  39         else {
  40                 die @_;
  41         }
  42 }
  43
  44 sub debug ($) {
  45         print "@_\n" if $verbose;
  46 }
  47
  48 sub mtime ($) {
  49         my $page=shift;
  50
  51         return (stat($page))[9];
  52 }
  53
  54 sub possibly_foolish_untaint ($) {
  55         my $tainted=shift;
  56         my ($untainted)=$tainted=~/(.*)/;
  57         return $untainted;
  58 }
  59
  60 sub basename {
  61         my $file=shift;
  62
  63         $file=~s!.*/!!;
  64         return $file;
  65 }
  66
  67 sub dirname {
  68         my $file=shift;
  69
  70         $file=~s!/?[^/]+$!!;
  71         return $file;
  72 }
  73
  74 sub pagetype ($) {
  75         my $page=shift;
  76
  77         if ($page =~ /\.mdwn$/) {
  78                 return ".mdwn";
  79         }
  80         else {
  81                 return "unknown";
  82         }
  83 }
  84
  85 sub pagename ($) {
  86         my $file=shift;
  87
  88         my $type=pagetype($file);
  89         my $page=$file;
  90         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
  91         return $page;
  92 }
  93
  94 sub htmlpage ($) {
  95         my $page=shift;
  96
  97         return $page.".html";
  98 }
  99
 100 sub readfile ($) {
 101         my $file=shift;
 102
 103         local $/=undef;
 104         open (IN, "$file") || error("failed to read $file: $!");
 105         my $ret=<IN>;
 106         close IN;
 107         return $ret;
 108 }
 109
 110 sub writefile ($$) {
 111         my $file=shift;
 112         my $content=shift;
 113
 114         my $dir=dirname($file);
 115         if (! -d $dir) {
 116                 my $d="";
 117                 foreach my $s (split(m!/+!, $dir)) {
 118                         $d.="$s/";
 119                         if (! -d $d) {
 120                                 mkdir($d) || error("failed to create directory $d: $!");
 121                         }
 122                 }
 123         }
 124
 125         open (OUT, ">$file") || error("failed to write $file: $!");
 126         print OUT $content;
 127         close OUT;
 128 }
 129
 130 sub findlinks {
 131         my $content=shift;
 132
 133         my @links;
 134         while ($content =~ /$wiki_link_regexp/g) {
 135                 push @links, lc($1);
 136         }
 137         return @links;
 138 }
 139
 140 # Given a page and the text of a link on the page, determine which existing
 141 # page that link best points to. Prefers pages under a subdirectory with
 142 # the same name as the source page, failing that goes down the directory tree
 143 # to the base looking for matching pages.
 144 sub bestlink ($$) {
 145         my $page=shift;
 146         my $link=lc(shift);
 147
 148         my $cwd=$page;
 149         do {
 150                 my $l=$cwd;
 151                 $l.="/" if length $l;
 152                 $l.=$link;
 153
 154                 if (exists $links{$l}) {
 155                         #debug("for $page, \"$link\", use $l");
 156                         return $l;
 157                 }
 158         } while $cwd=~s!/?[^/]+$!!;
 159
 160         #print STDERR "warning: page $page, broken link: $link\n";
 161         return "";
 162 }
 163
 164 sub isinlinableimage ($) {
 165         my $file=shift;
 166
 167         $file=~/\.(png|gif|jpg|jpeg)$/;
 168 }
 169
 170 sub htmllink ($$) {
 171         my $page=shift;
 172         my $link=shift;
 173
 174         my $bestlink=bestlink($page, $link);
 175
 176         return $link if $page eq $bestlink;
 177
 178         # TODO BUG: %renderedfiles may not have it, if the linked to page
 179         # was also added and isn't yet rendered! Note that this bug is
 180         # masked by the bug mentioned below that makes all new files
 181         # be rendered twice.
 182         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 183                 $bestlink=htmlpage($bestlink);
 184         }
 185         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 186                 return "<a href=\"$cgiurl?do=create&page=$link&from=$page\">?</a>$link"
 187         }
 188
 189         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 190
 191         if (isinlinableimage($bestlink)) {
 192                 return "<img src=\"$bestlink\">";
 193         }
 194         return "<a href=\"$bestlink\">$link</a>";
 195 }
 196
 197 sub linkify ($$) {
 198         my $content=shift;
 199         my $file=shift;
 200
 201         $content =~ s/$wiki_link_regexp/htmllink(pagename($file), $1)/eg;
 202
 203         return $content;
 204 }
 205
 206 sub htmlize ($$) {
 207         my $type=shift;
 208         my $content=shift;
 209
 210         if ($type eq '.mdwn') {
 211                 return Markdown::Markdown($content);
 212         }
 213         else {
 214                 error("htmlization of $type not supported");
 215         }
 216 }
 217
 218 sub linkbacks ($$) {
 219         my $content=shift;
 220         my $page=shift;
 221
 222         my @links;
 223         foreach my $p (keys %links) {
 224                 next if bestlink($page, $p) eq $page;
 225                 if (grep { length $_ && bestlink($p, $_) eq $page } @{$links{$p}}) {
 226                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
 227
 228                         # Trim common dir prefixes from both pages.
 229                         my $p_trimmed=$p;
 230                         my $page_trimmed=$page;
 231                         my $dir;
 232                         1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
 233                                 defined $dir &&
 234                                 $p_trimmed=~s/^\Q$dir\E// &&
 235                                 $page_trimmed=~s/^\Q$dir\E//;
 236
 237                         push @links, "<a href=\"$href\">$p_trimmed</a>";
 238                 }
 239         }
 240
 241         $content.="<hr><p>Links: ".join(" ", sort @links)."</p>\n" if @links;
 242         return $content;
 243 }
 244
 245 sub finalize ($$) {
 246         my $content=shift;
 247         my $page=shift;
 248
 249         my $title=basename($page);
 250         $title=~s/_/ /g;
 251
 252         my $pagelink="";
 253         my $path="";
 254         foreach my $dir (reverse split("/", $page)) {
 255                 if (length($pagelink)) {
 256                         $pagelink="<a href=\"$path$dir.html\">$dir</a>/ $pagelink";
 257                 }
 258                 else {
 259                         $pagelink=$dir;
 260                 }
 261                 $path.="../";
 262         }
 263         $path=~s/\.\.\/$/index.html/;
 264         $pagelink="<a href=\"$path\">$wikiname</a>/ $pagelink";
 265
 266         my @actions;
 267         if (length $cgiurl) {
 268                 push @actions, "<a href=\"$cgiurl?do=edit&page=$page\">Edit</a>";
 269                 push @actions, "<a href=\"$cgiurl?do=recentchanges\">RecentChanges</a>";
 270         }
 271
 272         $content="<html>\n<head><title>$title</title></head>\n<body>\n".
 273                   "<h1>$pagelink</h1>\n".
 274                   "@actions\n<hr>\n".
 275                   $content.
 276                   "</body>\n</html>\n";
 277
 278         return $content;
 279 }
 280
 281 sub render ($) {
 282         my $file=shift;
 283
 284         my $type=pagetype($file);
 285         my $content=readfile("$srcdir/$file");
 286         if ($type ne 'unknown') {
 287                 my $page=pagename($file);
 288
 289                 $links{$page}=[findlinks($content)];
 290
 291                 $content=linkify($content, $file);
 292                 $content=htmlize($type, $content);
 293                 $content=linkbacks($content, $page);
 294                 $content=finalize($content, $page);
 295
 296                 writefile("$destdir/".htmlpage($page), $content);
 297                 $oldpagemtime{$page}=time;
 298                 $renderedfiles{$page}=htmlpage($page);
 299         }
 300         else {
 301                 $links{$file}=[];
 302                 writefile("$destdir/$file", $content);
 303                 $oldpagemtime{$file}=time;
 304                 $renderedfiles{$file}=$file;
 305         }
 306 }
 307
 308 sub loadindex () {
 309         open (IN, "$srcdir/.index") || return;
 310         while (<IN>) {
 311                 $_=possibly_foolish_untaint($_);
 312                 chomp;
 313                 my ($mtime, $file, $rendered, @links)=split(' ', $_);
 314                 my $page=pagename($file);
 315                 $pagesources{$page}=$file;
 316                 $oldpagemtime{$page}=$mtime;
 317                 $oldlinks{$page}=[@links];
 318                 $links{$page}=[@links];
 319                 $renderedfiles{$page}=$rendered;
 320         }
 321         close IN;
 322 }
 323
 324 sub saveindex () {
 325         open (OUT, ">$srcdir/.index") || error("cannot write to .index: $!");
 326         foreach my $page (keys %oldpagemtime) {
 327         print OUT "$oldpagemtime{$page} $pagesources{$page} $renderedfiles{$page} ".
 328                   join(" ", @{$links{$page}})."\n"
 329                         if $oldpagemtime{$page};
 330         }
 331         close OUT;
 332 }
 333
 334 sub rcs_update () {
 335         if (-d "$srcdir/.svn") {
 336                 if (system("svn", "update", "--quiet", $srcdir) != 0) {
 337                         warn("svn update failed\n");
 338                 }
 339         }
 340 }
 341
 342 sub rcs_commit ($) {
 343         my $message=shift;
 344
 345         if (-d "$srcdir/.svn") {
 346                 if (system("svn", "commit", "--quiet", "-m",
 347                            possibly_foolish_untaint($message), $srcdir) != 0) {
 348                         warn("svn commit failed\n");
 349                 }
 350         }
 351 }
 352
 353 sub rcs_add ($) {
 354         my $file=shift;
 355
 356         if (-d "$srcdir/.svn") {
 357                 my $parent=dirname($file);
 358                 while (! -d "$srcdir/$parent/.svn") {
 359                         $file=$parent;
 360                         $parent=dirname($file);
 361                 }
 362
 363                 if (system("svn", "add", "--quiet", "$srcdir/$file") != 0) {
 364                         warn("svn add failed\n");
 365                 }
 366         }
 367 }
 368
 369 sub rcs_recentchanges ($) {
 370         my $num=shift;
 371         my @ret;
 372
 373         eval {use Date::Parse};
 374         eval {use Time::Duration};
 375
 376         if (-d "$srcdir/.svn") {
 377                 my $info=`LANG=C svn info $srcdir`;
 378                 my ($svn_url)=$info=~/^URL: (.*)$/m;
 379
 380                 my $div=qr/^--------------------+$/;
 381                 my $infoline=qr/^r(\d+)\s+\|\s+([^\s]+)\s+\|\s+(\d+-\d+-\d+\s+\d+:\d+:\d+\s+[-+]?\d+).*/;
 382                 my $state='start';
 383                 my ($rev, $user, $when, @pages, $message);
 384                 foreach (`LANG=C svn log -v '$svn_url'`) {
 385                         chomp;
 386                         print STDERR "state: $state ($_)\n";
 387                         if ($state eq 'start' && /$div/) {
 388                                 $state='header';
 389                         }
 390                         elsif ($state eq 'header' && /$infoline/) {
 391                                 $rev=$1;
 392                                 $user=$2;
 393                                 $when=ago(time - str2time($3));
 394                         }
 395                         elsif ($state eq 'header' && /^\s+(.*)/) {
 396                                 push @pages, $1;
 397                         }
 398                         elsif ($state eq 'header' && /^$/) {
 399                                 $state='body';
 400                         }
 401                         elsif ($state eq 'body' && /$div/) {
 402                                 push @ret, {rev => $rev, user => $user,
 403                                         date => $when, message => $message,
 404                                         pages => [@pages]},
 405                                 return @ret if @ret >= $num;
 406
 407                                 $state='header';
 408                                 $message=$rev=$user=$when=undef;
 409                                 @pages=();
 410                         }
 411                         elsif ($state eq 'body') {
 412                                 $message.="$_<br>\n";
 413                         }
 414                 }
 415         }
 416
 417         return @ret;
 418 }
 419
 420 sub prune ($) {
 421         my $file=shift;
 422
 423         unlink($file);
 424         my $dir=dirname($file);
 425         while (rmdir($dir)) {
 426                 $dir=dirname($dir);
 427         }
 428 }
 429
 430 sub refresh () {
 431         # Find existing pages.
 432         my %exists;
 433         my @files;
 434         find({
 435                 no_chdir => 1,
 436                 wanted => sub {
 437                         if (/$wiki_file_prune_regexp/) {
 438                                 $File::Find::prune=1;
 439                         }
 440                         elsif (! -d $_) {
 441                                 my ($f)=/$wiki_file_regexp/; # untaint
 442                                 if (! defined $f) {
 443                                         warn("skipping bad filename $_\n");
 444                                 }
 445                                 else {
 446                                         $f=~s/^\Q$srcdir\E\/?//;
 447                                         push @files, $f;
 448                                         $exists{pagename($f)}=1;
 449                                 }
 450                         }
 451                 },
 452         }, $srcdir);
 453
 454         my %rendered;
 455
 456         # check for added or removed pages
 457         my @add;
 458         foreach my $file (@files) {
 459                 my $page=pagename($file);
 460                 if (! $oldpagemtime{$page}) {
 461                         debug("new page $page");
 462                         push @add, $file;
 463                         $links{$page}=[];
 464                         $pagesources{$page}=$file;
 465                 }
 466         }
 467         my @del;
 468         foreach my $page (keys %oldpagemtime) {
 469                 if (! $exists{$page}) {
 470                         debug("removing old page $page");
 471                         push @del, $renderedfiles{$page};
 472                         prune($destdir."/".$renderedfiles{$page});
 473                         delete $renderedfiles{$page};
 474                         $oldpagemtime{$page}=0;
 475                         delete $pagesources{$page};
 476                 }
 477         }
 478
 479         # render any updated files
 480         foreach my $file (@files) {
 481                 my $page=pagename($file);
 482
 483                 if (! exists $oldpagemtime{$page} ||
 484                     mtime("$srcdir/$file") > $oldpagemtime{$page}) {
 485                         debug("rendering changed file $file");
 486                         render($file);
 487                         $rendered{$file}=1;
 488                 }
 489         }
 490
 491         # if any files were added or removed, check to see if each page
 492         # needs an update due to linking to them
 493         # TODO: inefficient; pages may get rendered above and again here;
 494         # problem is the bestlink may have changed and we won't know until
 495         # now
 496         if (@add || @del) {
 497 FILE:           foreach my $file (@files) {
 498                         my $page=pagename($file);
 499                         foreach my $f (@add, @del) {
 500                                 my $p=pagename($f);
 501                                 foreach my $link (@{$links{$page}}) {
 502                                         if (bestlink($page, $link) eq $p) {
 503                                                 debug("rendering $file, which links to $p");
 504                                                 render($file);
 505                                                 $rendered{$file}=1;
 506                                                 next FILE;
 507                                         }
 508                                 }
 509                         }
 510                 }
 511         }
 512
 513         # handle linkbacks; if a page has added/removed links, update the
 514         # pages it links to
 515         # TODO: inefficient; pages may get rendered above and again here;
 516         # problem is the linkbacks could be wrong in the first pass render
 517         # above
 518         if (%rendered) {
 519                 my %linkchanged;
 520                 foreach my $file (keys %rendered, @del) {
 521                         my $page=pagename($file);
 522                         if (exists $links{$page}) {
 523                                 foreach my $link (@{$links{$page}}) {
 524                                         $link=bestlink($page, $link);
 525                                         if (length $link &&
 526                                             ! exists $oldlinks{$page} ||
 527                                             ! grep { $_ eq $link } @{$oldlinks{$page}}) {
 528                                                 $linkchanged{$link}=1;
 529                                         }
 530                                 }
 531                         }
 532                         if (exists $oldlinks{$page}) {
 533                                 foreach my $link (@{$oldlinks{$page}}) {
 534                                         $link=bestlink($page, $link);
 535                                         if (length $link &&
 536                                             ! exists $links{$page} ||
 537                                             ! grep { $_ eq $link } @{$links{$page}}) {
 538                                                 $linkchanged{$link}=1;
 539                                         }
 540                                 }
 541                         }
 542                 }
 543                 foreach my $link (keys %linkchanged) {
 544                         my $linkfile=$pagesources{$link};
 545                         if (defined $linkfile) {
 546                                 debug("rendering $linkfile, to update its linkbacks");
 547                                 render($linkfile);
 548                         }
 549                 }
 550         }
 551 }
 552
 553 # Generates a C wrapper program for running ikiwiki in a specific way.
 554 # The wrapper may be safely made suid.
 555 sub gen_wrapper ($$) {
 556         my ($svn, $rebuild)=@_;
 557
 558         eval {use Cwd 'abs_path'};
 559         $srcdir=abs_path($srcdir);
 560         $destdir=abs_path($destdir);
 561         my $this=abs_path($0);
 562         if (! -x $this) {
 563                 error("$this doesn't seem to be executable");
 564         }
 565
 566         my @params=($srcdir, $destdir, "--wikiname=$wikiname");
 567         push @params, "--verbose" if $verbose;
 568         push @params, "--rebuild" if $rebuild;
 569         push @params, "--nosvn" if !$svn;
 570         push @params, "--cgi" if $cgi;
 571         push @params, "--url=$url" if $url;
 572         push @params, "--cgiurl=$cgiurl" if $cgiurl;
 573         my $params=join(" ", @params);
 574         my $call='';
 575         foreach my $p ($this, $this, @params) {
 576                 $call.=qq{"$p", };
 577         }
 578         $call.="NULL";
 579
 580         my @envsave;
 581         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
 582                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE} if $cgi;
 583         my $envsave="";
 584         foreach my $var (@envsave) {
 585                 $envsave.=<<"EOF"
 586         if ((s=getenv("$var")))
 587                 asprintf(&newenviron[i++], "%s=%s", "$var", s);
 588 EOF
 589         }
 590
 591         open(OUT, ">ikiwiki-wrap.c") || error("failed to write ikiwiki-wrap.c: $!");;
 592         print OUT <<"EOF";
 593 /* A wrapper for ikiwiki, can be safely made suid. */
 594 #define _GNU_SOURCE
 595 #include <stdio.h>
 596 #include <unistd.h>
 597 #include <stdlib.h>
 598 #include <string.h>
 599
 600 extern char **environ;
 601
 602 int main (int argc, char **argv) {
 603         /* Sanitize environment. */
 604         char *s;
 605         char *newenviron[$#envsave+3];
 606         int i=0;
 607 $envsave
 608         newenviron[i++]="HOME=$ENV{HOME}";
 609         newenviron[i]=NULL;
 610         environ=newenviron;
 611
 612         if (argc == 2 && strcmp(argv[1], "--params") == 0) {
 613                 printf("$params\\n");
 614                 exit(0);
 615         }
 616
 617         execl($call);
 618         perror("failed to run $this");
 619         exit(1);
 620 }
 621 EOF
 622         close OUT;
 623         if (system("gcc", "ikiwiki-wrap.c", "-o", "ikiwiki-wrap") != 0) {
 624                 error("failed to compile ikiwiki-wrap.c");
 625         }
 626         unlink("ikiwiki-wrap.c");
 627         print "successfully generated ikiwiki-wrap\n";
 628         exit 0;
 629 }
 630
 631 sub cgi () {
 632         eval q{use CGI};
 633         my $q=CGI->new;
 634
 635         my $do=$q->param('do');
 636         if (! defined $do || ! length $do) {
 637                 error("\"do\" parameter missing");
 638         }
 639
 640         if ($do eq 'recentchanges') {
 641                 my $list="<ul>\n";
 642                 foreach my $change (rcs_recentchanges(100)) {
 643                         print STDERR "change: $change....\n";
 644                         $list.="<li>";
 645                         foreach my $page (@{$change->{pages}}) {
 646                                 $list.=$page." ";
 647                         }
 648                         $list.="<br>\n";
 649                         $list.="changed ".$change->{when}." by ".
 650                                htmllink("index", $change->{user}).
 651                                ": <i>".$change->{message}."<br>\n";
 652                         $list.="</li>\n";
 653                 }
 654                 $list.="</ul>\n";
 655
 656                 print $q->header,
 657                       $q->start_html("RecentChanges"),
 658                       $q->h1("<a href=\"$url\">$wikiname</a>/ RecentChanges"),
 659                       $list,
 660                       $q->end_form,
 661                       $q->end_html;
 662                 return;
 663         }
 664
 665         my ($page)=$q->param('page')=~/$wiki_file_regexp/;
 666         if (! defined $page || ! length $page || $page ne $q->param('page') ||
 667             $page=~/$wiki_file_prune_regexp/ || $page=~/^\//) {
 668                 error("bad page name");
 669         }
 670         $page=lc($page);
 671
 672         my $action=$q->request_uri;
 673         $action=~s/\?.*//;
 674
 675         if ($do eq 'create') {
 676                 if (exists $pagesources{lc($page)}) {
 677                         # hmm, someone else made the page in the meantime?
 678                         print $q->redirect("$url/".htmlpage($page));
 679                 }
 680
 681                 my @page_locs;
 682                 my ($from)=$q->param('from')=~/$wiki_file_regexp/;
 683                 if (! defined $from || ! length $from ||
 684                     $from ne $q->param('from') ||
 685                     $from=~/$wiki_file_prune_regexp/ || $from=~/^\//) {
 686                         @page_locs=$page;
 687                 }
 688                 else {
 689                         my $dir=$from."/";
 690                         $dir=~s![^/]+/$!!;
 691                         push @page_locs, $dir.$page;
 692                         push @page_locs, "$from/$page";
 693                         while (length $dir) {
 694                                 $dir=~s![^/]+/$!!;
 695                                 push @page_locs, $dir.$page;
 696                         }
 697                 }
 698
 699                 $q->param("do", "save");
 700                 print $q->header,
 701                       $q->start_html("Creating $page"),
 702                       $q->start_h1("<a href=\"$url\">$wikiname</a>/ Creating $page"),
 703                       $q->start_form(-action => $action),
 704                       $q->hidden('do'),
 705                       "Select page location:",
 706                       $q->popup_menu('page', \@page_locs),
 707                       $q->textarea(-name => 'content',
 708                                -default => "",
 709                                -rows => 20,
 710                                -columns => 80),
 711                       $q->br,
 712                       "Optional comment about this change:",
 713                       $q->br,
 714                       $q->textfield(-name => "comments", -size => 80),
 715                       $q->br,
 716                       $q->submit("Save Page"),
 717                       $q->end_form,
 718                       $q->end_html;
 719         }
 720         elsif ($do eq 'edit') {
 721                 my $content="";
 722                 if (exists $pagesources{lc($page)}) {
 723                         $content=readfile("$srcdir/$pagesources{lc($page)}");
 724                         $content=~s/\n/\r\n/g;
 725                 }
 726                 $q->param("do", "save");
 727                 print $q->header,
 728                       $q->start_html("Editing $page"),
 729                       $q->h1("<a href=\"$url\">$wikiname</a>/ Editing $page"),
 730                       $q->start_form(-action => $action),
 731                       $q->hidden('do'),
 732                       $q->hidden('page'),
 733                       $q->textarea(-name => 'content',
 734                                -default => $content,
 735                                -rows => 20,
 736                                -columns => 80),
 737                       $q->br,
 738                       "Optional comment about this change:",
 739                       $q->br,
 740                       $q->textfield(-name => "comments", -size => 80),
 741                       $q->br,
 742                       $q->submit("Save Page"),
 743                       $q->end_form,
 744                       $q->end_html;
 745         }
 746         elsif ($do eq 'save') {
 747                 my $file=$page.$default_pagetype;
 748                 my $newfile=1;
 749                 if (exists $pagesources{lc($page)}) {
 750                         $file=$pagesources{lc($page)};
 751                         $newfile=0;
 752                 }
 753
 754                 my $content=$q->param('content');
 755                 $content=~s/\r\n/\n/g;
 756                 $content=~s/\r/\n/g;
 757                 writefile("$srcdir/$file", $content);
 758
 759                 my $message="web commit from $ENV{REMOTE_ADDR}";
 760                 if (defined $q->param('comments')) {
 761                         $message.=": ".$q->param('comments');
 762                 }
 763
 764                 if ($svn) {
 765                         if ($newfile) {
 766                                 rcs_add($file);
 767                         }
 768                         # presumably the commit will trigger an update
 769                         # of the wiki
 770                         rcs_commit($message);
 771                 }
 772                 else {
 773                         refresh();
 774                 }
 775
 776                 print $q->redirect("$url/".htmlpage($page));
 777         }
 778         else {
 779                 error("unknown do parameter");
 780         }
 781 }
 782
 783 my $rebuild=0;
 784 my $wrapper=0;
 785 if (grep /^-/, @ARGV) {
 786         eval {use Getopt::Long};
 787         GetOptions(
 788                 "wikiname=s" => \$wikiname,
 789                 "verbose|v" => \$verbose,
 790                 "rebuild" => \$rebuild,
 791                 "wrapper" => \$wrapper,
 792                 "svn!" => \$svn,
 793                 "cgi" => \$cgi,
 794                 "url=s" => \$url,
 795                 "cgiurl=s" => \$cgiurl,
 796         ) || usage();
 797 }
 798 usage() unless @ARGV == 2;
 799 ($srcdir) = possibly_foolish_untaint(shift);
 800 ($destdir) = possibly_foolish_untaint(shift);
 801
 802 if ($cgi && ! length $url) {
 803         error("Must specify url to wiki with --url when using --cgi");
 804 }
 805
 806 gen_wrapper($svn, $rebuild) if $wrapper;
 807 memoize('pagename');
 808 memoize('bestlink');
 809 loadindex() unless $rebuild;
 810 if ($cgi) {
 811         cgi();
 812 }
 813 else {
 814         rcs_update() if $svn;
 815         refresh();
 816         saveindex();
 817 }