ikiwiki

   1 #!/usr/bin/perl -T
   2
   3 use warnings;
   4 use strict;
   5 use File::Find;
   6 use Memoize;
   7 use File::Spec;
   8 use HTML::Template;
   9
  10 BEGIN {
  11         $blosxom::version="is a proper perl module too much to ask?";
  12         do "/usr/bin/markdown";
  13 }
  14
  15 $ENV{PATH}="/usr/local/bin:/usr/bin:/bin";
  16 my ($srcdir, $templatedir, $destdir, %links, %oldlinks, %oldpagemtime,
  17     %renderedfiles, %pagesources);
  18 my $wiki_link_regexp=qr/\[\[([^\s]+)\]\]/;
  19 my $wiki_file_regexp=qr/(^[-A-Za-z0-9_.:\/+]+$)/;
  20 my $wiki_file_prune_regexp=qr!((^|/).svn/|\.\.|^\.|\/\.|\.html?$)!;
  21 my $verbose=0;
  22 my $wikiname="wiki";
  23 my $default_pagetype=".mdwn";
  24 my $cgi=0;
  25 my $url="";
  26 my $cgiurl="";
  27 my $historyurl="";
  28 my $svn=1;
  29 my $anonok=0;
  30
  31 sub usage { #{{{
  32         die "usage: ikiwiki [options] source templates dest\n";
  33 } #}}}
  34
  35 sub error ($) { #{{{
  36         if ($cgi) {
  37                 print "Content-type: text/html\n\n";
  38                 print misctemplate("Error", "<p>Error: @_</p>");
  39                 exit 1;
  40         }
  41         else {
  42                 die @_;
  43         }
  44 } #}}}
  45
  46 sub debug ($) { #{{{
  47         if (! $cgi) {
  48                 print "@_\n" if $verbose;
  49         }
  50         else {
  51                 print STDERR "@_\n" if $verbose;
  52         }
  53 } #}}}
  54
  55 sub mtime ($) { #{{{
  56         my $page=shift;
  57
  58         return (stat($page))[9];
  59 } #}}}
  60
  61 sub possibly_foolish_untaint ($) { #{{{
  62         my $tainted=shift;
  63         my ($untainted)=$tainted=~/(.*)/;
  64         return $untainted;
  65 } #}}}
  66
  67 sub basename ($) { #{{{
  68         my $file=shift;
  69
  70         $file=~s!.*/!!;
  71         return $file;
  72 } #}}}
  73
  74 sub dirname ($) { #{{{
  75         my $file=shift;
  76
  77         $file=~s!/?[^/]+$!!;
  78         return $file;
  79 } #}}}
  80
  81 sub pagetype ($) { #{{{
  82         my $page=shift;
  83
  84         if ($page =~ /\.mdwn$/) {
  85                 return ".mdwn";
  86         }
  87         else {
  88                 return "unknown";
  89         }
  90 } #}}}
  91
  92 sub pagename ($) { #{{{
  93         my $file=shift;
  94
  95         my $type=pagetype($file);
  96         my $page=$file;
  97         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
  98         return $page;
  99 } #}}}
 100
 101 sub htmlpage ($) { #{{{
 102         my $page=shift;
 103
 104         return $page.".html";
 105 } #}}}
 106
 107 sub readfile ($) { #{{{
 108         my $file=shift;
 109
 110         local $/=undef;
 111         open (IN, "$file") || error("failed to read $file: $!");
 112         my $ret=<IN>;
 113         close IN;
 114         return $ret;
 115 } #}}}
 116
 117 sub writefile ($$) { #{{{
 118         my $file=shift;
 119         my $content=shift;
 120
 121         my $dir=dirname($file);
 122         if (! -d $dir) {
 123                 my $d="";
 124                 foreach my $s (split(m!/+!, $dir)) {
 125                         $d.="$s/";
 126                         if (! -d $d) {
 127                                 mkdir($d) || error("failed to create directory $d: $!");
 128                         }
 129                 }
 130         }
 131
 132         open (OUT, ">$file") || error("failed to write $file: $!");
 133         print OUT $content;
 134         close OUT;
 135 } #}}}
 136
 137 sub findlinks ($) { #{{{
 138         my $content=shift;
 139
 140         my @links;
 141         while ($content =~ /$wiki_link_regexp/g) {
 142                 push @links, lc($1);
 143         }
 144         return @links;
 145 } #}}}
 146
 147 # Given a page and the text of a link on the page, determine which existing
 148 # page that link best points to. Prefers pages under a subdirectory with
 149 # the same name as the source page, failing that goes down the directory tree
 150 # to the base looking for matching pages.
 151 sub bestlink ($$) { #{{{
 152         my $page=shift;
 153         my $link=lc(shift);
 154
 155         my $cwd=$page;
 156         do {
 157                 my $l=$cwd;
 158                 $l.="/" if length $l;
 159                 $l.=$link;
 160
 161                 if (exists $links{$l}) {
 162                         #debug("for $page, \"$link\", use $l");
 163                         return $l;
 164                 }
 165         } while $cwd=~s!/?[^/]+$!!;
 166
 167         #print STDERR "warning: page $page, broken link: $link\n";
 168         return "";
 169 } #}}}
 170
 171 sub isinlinableimage ($) { #{{{
 172         my $file=shift;
 173
 174         $file=~/\.(png|gif|jpg|jpeg)$/;
 175 } #}}}
 176
 177 sub htmllink { #{{{
 178         my $page=shift;
 179         my $link=shift;
 180         my $noimagelink=shift;
 181
 182         my $bestlink=bestlink($page, $link);
 183
 184         return $link if $page eq $bestlink;
 185
 186         # TODO BUG: %renderedfiles may not have it, if the linked to page
 187         # was also added and isn't yet rendered! Note that this bug is
 188         # masked by the bug mentioned below that makes all new files
 189         # be rendered twice.
 190         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 191                 $bestlink=htmlpage($bestlink);
 192         }
 193         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 194                 return "<a href=\"$cgiurl?do=create&page=$link&from=$page\">?</a>$link"
 195         }
 196
 197         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 198
 199         if (! $noimagelink && isinlinableimage($bestlink)) {
 200                 return "<img src=\"$bestlink\">";
 201         }
 202         return "<a href=\"$bestlink\">$link</a>";
 203 } #}}}
 204
 205 sub linkify ($$) { #{{{
 206         my $content=shift;
 207         my $file=shift;
 208
 209         $content =~ s/$wiki_link_regexp/htmllink(pagename($file), $1)/eg;
 210
 211         return $content;
 212 } #}}}
 213
 214 sub htmlize ($$) { #{{{
 215         my $type=shift;
 216         my $content=shift;
 217
 218         if ($type eq '.mdwn') {
 219                 return Markdown::Markdown($content);
 220         }
 221         else {
 222                 error("htmlization of $type not supported");
 223         }
 224 } #}}}
 225
 226 sub backlinks ($) { #{{{
 227         my $page=shift;
 228
 229         my @links;
 230         foreach my $p (keys %links) {
 231                 next if bestlink($page, $p) eq $page;
 232                 if (grep { length $_ && bestlink($p, $_) eq $page } @{$links{$p}}) {
 233                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
 234
 235                         # Trim common dir prefixes from both pages.
 236                         my $p_trimmed=$p;
 237                         my $page_trimmed=$page;
 238                         my $dir;
 239                         1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
 240                                 defined $dir &&
 241                                 $p_trimmed=~s/^\Q$dir\E// &&
 242                                 $page_trimmed=~s/^\Q$dir\E//;
 243
 244                         push @links, { url => $href, page => $p_trimmed };
 245                 }
 246         }
 247
 248         return sort { $a->{page} cmp $b->{page} } @links;
 249 } #}}}
 250
 251 sub parentlinks ($) { #{{{
 252         my $page=shift;
 253
 254         my @ret;
 255         my $pagelink="";
 256         my $path="";
 257         my $skip=1;
 258         foreach my $dir (reverse split("/", $page)) {
 259                 if (! $skip) {
 260                         unshift @ret, { url => "$path$dir.html", page => $dir };
 261                 }
 262                 else {
 263                         $skip=0;
 264                 }
 265                 $path.="../";
 266         }
 267         unshift @ret, { url => $path , page => $wikiname };
 268         return @ret;
 269 } #}}}
 270
 271 sub indexlink () { #{{{
 272         return "<a href=\"$url\">$wikiname</a>";
 273 } #}}}
 274
 275 sub finalize ($$) { #{{{
 276         my $content=shift;
 277         my $page=shift;
 278
 279         my $title=basename($page);
 280         $title=~s/_/ /g;
 281
 282         my $template=HTML::Template->new(blind_cache => 1,
 283                 filename => "$templatedir/page.tmpl");
 284
 285         if (length $cgiurl) {
 286                 $template->param(editurl => "$cgiurl?do=edit&page=$page");
 287                 if ($svn) {
 288                         $template->param(recentchangesurl => "$cgiurl?do=recentchanges");
 289                 }
 290         }
 291
 292         if (length $historyurl) {
 293                 my $u=$historyurl;
 294                 $u=~s/\[\[\]\]/$pagesources{$page}/g;
 295                 $template->param(historyurl => $u);
 296         }
 297
 298         $template->param(
 299                 title => $title,
 300                 wikiname => $wikiname,
 301                 parentlinks => [parentlinks($page)],
 302                 content => $content,
 303                 backlinks => [backlinks($page)],
 304         );
 305
 306         return $template->output;
 307 } #}}}
 308
 309 # Important security check. Make sure to call this before saving any files
 310 # to the source directory.
 311 sub check_overwrite ($$) { #{{{
 312         my $dest=shift;
 313         my $src=shift;
 314
 315         if (! exists $renderedfiles{$src} && -e $dest) {
 316                 error("$dest exists and was not rendered from $src before, not overwriting");
 317         }
 318 } #}}}
 319
 320 sub render ($) { #{{{
 321         my $file=shift;
 322
 323         my $type=pagetype($file);
 324         my $content=readfile("$srcdir/$file");
 325         if ($type ne 'unknown') {
 326                 my $page=pagename($file);
 327
 328                 $links{$page}=[findlinks($content)];
 329
 330                 $content=linkify($content, $file);
 331                 $content=htmlize($type, $content);
 332                 $content=finalize($content, $page);
 333
 334                 check_overwrite("$destdir/".htmlpage($page), $page);
 335                 writefile("$destdir/".htmlpage($page), $content);
 336                 $oldpagemtime{$page}=time;
 337                 $renderedfiles{$page}=htmlpage($page);
 338         }
 339         else {
 340                 $links{$file}=[];
 341                 check_overwrite("$destdir/$file", $file);
 342                 writefile("$destdir/$file", $content);
 343                 $oldpagemtime{$file}=time;
 344                 $renderedfiles{$file}=$file;
 345         }
 346 } #}}}
 347
 348 sub loadindex () { #{{{
 349         open (IN, "$srcdir/.ikiwiki/index") || return;
 350         while (<IN>) {
 351                 $_=possibly_foolish_untaint($_);
 352                 chomp;
 353                 my ($mtime, $file, $rendered, @links)=split(' ', $_);
 354                 my $page=pagename($file);
 355                 $pagesources{$page}=$file;
 356                 $oldpagemtime{$page}=$mtime;
 357                 $oldlinks{$page}=[@links];
 358                 $links{$page}=[@links];
 359                 $renderedfiles{$page}=$rendered;
 360         }
 361         close IN;
 362 } #}}}
 363
 364 sub saveindex () { #{{{
 365         if (! -d "$srcdir/.ikiwiki") {
 366                 mkdir("$srcdir/.ikiwiki");
 367         }
 368         open (OUT, ">$srcdir/.ikiwiki/index") || error("cannot write to index: $!");
 369         foreach my $page (keys %oldpagemtime) {
 370                 print OUT "$oldpagemtime{$page} $pagesources{$page} $renderedfiles{$page} ".
 371                         join(" ", @{$links{$page}})."\n"
 372                                 if $oldpagemtime{$page};
 373         }
 374         close OUT;
 375 } #}}}
 376
 377 sub rcs_update () { #{{{
 378         if (-d "$srcdir/.svn") {
 379                 if (system("svn", "update", "--quiet", $srcdir) != 0) {
 380                         warn("svn update failed\n");
 381                 }
 382         }
 383 } #}}}
 384
 385 sub rcs_commit ($) { #{{{
 386         my $message=shift;
 387
 388         if (-d "$srcdir/.svn") {
 389                 if (system("svn", "commit", "--quiet", "-m",
 390                            possibly_foolish_untaint($message), $srcdir) != 0) {
 391                         warn("svn commit failed\n");
 392                 }
 393         }
 394 } #}}}
 395
 396 sub rcs_add ($) { #{{{
 397         my $file=shift;
 398
 399         if (-d "$srcdir/.svn") {
 400                 my $parent=dirname($file);
 401                 while (! -d "$srcdir/$parent/.svn") {
 402                         $file=$parent;
 403                         $parent=dirname($file);
 404                 }
 405
 406                 if (system("svn", "add", "--quiet", "$srcdir/$file") != 0) {
 407                         warn("svn add failed\n");
 408                 }
 409         }
 410 } #}}}
 411
 412 sub rcs_recentchanges ($) { #{{{
 413         my $num=shift;
 414         my @ret;
 415
 416         eval q{use Date::Parse};
 417         eval q{use Time::Duration};
 418
 419         if (-d "$srcdir/.svn") {
 420                 my $info=`LANG=C svn info $srcdir`;
 421                 my ($svn_url)=$info=~/^URL: (.*)$/m;
 422
 423                 # FIXME: currently assumes that the wiki is somewhere
 424                 # under trunk in svn, doesn't support other layouts.
 425                 my ($svn_base)=$svn_url=~m!(/trunk(?:/.*)?)$!;
 426
 427                 my $div=qr/^--------------------+$/;
 428                 my $infoline=qr/^r(\d+)\s+\|\s+([^\s]+)\s+\|\s+(\d+-\d+-\d+\s+\d+:\d+:\d+\s+[-+]?\d+).*/;
 429                 my $state='start';
 430                 my ($rev, $user, $when, @pages, @message);
 431                 foreach (`LANG=C svn log -v '$svn_url'`) {
 432                         chomp;
 433                         if ($state eq 'start' && /$div/) {
 434                                 $state='header';
 435                         }
 436                         elsif ($state eq 'header' && /$infoline/) {
 437                                 $rev=$1;
 438                                 $user=$2;
 439                                 $when=concise(ago(time - str2time($3)));
 440                         }
 441                         elsif ($state eq 'header' && /^\s+[A-Z]\s+\Q$svn_base\E\/(.+)$/) {
 442                                 push @pages, { link => htmllink("", pagename($1), 1) }
 443                                         if length $1;
 444                         }
 445                         elsif ($state eq 'header' && /^$/) {
 446                                 $state='body';
 447                         }
 448                         elsif ($state eq 'body' && /$div/) {
 449                                 my $committype="web";
 450                                 if (defined $message[0] &&
 451                                     $message[0]->{line}=~/^web commit by (\w+):?(.*)/) {
 452                                         $user="$1";
 453                                         $message[0]->{line}=$2;
 454                                 }
 455                                 else {
 456                                         $committype="svn";
 457                                 }
 458
 459                                 push @ret, { rev => $rev,
 460                                         user => htmllink("", $user, 1),
 461                                         committype => $committype,
 462                                         when => $when, message => [@message],
 463                                         pages => [@pages] } if @pages;
 464                                 return @ret if @ret >= $num;
 465
 466                                 $state='header';
 467                                 $rev=$user=$when=undef;
 468                                 @pages=@message=();
 469                         }
 470                         elsif ($state eq 'body') {
 471                                 push @message, {line => $_},
 472                         }
 473                 }
 474         }
 475
 476         return @ret;
 477 } #}}}
 478
 479 sub prune ($) { #{{{
 480         my $file=shift;
 481
 482         unlink($file);
 483         my $dir=dirname($file);
 484         while (rmdir($dir)) {
 485                 $dir=dirname($dir);
 486         }
 487 } #}}}
 488
 489 sub refresh () { #{{{
 490         # Find existing pages.
 491         my %exists;
 492         my @files;
 493         find({
 494                 no_chdir => 1,
 495                 wanted => sub {
 496                         if (/$wiki_file_prune_regexp/) {
 497                                 $File::Find::prune=1;
 498                         }
 499                         elsif (! -d $_) {
 500                                 my ($f)=/$wiki_file_regexp/; # untaint
 501                                 if (! defined $f) {
 502                                         warn("skipping bad filename $_\n");
 503                                 }
 504                                 else {
 505                                         $f=~s/^\Q$srcdir\E\/?//;
 506                                         push @files, $f;
 507                                         $exists{pagename($f)}=1;
 508                                 }
 509                         }
 510                 },
 511         }, $srcdir);
 512
 513         my %rendered;
 514
 515         # check for added or removed pages
 516         my @add;
 517         foreach my $file (@files) {
 518                 my $page=pagename($file);
 519                 if (! $oldpagemtime{$page}) {
 520                         debug("new page $page");
 521                         push @add, $file;
 522                         $links{$page}=[];
 523                         $pagesources{$page}=$file;
 524                 }
 525         }
 526         my @del;
 527         foreach my $page (keys %oldpagemtime) {
 528                 if (! $exists{$page}) {
 529                         debug("removing old page $page");
 530                         push @del, $renderedfiles{$page};
 531                         prune($destdir."/".$renderedfiles{$page});
 532                         delete $renderedfiles{$page};
 533                         $oldpagemtime{$page}=0;
 534                         delete $pagesources{$page};
 535                 }
 536         }
 537
 538         # render any updated files
 539         foreach my $file (@files) {
 540                 my $page=pagename($file);
 541
 542                 if (! exists $oldpagemtime{$page} ||
 543                     mtime("$srcdir/$file") > $oldpagemtime{$page}) {
 544                         debug("rendering changed file $file");
 545                         render($file);
 546                         $rendered{$file}=1;
 547                 }
 548         }
 549
 550         # if any files were added or removed, check to see if each page
 551         # needs an update due to linking to them
 552         # TODO: inefficient; pages may get rendered above and again here;
 553         # problem is the bestlink may have changed and we won't know until
 554         # now
 555         if (@add || @del) {
 556 FILE:           foreach my $file (@files) {
 557                         my $page=pagename($file);
 558                         foreach my $f (@add, @del) {
 559                                 my $p=pagename($f);
 560                                 foreach my $link (@{$links{$page}}) {
 561                                         if (bestlink($page, $link) eq $p) {
 562                                                 debug("rendering $file, which links to $p");
 563                                                 render($file);
 564                                                 $rendered{$file}=1;
 565                                                 next FILE;
 566                                         }
 567                                 }
 568                         }
 569                 }
 570         }
 571
 572         # handle backlinks; if a page has added/removed links, update the
 573         # pages it links to
 574         # TODO: inefficient; pages may get rendered above and again here;
 575         # problem is the backlinks could be wrong in the first pass render
 576         # above
 577         if (%rendered) {
 578                 my %linkchanged;
 579                 foreach my $file (keys %rendered, @del) {
 580                         my $page=pagename($file);
 581                         if (exists $links{$page}) {
 582                                 foreach my $link (@{$links{$page}}) {
 583                                         $link=bestlink($page, $link);
 584                                         if (length $link &&
 585                                             ! exists $oldlinks{$page} ||
 586                                             ! grep { $_ eq $link } @{$oldlinks{$page}}) {
 587                                                 $linkchanged{$link}=1;
 588                                         }
 589                                 }
 590                         }
 591                         if (exists $oldlinks{$page}) {
 592                                 foreach my $link (@{$oldlinks{$page}}) {
 593                                         $link=bestlink($page, $link);
 594                                         if (length $link &&
 595                                             ! exists $links{$page} ||
 596                                             ! grep { $_ eq $link } @{$links{$page}}) {
 597                                                 $linkchanged{$link}=1;
 598                                         }
 599                                 }
 600                         }
 601                 }
 602                 foreach my $link (keys %linkchanged) {
 603                         my $linkfile=$pagesources{$link};
 604                         if (defined $linkfile) {
 605                                 debug("rendering $linkfile, to update its backlinks");
 606                                 render($linkfile);
 607                         }
 608                 }
 609         }
 610 } #}}}
 611
 612 # Generates a C wrapper program for running ikiwiki in a specific way.
 613 # The wrapper may be safely made suid.
 614 sub gen_wrapper ($$) { #{{{
 615         my ($svn, $rebuild)=@_;
 616
 617         eval q{use Cwd 'abs_path'};
 618         $srcdir=abs_path($srcdir);
 619         $destdir=abs_path($destdir);
 620         my $this=abs_path($0);
 621         if (! -x $this) {
 622                 error("$this doesn't seem to be executable");
 623         }
 624
 625         my @params=($srcdir, $templatedir, $destdir, "--wikiname=$wikiname");
 626         push @params, "--verbose" if $verbose;
 627         push @params, "--rebuild" if $rebuild;
 628         push @params, "--nosvn" if !$svn;
 629         push @params, "--cgi" if $cgi;
 630         push @params, "--url=$url" if $url;
 631         push @params, "--cgiurl=$cgiurl" if $cgiurl;
 632         push @params, "--historyurl=$historyurl" if $historyurl;
 633         push @params, "--anonok" if $anonok;
 634         my $params=join(" ", @params);
 635         my $call='';
 636         foreach my $p ($this, $this, @params) {
 637                 $call.=qq{"$p", };
 638         }
 639         $call.="NULL";
 640
 641         my @envsave;
 642         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
 643                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
 644                        HTTP_COOKIE} if $cgi;
 645         my $envsave="";
 646         foreach my $var (@envsave) {
 647                 $envsave.=<<"EOF"
 648         if ((s=getenv("$var")))
 649                 asprintf(&newenviron[i++], "%s=%s", "$var", s);
 650 EOF
 651         }
 652
 653         open(OUT, ">ikiwiki-wrap.c") || error("failed to write ikiwiki-wrap.c: $!");;
 654         print OUT <<"EOF";
 655 /* A wrapper for ikiwiki, can be safely made suid. */
 656 #define _GNU_SOURCE
 657 #include <stdio.h>
 658 #include <unistd.h>
 659 #include <stdlib.h>
 660 #include <string.h>
 661
 662 extern char **environ;
 663
 664 int main (int argc, char **argv) {
 665         /* Sanitize environment. */
 666         char *s;
 667         char *newenviron[$#envsave+3];
 668         int i=0;
 669 $envsave
 670         newenviron[i++]="HOME=$ENV{HOME}";
 671         newenviron[i]=NULL;
 672         environ=newenviron;
 673
 674         if (argc == 2 && strcmp(argv[1], "--params") == 0) {
 675                 printf("$params\\n");
 676                 exit(0);
 677         }
 678
 679         execl($call);
 680         perror("failed to run $this");
 681         exit(1);
 682 }
 683 EOF
 684         close OUT;
 685         if (system("gcc", "ikiwiki-wrap.c", "-o", "ikiwiki-wrap") != 0) {
 686                 error("failed to compile ikiwiki-wrap.c");
 687         }
 688         unlink("ikiwiki-wrap.c");
 689         print "successfully generated ikiwiki-wrap\n";
 690         exit 0;
 691 } #}}}
 692
 693 sub misctemplate ($$) { #{{{
 694         my $title=shift;
 695         my $pagebody=shift;
 696
 697         my $template=HTML::Template->new(
 698                 filename => "$templatedir/misc.tmpl"
 699         );
 700         $template->param(
 701                 title => $title,
 702                 indexlink => indexlink(),
 703                 wikiname => $wikiname,
 704                 pagebody => $pagebody,
 705         );
 706         return $template->output;
 707 }#}}}
 708
 709 sub cgi_recentchanges ($) { #{{{
 710         my $q=shift;
 711
 712         my $template=HTML::Template->new(
 713                 filename => "$templatedir/recentchanges.tmpl"
 714         );
 715         $template->param(
 716                 title => "RecentChanges",
 717                 indexlink => indexlink(),
 718                 wikiname => $wikiname,
 719                 changelog => [rcs_recentchanges(100)],
 720         );
 721         print $q->header, $template->output;
 722 } #}}}
 723
 724 sub userinfo_get ($$) { #{{{
 725         my $user=shift;
 726         my $field=shift;
 727
 728         eval q{use Storable};
 729         my $userdata=eval{ Storable::lock_retrieve("$srcdir/.ikiwiki/userdb") };
 730         if (! defined $userdata || ! ref $userdata ||
 731             ! exists $userdata->{$user} || ! ref $userdata->{$user}) {
 732                 return "";
 733         }
 734         return $userdata->{$user}->{$field};
 735 } #}}}
 736
 737 sub userinfo_set ($$) { #{{{
 738         my $user=shift;
 739         my $info=shift;
 740
 741         eval q{use Storable};
 742         my $userdata=eval{ Storable::lock_retrieve("$srcdir/.ikiwiki/userdb") };
 743         if (! defined $userdata || ! ref $userdata) {
 744                 $userdata={};
 745         }
 746         $userdata->{$user}=$info;
 747         my $oldmask=umask(077);
 748         my $ret=Storable::lock_store($userdata, "$srcdir/.ikiwiki/userdb");
 749         umask($oldmask);
 750         return $ret;
 751 } #}}}
 752
 753 sub cgi_signin ($$) { #{{{
 754         my $q=shift;
 755         my $session=shift;
 756
 757         eval q{use CGI::FormBuilder};
 758         my $form = CGI::FormBuilder->new(
 759                 title => "$wikiname signin",
 760                 fields => [qw(do page name password confirm_password email)],
 761                 header => 1,
 762                 method => 'POST',
 763                 validate => {
 764                         confirm_password => {
 765                                 perl => q{eq $form->field("password")},
 766                         },
 767                         email => 'EMAIL',
 768                 },
 769                 required => 'NONE',
 770                 javascript => 0,
 771                 params => $q,
 772                 action => $q->request_uri,
 773                 header => 0,
 774                 template => (-e "$templatedir/signin.tmpl" ? "$templatedir/signin.tmpl" : "")
 775         );
 776
 777         $form->field(name => "name", required => 0);
 778         $form->field(name => "do", type => "hidden");
 779         $form->field(name => "page", type => "hidden");
 780         $form->field(name => "password", type => "password", required => 0);
 781         $form->field(name => "confirm_password", type => "password", required => 0);
 782         $form->field(name => "email", required => 0);
 783         if ($q->param("do") ne "signin") {
 784                 $form->text("You need to log in before you can edit pages.");
 785         }
 786
 787         if ($form->submitted) {
 788                 # Set required fields based on how form was submitted.
 789                 my %required=(
 790                         "Login" => [qw(name password)],
 791                         "Register" => [qw(name password confirm_password email)],
 792                         "Mail Password" => [qw(name)],
 793                 );
 794                 foreach my $opt (@{$required{$form->submitted}}) {
 795                         $form->field(name => $opt, required => 1);
 796                 }
 797
 798                 # Validate password differently depending on how
 799                 # form was submitted.
 800                 if ($form->submitted eq 'Login') {
 801                         $form->field(
 802                                 name => "password",
 803                                 validate => sub {
 804                                         length $form->field("name") &&
 805                                         shift eq userinfo_get($form->field("name"), 'password');
 806                                 },
 807                         );
 808                         $form->field(name => "name", validate => '/^\w+$/');
 809                 }
 810                 else {
 811                         $form->field(name => "password", validate => 'VALUE');
 812                 }
 813                 # And make sure the entered name exists when logging
 814                 # in or sending email, and does not when registering.
 815                 if ($form->submitted eq 'Register') {
 816                         $form->field(
 817                                 name => "name",
 818                                 validate => sub {
 819                                         my $name=shift;
 820                                         length $name &&
 821                                         ! userinfo_get($name, "regdate");
 822                                 },
 823                         );
 824                 }
 825                 else {
 826                         $form->field(
 827                                 name => "name",
 828                                 validate => sub {
 829                                         my $name=shift;
 830                                         length $name &&
 831                                         userinfo_get($name, "regdate");
 832                                 },
 833                         );
 834                 }
 835         }
 836         else {
 837                 # First time settings.
 838                 $form->field(name => "name", comment => "use FirstnameLastName");
 839                 $form->field(name => "confirm_password", comment => "(only needed");
 840                 $form->field(name => "email",            comment => "for registration)");
 841                 if ($session->param("name")) {
 842                         $form->field(name => "name", value => $session->param("name"));
 843                 }
 844         }
 845
 846         if ($form->submitted && $form->validate) {
 847                 if ($form->submitted eq 'Login') {
 848                         $session->param("name", $form->field("name"));
 849                         if (defined $form->field("do") &&
 850                             $form->field("do") ne 'signin') {
 851                                 print $q->redirect(
 852                                         "$cgiurl?do=".$form->field("do").
 853                                         "&page=".$form->field("page"));
 854                         }
 855                         else {
 856                                 print $q->redirect($url);
 857                         }
 858                 }
 859                 elsif ($form->submitted eq 'Register') {
 860                         my $user_name=$form->field('name');
 861                         if (userinfo_set($user_name, {
 862                                            'email' => $form->field('email'),
 863                                            'password' => $form->field('password'),
 864                                            'regdate' => time
 865                                          })) {
 866                                 $form->field(name => "confirm_password", type => "hidden");
 867                                 $form->field(name => "email", type => "hidden");
 868                                 $form->text("Registration successful. Now you can Login.");
 869                                 print $session->header();
 870                                 print misctemplate($form->title, $form->render(submit => ["Login"]));
 871                         }
 872                         else {
 873                                 error("Error saving registration.");
 874                         }
 875                 }
 876                 elsif ($form->submitted eq 'Mail Password') {
 877                         my $user_name=$form->field("name");
 878                         my $template=HTML::Template->new(
 879                                 filename => "$templatedir/passwordmail.tmpl"
 880                         );
 881                         $template->param(
 882                                 user_name => $user_name,
 883                                 user_password => userinfo_get($user_name, "password"),
 884                                 wikiurl => $url,
 885                                 wikiname => $wikiname,
 886                                 REMOTE_ADDR => $ENV{REMOTE_ADDR},
 887                         );
 888
 889                         eval q{use Mail::Sendmail};
 890                         my ($fromhost) = $cgiurl =~ m!/([^/]+)!;
 891                         print STDERR "$< $> >>> $cgiurl ".(getpwuid($>))[0]."@".$fromhost."\n";
 892                         sendmail(
 893                                 To => userinfo_get($user_name, "email"),
 894                                 From => "$wikiname admin <".(getpwuid($>))[0]."@".$fromhost.">",
 895                                 Subject => "$wikiname information",
 896                                 Message => $template->output,
 897                         ) or error("Failed to send mail");
 898
 899                         $form->text("Your password has been emailed to you.");
 900                         $form->field(name => "name", required => 0);
 901                         print $session->header();
 902                         print misctemplate($form->title, $form->render(submit => ["Login", "Register", "Mail Password"]));
 903                 }
 904         }
 905         else {
 906                 print $session->header();
 907                 print misctemplate($form->title, $form->render(submit => ["Login", "Register", "Mail Password"]));
 908         }
 909 } #}}}
 910
 911 sub cgi_editpage ($$) { #{{{
 912         my $q=shift;
 913         my $session=shift;
 914
 915         eval q{use CGI::FormBuilder};
 916         my $form = CGI::FormBuilder->new(
 917                 fields => [qw(do from page content comments)],
 918                 header => 1,
 919                 method => 'POST',
 920                 validate => {
 921                         content => '/.+/',
 922                 },
 923                 required => [qw{content}],
 924                 javascript => 0,
 925                 params => $q,
 926                 action => $q->request_uri,
 927                 table => 0,
 928                 template => "$templatedir/editpage.tmpl"
 929         );
 930
 931         my ($page)=$form->param('page')=~/$wiki_file_regexp/;
 932         if (! defined $page || ! length $page || $page ne $q->param('page') ||
 933             $page=~/$wiki_file_prune_regexp/ || $page=~/^\//) {
 934                 error("bad page name");
 935         }
 936         $page=lc($page);
 937
 938         $form->field(name => "do", type => 'hidden');
 939         $form->field(name => "from", type => 'hidden');
 940         $form->field(name => "page", value => "$page", force => 1);
 941         $form->field(name => "comments", type => "text", size => 80);
 942         $form->field(name => "content", type => "textarea", rows => 20,
 943                 cols => 80);
 944
 945         if ($form->submitted eq "Cancel") {
 946                 print $q->redirect("$url/".htmlpage($page));
 947                 return;
 948         }
 949         if (! $form->submitted || ! $form->validate) {
 950                 if ($form->field("do") eq "create") {
 951                         if (exists $pagesources{lc($page)}) {
 952                                 # hmm, someone else made the page in the
 953                                 # meantime?
 954                                 print $q->redirect("$url/".htmlpage($page));
 955                                 return;
 956                         }
 957
 958                         my @page_locs;
 959                         my ($from)=$form->param('from')=~/$wiki_file_regexp/;
 960                         if (! defined $from || ! length $from ||
 961                             $from ne $form->param('from') ||
 962                             $from=~/$wiki_file_prune_regexp/ || $from=~/^\//) {
 963                                 @page_locs=$page;
 964                         }
 965                         else {
 966                                 my $dir=$from."/";
 967                                 $dir=~s![^/]+/$!!;
 968                                 push @page_locs, $dir.$page;
 969                                 push @page_locs, "$from/$page";
 970                                 while (length $dir) {
 971                                         $dir=~s![^/]+/$!!;
 972                                         push @page_locs, $dir.$page;
 973                                 }
 974                         }
 975
 976                         $form->tmpl_param("page_select", 1);
 977                         $form->field(name => "page", type => 'select',
 978                                 options => \@page_locs);
 979                         $form->title("creating $page");
 980                 }
 981                 elsif ($form->field("do") eq "edit") {
 982                         my $content="";
 983                         if (exists $pagesources{lc($page)}) {
 984                                 $content=readfile("$srcdir/$pagesources{lc($page)}");
 985                                 $content=~s/\n/\r\n/g;
 986                         }
 987                         $form->tmpl_param("page_select", 0);
 988                         $form->field(name => "content", value => $content,
 989                                 force => 1);
 990                         $form->field(name => "page", type => 'hidden');
 991                         $form->title("editing $page");
 992                 }
 993
 994                 $form->tmpl_param("can_commit", $svn);
 995                 $form->tmpl_param("indexlink", indexlink());
 996                 print $form->render(submit => ["Save Page", "Cancel"]);
 997         }
 998         else {
 999                 # save page
1000                 my $file=$page.$default_pagetype;
1001                 my $newfile=1;
1002                 if (exists $pagesources{lc($page)}) {
1003                         $file=$pagesources{lc($page)};
1004                         $newfile=0;
1005                 }
1006
1007                 my $content=$form->field('content');
1008                 $content=~s/\r\n/\n/g;
1009                 $content=~s/\r/\n/g;
1010                 writefile("$srcdir/$file", $content);
1011
1012                 my $message="web commit ";
1013                 if ($session->param("name")) {
1014                         $message.="by ".$session->param("name");
1015                 }
1016                 else {
1017                         $message.="from $ENV{REMOTE_ADDR}";
1018                 }
1019                 if (defined $form->field('comments') &&
1020                     length $form->field('comments')) {
1021                         $message.=": ".$form->field('comments');
1022                 }
1023
1024                 if ($svn) {
1025                         if ($newfile) {
1026                                 rcs_add($file);
1027                         }
1028                         # presumably the commit will trigger an update
1029                         # of the wiki
1030                         rcs_commit($message);
1031                 }
1032                 else {
1033                         refresh();
1034                 }
1035
1036                 print $q->redirect("$url/".htmlpage($page));
1037         }
1038 } #}}}
1039
1040 sub cgi () { #{{{
1041         eval q{use CGI};
1042         eval q{use CGI::Session};
1043
1044         my $q=CGI->new;
1045
1046         my $do=$q->param('do');
1047         if (! defined $do || ! length $do) {
1048                 error("\"do\" parameter missing");
1049         }
1050
1051         # This does not need a session.
1052         if ($do eq 'recentchanges') {
1053                 cgi_recentchanges($q);
1054                 return;
1055         }
1056
1057         CGI::Session->name("ikiwiki_session");
1058
1059         my $oldmask=umask(077);
1060         my $session = CGI::Session->new("driver:db_file", $q,
1061                 { FileName => "$srcdir/.ikiwiki/sessions.db" });
1062         umask($oldmask);
1063
1064         # Everything below this point needs the user to be signed in.
1065         if ((! $anonok && ! defined $session->param("name") ||
1066                 ! userinfo_get($session->param("name"), "regdate")) || $do eq 'signin') {
1067                 cgi_signin($q, $session);
1068
1069                 # Force session flush with safe umask.
1070                 my $oldmask=umask(077);
1071                 $session->flush;
1072                 umask($oldmask);
1073
1074                 return;
1075         }
1076
1077         if ($do eq 'create' || $do eq 'edit') {
1078                 cgi_editpage($q, $session);
1079         }
1080         else {
1081                 error("unknown do parameter");
1082         }
1083 } #}}}
1084
1085 # main {{{
1086 my $rebuild=0;
1087 my $wrapper=0;
1088 if (grep /^-/, @ARGV) {
1089         eval {use Getopt::Long};
1090         GetOptions(
1091                 "wikiname=s" => \$wikiname,
1092                 "verbose|v" => \$verbose,
1093                 "rebuild" => \$rebuild,
1094                 "wrapper" => \$wrapper,
1095                 "svn!" => \$svn,
1096                 "anonok!" => \$anonok,
1097                 "cgi" => \$cgi,
1098                 "url=s" => \$url,
1099                 "cgiurl=s" => \$cgiurl,
1100                 "historyurl=s" => \$historyurl,
1101         ) || usage();
1102 }
1103 usage() unless @ARGV == 3;
1104 ($srcdir) = possibly_foolish_untaint(shift);
1105 ($templatedir) = possibly_foolish_untaint(shift);
1106 ($destdir) = possibly_foolish_untaint(shift);
1107
1108 if ($cgi && ! length $url) {
1109         error("Must specify url to wiki with --url when using --cgi");
1110 }
1111
1112 gen_wrapper($svn, $rebuild) if $wrapper;
1113 memoize('pagename');
1114 memoize('bestlink');
1115 loadindex() unless $rebuild;
1116 if ($cgi) {
1117         cgi();
1118 }
1119 else {
1120         rcs_update() if $svn;
1121         refresh();
1122         saveindex();
1123 }
1124 #}}}