ikiwiki

   1 #!/usr/bin/perl -T
   2 $ENV{PATH}="/usr/local/bin:/usr/bin:/bin";
   3
   4 use warnings;
   5 use strict;
   6 use Memoize;
   7 use File::Spec;
   8 use HTML::Template;
   9 use Getopt::Long;
  10
  11 my (%links, %oldlinks, %oldpagemtime, %renderedfiles, %pagesources);
  12
  13 my %config=( #{{{
  14         wiki_file_prune_regexp => qr{((^|/).svn/|\.\.|^\.|\/\.|\.html?$)},
  15         wiki_link_regexp => qr/\[\[([^\s]+)\]\]/,
  16         wiki_file_regexp => qr/(^[-A-Za-z0-9_.:\/+]+$)/,
  17         verbose => 0,
  18         wikiname => "wiki",
  19         default_pageext => ".mdwn",
  20         cgi => 0,
  21         url => "",
  22         cgiurl => "",
  23         historyurl => "",
  24         svn => 1,
  25         anonok => 0,
  26         rebuild => 0,
  27         wrapper => 0,
  28         srcdir => undef,
  29         destdir => undef,
  30         templatedir => undef,
  31 ); #}}}
  32
  33 GetOptions( #{{{
  34         "wikiname=s" => \$config{wikiname},
  35         "verbose|v!" => \$config{verbose},
  36         "rebuild!" => \$config{rebuild},
  37         "wrapper!" => \$config{wrapper},
  38         "svn!" => \$config{svn},
  39         "anonok!" => \$config{anonok},
  40         "cgi!" => \$config{cgi},
  41         "url=s" => \$config{url},
  42         "cgiurl=s" => \$config{cgiurl},
  43         "historyurl=s" => \$config{historyurl},
  44         "exclude=s@" => sub {
  45                 $config{wiki_file_prune_regexp}=qr/$config{wiki_file_prune_regexp}|$_[1]/;
  46         },
  47 ) || usage();
  48
  49 usage() unless @ARGV == 3;
  50 $config{srcdir} = possibly_foolish_untaint(shift);
  51 $config{templatedir} = possibly_foolish_untaint(shift);
  52 $config{destdir} = possibly_foolish_untaint(shift);
  53 if ($config{cgi} && ! length $config{url}) {
  54         error("Must specify url to wiki with --url when using --cgi");
  55 } #}}}
  56
  57 sub usage { #{{{
  58         die "usage: ikiwiki [options] source templates dest\n";
  59 } #}}}
  60
  61 sub error { #{{{
  62         if ($config{cgi}) {
  63                 print "Content-type: text/html\n\n";
  64                 print misctemplate("Error", "<p>Error: @_</p>");
  65                 exit 1;
  66         }
  67         else {
  68                 die @_;
  69         }
  70 } #}}}
  71
  72 sub debug ($) { #{{{
  73         return unless $config{verbose};
  74         if (! $config{cgi}) {
  75                 print "@_\n";
  76         }
  77         else {
  78                 print STDERR "@_\n";
  79         }
  80 } #}}}
  81
  82 sub mtime ($) { #{{{
  83         my $page=shift;
  84
  85         return (stat($page))[9];
  86 } #}}}
  87
  88 sub possibly_foolish_untaint { #{{{
  89         my $tainted=shift;
  90         my ($untainted)=$tainted=~/(.*)/;
  91         return $untainted;
  92 } #}}}
  93
  94 sub basename ($) { #{{{
  95         my $file=shift;
  96
  97         $file=~s!.*/!!;
  98         return $file;
  99 } #}}}
 100
 101 sub dirname ($) { #{{{
 102         my $file=shift;
 103
 104         $file=~s!/?[^/]+$!!;
 105         return $file;
 106 } #}}}
 107
 108 sub pagetype ($) { #{{{
 109         my $page=shift;
 110
 111         if ($page =~ /\.mdwn$/) {
 112                 return ".mdwn";
 113         }
 114         else {
 115                 return "unknown";
 116         }
 117 } #}}}
 118
 119 sub pagename ($) { #{{{
 120         my $file=shift;
 121
 122         my $type=pagetype($file);
 123         my $page=$file;
 124         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
 125         return $page;
 126 } #}}}
 127
 128 sub htmlpage ($) { #{{{
 129         my $page=shift;
 130
 131         return $page.".html";
 132 } #}}}
 133
 134 sub readfile ($) { #{{{
 135         my $file=shift;
 136
 137         local $/=undef;
 138         open (IN, "$file") || error("failed to read $file: $!");
 139         my $ret=<IN>;
 140         close IN;
 141         return $ret;
 142 } #}}}
 143
 144 sub writefile ($$) { #{{{
 145         my $file=shift;
 146         my $content=shift;
 147
 148         my $dir=dirname($file);
 149         if (! -d $dir) {
 150                 my $d="";
 151                 foreach my $s (split(m!/+!, $dir)) {
 152                         $d.="$s/";
 153                         if (! -d $d) {
 154                                 mkdir($d) || error("failed to create directory $d: $!");
 155                         }
 156                 }
 157         }
 158
 159         open (OUT, ">$file") || error("failed to write $file: $!");
 160         print OUT $content;
 161         close OUT;
 162 } #}}}
 163
 164 sub findlinks ($) { #{{{
 165         my $content=shift;
 166
 167         my @links;
 168         while ($content =~ /$config{wiki_link_regexp}/g) {
 169                 push @links, lc($1);
 170         }
 171         return @links;
 172 } #}}}
 173
 174 sub bestlink ($$) { #{{{
 175         # Given a page and the text of a link on the page, determine which
 176         # existing page that link best points to. Prefers pages under a
 177         # subdirectory with the same name as the source page, failing that
 178         # goes down the directory tree to the base looking for matching
 179         # pages.
 180         my $page=shift;
 181         my $link=lc(shift);
 182
 183         my $cwd=$page;
 184         do {
 185                 my $l=$cwd;
 186                 $l.="/" if length $l;
 187                 $l.=$link;
 188
 189                 if (exists $links{$l}) {
 190                         #debug("for $page, \"$link\", use $l");
 191                         return $l;
 192                 }
 193         } while $cwd=~s!/?[^/]+$!!;
 194
 195         #print STDERR "warning: page $page, broken link: $link\n";
 196         return "";
 197 } #}}}
 198
 199 sub isinlinableimage ($) { #{{{
 200         my $file=shift;
 201
 202         $file=~/\.(png|gif|jpg|jpeg)$/;
 203 } #}}}
 204
 205 sub htmllink { #{{{
 206         my $page=shift;
 207         my $link=shift;
 208         my $noimageinline=shift; # don't turn links into inline html images
 209         my $createsubpage=shift; # force creation of a subpage if page DNE
 210
 211         my $bestlink=bestlink($page, $link);
 212
 213         return $link if length $bestlink && $page eq $bestlink;
 214
 215         # TODO BUG: %renderedfiles may not have it, if the linked to page
 216         # was also added and isn't yet rendered! Note that this bug is
 217         # masked by the bug mentioned below that makes all new files
 218         # be rendered twice.
 219         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 220                 $bestlink=htmlpage($bestlink);
 221         }
 222         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 223                 if (! $createsubpage) {
 224                         return "<a href=\"$config{cgiurl}?do=create&page=$link&from=$page\">?</a>$link"
 225                 }
 226                 else {
 227                         return "<a href=\"$config{cgiurl}?do=create&page=$page/$link\">?</a>$link"
 228                 }
 229         }
 230
 231         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 232
 233         if (! $noimageinline && isinlinableimage($bestlink)) {
 234                 return "<img src=\"$bestlink\">";
 235         }
 236         return "<a href=\"$bestlink\">$link</a>";
 237 } #}}}
 238
 239 sub linkify ($$) { #{{{
 240         my $content=shift;
 241         my $file=shift;
 242
 243         $content =~ s/$config{wiki_link_regexp}/htmllink(pagename($file), $1)/eg;
 244
 245         return $content;
 246 } #}}}
 247
 248 sub htmlize ($$) { #{{{
 249         my $type=shift;
 250         my $content=shift;
 251
 252         if (! $INC{"/usr/bin/markdown"}) {
 253                 no warnings 'once';
 254                 $blosxom::version="is a proper perl module too much to ask?";
 255                 use warnings 'all';
 256                 do "/usr/bin/markdown";
 257         }
 258
 259         if ($type eq '.mdwn') {
 260                 return Markdown::Markdown($content);
 261         }
 262         else {
 263                 error("htmlization of $type not supported");
 264         }
 265 } #}}}
 266
 267 sub backlinks ($) { #{{{
 268         my $page=shift;
 269
 270         my @links;
 271         foreach my $p (keys %links) {
 272                 next if bestlink($page, $p) eq $page;
 273                 if (grep { length $_ && bestlink($p, $_) eq $page } @{$links{$p}}) {
 274                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
 275
 276                         # Trim common dir prefixes from both pages.
 277                         my $p_trimmed=$p;
 278                         my $page_trimmed=$page;
 279                         my $dir;
 280                         1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
 281                                 defined $dir &&
 282                                 $p_trimmed=~s/^\Q$dir\E// &&
 283                                 $page_trimmed=~s/^\Q$dir\E//;
 284
 285                         push @links, { url => $href, page => $p_trimmed };
 286                 }
 287         }
 288
 289         return sort { $a->{page} cmp $b->{page} } @links;
 290 } #}}}
 291
 292 sub parentlinks ($) { #{{{
 293         my $page=shift;
 294
 295         my @ret;
 296         my $pagelink="";
 297         my $path="";
 298         my $skip=1;
 299         foreach my $dir (reverse split("/", $page)) {
 300                 if (! $skip) {
 301                         unshift @ret, { url => "$path$dir.html", page => $dir };
 302                 }
 303                 else {
 304                         $skip=0;
 305                 }
 306                 $path.="../";
 307         }
 308         unshift @ret, { url => $path , page => $config{wikiname} };
 309         return @ret;
 310 } #}}}
 311
 312 sub indexlink () { #{{{
 313         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 314 } #}}}
 315
 316 sub finalize ($$) { #{{{
 317         my $content=shift;
 318         my $page=shift;
 319
 320         my $title=basename($page);
 321         $title=~s/_/ /g;
 322
 323         my $template=HTML::Template->new(blind_cache => 1,
 324                 filename => "$config{templatedir}/page.tmpl");
 325
 326         if (length $config{cgiurl}) {
 327                 $template->param(editurl => "$config{cgiurl}?do=edit&page=$page");
 328                 if ($config{svn}) {
 329                         $template->param(recentchangesurl => "$config{cgiurl}?do=recentchanges");
 330                 }
 331         }
 332
 333         if (length $config{historyurl}) {
 334                 my $u=$config{historyurl};
 335                 $u=~s/\[\[\]\]/$pagesources{$page}/g;
 336                 $template->param(historyurl => $u);
 337         }
 338
 339         $template->param(
 340                 title => $title,
 341                 wikiname => $config{wikiname},
 342                 parentlinks => [parentlinks($page)],
 343                 content => $content,
 344                 backlinks => [backlinks($page)],
 345                 discussionlink => htmllink($page, "Discussion", 1, 1),
 346         );
 347
 348         return $template->output;
 349 } #}}}
 350
 351 sub check_overwrite ($$) { #{{{
 352         # Important security check. Make sure to call this before saving
 353         # any files to the source directory.
 354         my $dest=shift;
 355         my $src=shift;
 356
 357         if (! exists $renderedfiles{$src} && -e $dest && ! $config{rebuild}) {
 358                 error("$dest exists and was rendered from ".
 359                         join(" ",(grep { $renderedfiles{$_} eq $dest } keys
 360                                 %renderedfiles)).
 361                         ", not from $src before not overwriting");
 362         }
 363 } #}}}
 364
 365 sub render ($) { #{{{
 366         my $file=shift;
 367
 368         my $type=pagetype($file);
 369         my $content=readfile("$config{srcdir}/$file");
 370         if ($type ne 'unknown') {
 371                 my $page=pagename($file);
 372
 373                 $links{$page}=[findlinks($content)];
 374
 375                 $content=linkify($content, $file);
 376                 $content=htmlize($type, $content);
 377                 $content=finalize($content, $page);
 378
 379                 check_overwrite("$config{destdir}/".htmlpage($page), $page);
 380                 writefile("$config{destdir}/".htmlpage($page), $content);
 381                 $oldpagemtime{$page}=time;
 382                 $renderedfiles{$page}=htmlpage($page);
 383         }
 384         else {
 385                 $links{$file}=[];
 386                 check_overwrite("$config{destdir}/$file", $file);
 387                 writefile("$config{destdir}/$file", $content);
 388                 $oldpagemtime{$file}=time;
 389                 $renderedfiles{$file}=$file;
 390         }
 391 } #}}}
 392
 393 sub loadindex () { #{{{
 394         open (IN, "$config{srcdir}/.ikiwiki/index") || return;
 395         while (<IN>) {
 396                 $_=possibly_foolish_untaint($_);
 397                 chomp;
 398                 my ($mtime, $file, $rendered, @links)=split(' ', $_);
 399                 my $page=pagename($file);
 400                 $pagesources{$page}=$file;
 401                 $oldpagemtime{$page}=$mtime;
 402                 $oldlinks{$page}=[@links];
 403                 $links{$page}=[@links];
 404                 $renderedfiles{$page}=$rendered;
 405         }
 406         close IN;
 407 } #}}}
 408
 409 sub saveindex () { #{{{
 410         if (! -d "$config{srcdir}/.ikiwiki") {
 411                 mkdir("$config{srcdir}/.ikiwiki");
 412         }
 413         open (OUT, ">$config{srcdir}/.ikiwiki/index") || error("cannot write to index: $!");
 414         foreach my $page (keys %oldpagemtime) {
 415                 print OUT "$oldpagemtime{$page} $pagesources{$page} $renderedfiles{$page} ".
 416                         join(" ", @{$links{$page}})."\n"
 417                                 if $oldpagemtime{$page};
 418         }
 419         close OUT;
 420 } #}}}
 421
 422 sub rcs_update () { #{{{
 423         if (-d "$config{srcdir}/.svn") {
 424                 if (system("svn", "update", "--quiet", $config{srcdir}) != 0) {
 425                         warn("svn update failed\n");
 426                 }
 427         }
 428 } #}}}
 429
 430 sub rcs_commit ($) { #{{{
 431         my $message=shift;
 432
 433         if (-d "$config{srcdir}/.svn") {
 434                 if (system("svn", "commit", "--quiet", "-m",
 435                            possibly_foolish_untaint($message),
 436                            $config{srcdir}) != 0) {
 437                         warn("svn commit failed\n");
 438                 }
 439         }
 440 } #}}}
 441
 442 sub rcs_add ($) { #{{{
 443         my $file=shift;
 444
 445         if (-d "$config{srcdir}/.svn") {
 446                 my $parent=dirname($file);
 447                 while (! -d "$config{srcdir}/$parent/.svn") {
 448                         $file=$parent;
 449                         $parent=dirname($file);
 450                 }
 451
 452                 if (system("svn", "add", "--quiet", "$config{srcdir}/$file") != 0) {
 453                         warn("svn add failed\n");
 454                 }
 455         }
 456 } #}}}
 457
 458 sub rcs_recentchanges ($) { #{{{
 459         my $num=shift;
 460         my @ret;
 461
 462         eval q{use Date::Parse};
 463         eval q{use Time::Duration};
 464
 465         if (-d "$config{srcdir}/.svn") {
 466                 my $info=`LANG=C svn info $config{srcdir}`;
 467                 my ($svn_url)=$info=~/^URL: (.*)$/m;
 468
 469                 # FIXME: currently assumes that the wiki is somewhere
 470                 # under trunk in svn, doesn't support other layouts.
 471                 my ($svn_base)=$svn_url=~m!(/trunk(?:/.*)?)$!;
 472
 473                 my $div=qr/^--------------------+$/;
 474                 my $infoline=qr/^r(\d+)\s+\|\s+([^\s]+)\s+\|\s+(\d+-\d+-\d+\s+\d+:\d+:\d+\s+[-+]?\d+).*/;
 475                 my $state='start';
 476                 my ($rev, $user, $when, @pages, @message);
 477                 foreach (`LANG=C svn log -v '$svn_url'`) {
 478                         chomp;
 479                         if ($state eq 'start' && /$div/) {
 480                                 $state='header';
 481                         }
 482                         elsif ($state eq 'header' && /$infoline/) {
 483                                 $rev=$1;
 484                                 $user=$2;
 485                                 $when=concise(ago(time - str2time($3)));
 486                         }
 487                         elsif ($state eq 'header' && /^\s+[A-Z]\s+\Q$svn_base\E\/(.+)$/) {
 488                                 push @pages, { link => htmllink("", pagename($1), 1) }
 489                                         if length $1;
 490                         }
 491                         elsif ($state eq 'header' && /^$/) {
 492                                 $state='body';
 493                         }
 494                         elsif ($state eq 'body' && /$div/) {
 495                                 my $committype="web";
 496                                 if (defined $message[0] &&
 497                                     $message[0]->{line}=~/^web commit by (\w+):?(.*)/) {
 498                                         $user="$1";
 499                                         $message[0]->{line}=$2;
 500                                 }
 501                                 else {
 502                                         $committype="svn";
 503                                 }
 504
 505                                 push @ret, { rev => $rev,
 506                                         user => htmllink("", $user, 1),
 507                                         committype => $committype,
 508                                         when => $when, message => [@message],
 509                                         pages => [@pages] } if @pages;
 510                                 return @ret if @ret >= $num;
 511
 512                                 $state='header';
 513                                 $rev=$user=$when=undef;
 514                                 @pages=@message=();
 515                         }
 516                         elsif ($state eq 'body') {
 517                                 push @message, {line => $_},
 518                         }
 519                 }
 520         }
 521
 522         return @ret;
 523 } #}}}
 524
 525 sub prune ($) { #{{{
 526         my $file=shift;
 527
 528         unlink($file);
 529         my $dir=dirname($file);
 530         while (rmdir($dir)) {
 531                 $dir=dirname($dir);
 532         }
 533 } #}}}
 534
 535 sub refresh () { #{{{
 536         # Find existing pages.
 537         my %exists;
 538         my @files;
 539
 540         eval q{use File::Find};
 541         find({
 542                 no_chdir => 1,
 543                 wanted => sub {
 544                         if (/$config{wiki_file_prune_regexp}/) {
 545                                 no warnings 'once';
 546                                 $File::Find::prune=1;
 547                                 use warnings "all";
 548                         }
 549                         elsif (! -d $_) {
 550                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 551                                 if (! defined $f) {
 552                                         warn("skipping bad filename $_\n");
 553                                 }
 554                                 else {
 555                                         $f=~s/^\Q$config{srcdir}\E\/?//;
 556                                         push @files, $f;
 557                                         $exists{pagename($f)}=1;
 558                                 }
 559                         }
 560                 },
 561         }, $config{srcdir});
 562
 563         my %rendered;
 564
 565         # check for added or removed pages
 566         my @add;
 567         foreach my $file (@files) {
 568                 my $page=pagename($file);
 569                 if (! $oldpagemtime{$page}) {
 570                         debug("new page $page");
 571                         push @add, $file;
 572                         $links{$page}=[];
 573                         $pagesources{$page}=$file;
 574                 }
 575         }
 576         my @del;
 577         foreach my $page (keys %oldpagemtime) {
 578                 if (! $exists{$page}) {
 579                         debug("removing old page $page");
 580                         push @del, $renderedfiles{$page};
 581                         prune($config{destdir}."/".$renderedfiles{$page});
 582                         delete $renderedfiles{$page};
 583                         $oldpagemtime{$page}=0;
 584                         delete $pagesources{$page};
 585                 }
 586         }
 587
 588         # render any updated files
 589         foreach my $file (@files) {
 590                 my $page=pagename($file);
 591
 592                 if (! exists $oldpagemtime{$page} ||
 593                     mtime("$config{srcdir}/$file") > $oldpagemtime{$page}) {
 594                         debug("rendering changed file $file");
 595                         render($file);
 596                         $rendered{$file}=1;
 597                 }
 598         }
 599
 600         # if any files were added or removed, check to see if each page
 601         # needs an update due to linking to them
 602         # TODO: inefficient; pages may get rendered above and again here;
 603         # problem is the bestlink may have changed and we won't know until
 604         # now
 605         if (@add || @del) {
 606 FILE:           foreach my $file (@files) {
 607                         my $page=pagename($file);
 608                         foreach my $f (@add, @del) {
 609                                 my $p=pagename($f);
 610                                 foreach my $link (@{$links{$page}}) {
 611                                         if (bestlink($page, $link) eq $p) {
 612                                                 debug("rendering $file, which links to $p");
 613                                                 render($file);
 614                                                 $rendered{$file}=1;
 615                                                 next FILE;
 616                                         }
 617                                 }
 618                         }
 619                 }
 620         }
 621
 622         # handle backlinks; if a page has added/removed links, update the
 623         # pages it links to
 624         # TODO: inefficient; pages may get rendered above and again here;
 625         # problem is the backlinks could be wrong in the first pass render
 626         # above
 627         if (%rendered) {
 628                 my %linkchanged;
 629                 foreach my $file (keys %rendered, @del) {
 630                         my $page=pagename($file);
 631                         if (exists $links{$page}) {
 632                                 foreach my $link (@{$links{$page}}) {
 633                                         $link=bestlink($page, $link);
 634                                         if (length $link &&
 635                                             ! exists $oldlinks{$page} ||
 636                                             ! grep { $_ eq $link } @{$oldlinks{$page}}) {
 637                                                 $linkchanged{$link}=1;
 638                                         }
 639                                 }
 640                         }
 641                         if (exists $oldlinks{$page}) {
 642                                 foreach my $link (@{$oldlinks{$page}}) {
 643                                         $link=bestlink($page, $link);
 644                                         if (length $link &&
 645                                             ! exists $links{$page} ||
 646                                             ! grep { $_ eq $link } @{$links{$page}}) {
 647                                                 $linkchanged{$link}=1;
 648                                         }
 649                                 }
 650                         }
 651                 }
 652                 foreach my $link (keys %linkchanged) {
 653                         my $linkfile=$pagesources{$link};
 654                         if (defined $linkfile) {
 655                                 debug("rendering $linkfile, to update its backlinks");
 656                                 render($linkfile);
 657                         }
 658                 }
 659         }
 660 } #}}}
 661
 662 sub gen_wrapper () { #{{{
 663         eval q{use Cwd 'abs_path'};
 664         $config{srcdir}=abs_path($config{srcdir});
 665         $config{destdir}=abs_path($config{destdir});
 666         my $this=abs_path($0);
 667         if (! -x $this) {
 668                 error("$this doesn't seem to be executable");
 669         }
 670
 671         my @params=($config{srcdir}, $config{templatedir}, $config{destdir},
 672                 "--wikiname=$config{wikiname}");
 673         push @params, "--verbose" if $config{verbose};
 674         push @params, "--rebuild" if $config{rebuild};
 675         push @params, "--nosvn" if !$config{svn};
 676         push @params, "--cgi" if $config{cgi};
 677         push @params, "--url=$config{url}" if length $config{url};
 678         push @params, "--cgiurl=$config{cgiurl}" if length $config{cgiurl};
 679         push @params, "--historyurl=$config{historyurl}" if length $config{historyurl};
 680         push @params, "--anonok" if $config{anonok};
 681         my $params=join(" ", map { "\'$_\'" } @params);
 682         my $call='';
 683         foreach my $p ($this, $this, @params) {
 684                 $call.=qq{"$p", };
 685         }
 686         $call.="NULL";
 687
 688         my @envsave;
 689         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
 690                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
 691                        HTTP_COOKIE} if $config{cgi};
 692         my $envsave="";
 693         foreach my $var (@envsave) {
 694                 $envsave.=<<"EOF"
 695         if ((s=getenv("$var")))
 696                 asprintf(&newenviron[i++], "%s=%s", "$var", s);
 697 EOF
 698         }
 699
 700         open(OUT, ">ikiwiki-wrap.c") || error("failed to write ikiwiki-wrap.c: $!");;
 701         print OUT <<"EOF";
 702 /* A wrapper for ikiwiki, can be safely made suid. */
 703 #define _GNU_SOURCE
 704 #include <stdio.h>
 705 #include <unistd.h>
 706 #include <stdlib.h>
 707 #include <string.h>
 708
 709 extern char **environ;
 710
 711 int main (int argc, char **argv) {
 712         /* Sanitize environment. */
 713         char *s;
 714         char *newenviron[$#envsave+3];
 715         int i=0;
 716 $envsave
 717         newenviron[i++]="HOME=$ENV{HOME}";
 718         newenviron[i]=NULL;
 719         environ=newenviron;
 720
 721         if (argc == 2 && strcmp(argv[1], "--params") == 0) {
 722                 printf("$params\\n");
 723                 exit(0);
 724         }
 725
 726         execl($call);
 727         perror("failed to run $this");
 728         exit(1);
 729 }
 730 EOF
 731         close OUT;
 732         if (system("gcc", "ikiwiki-wrap.c", "-o", "ikiwiki-wrap") != 0) {
 733                 error("failed to compile ikiwiki-wrap.c");
 734         }
 735         unlink("ikiwiki-wrap.c");
 736         print "successfully generated ikiwiki-wrap\n";
 737         exit 0;
 738 } #}}}
 739
 740 sub misctemplate ($$) { #{{{
 741         my $title=shift;
 742         my $pagebody=shift;
 743
 744         my $template=HTML::Template->new(
 745                 filename => "$config{templatedir}/misc.tmpl"
 746         );
 747         $template->param(
 748                 title => $title,
 749                 indexlink => indexlink(),
 750                 wikiname => $config{wikiname},
 751                 pagebody => $pagebody,
 752         );
 753         return $template->output;
 754 }#}}}
 755
 756 sub cgi_recentchanges ($) { #{{{
 757         my $q=shift;
 758
 759         my $template=HTML::Template->new(
 760                 filename => "$config{templatedir}/recentchanges.tmpl"
 761         );
 762         $template->param(
 763                 title => "RecentChanges",
 764                 indexlink => indexlink(),
 765                 wikiname => $config{wikiname},
 766                 changelog => [rcs_recentchanges(100)],
 767         );
 768         print $q->header, $template->output;
 769 } #}}}
 770
 771 sub userinfo_get ($$) { #{{{
 772         my $user=shift;
 773         my $field=shift;
 774
 775         eval q{use Storable};
 776         my $userdata=eval{ Storable::lock_retrieve("$config{srcdir}/.ikiwiki/userdb") };
 777         if (! defined $userdata || ! ref $userdata ||
 778             ! exists $userdata->{$user} || ! ref $userdata->{$user}) {
 779                 return "";
 780         }
 781         return $userdata->{$user}->{$field};
 782 } #}}}
 783
 784 sub userinfo_set ($$) { #{{{
 785         my $user=shift;
 786         my $info=shift;
 787
 788         eval q{use Storable};
 789         my $userdata=eval{ Storable::lock_retrieve("$config{srcdir}/.ikiwiki/userdb") };
 790         if (! defined $userdata || ! ref $userdata) {
 791                 $userdata={};
 792         }
 793         $userdata->{$user}=$info;
 794         my $oldmask=umask(077);
 795         my $ret=Storable::lock_store($userdata, "$config{srcdir}/.ikiwiki/userdb");
 796         umask($oldmask);
 797         return $ret;
 798 } #}}}
 799
 800 sub cgi_signin ($$) { #{{{
 801         my $q=shift;
 802         my $session=shift;
 803
 804         eval q{use CGI::FormBuilder};
 805         my $form = CGI::FormBuilder->new(
 806                 title => "$config{wikiname} signin",
 807                 fields => [qw(do page from name password confirm_password email)],
 808                 header => 1,
 809                 method => 'POST',
 810                 validate => {
 811                         confirm_password => {
 812                                 perl => q{eq $form->field("password")},
 813                         },
 814                         email => 'EMAIL',
 815                 },
 816                 required => 'NONE',
 817                 javascript => 0,
 818                 params => $q,
 819                 action => $q->request_uri,
 820                 header => 0,
 821                 template => (-e "$config{templatedir}/signin.tmpl" ?
 822                               "$config{templatedir}/signin.tmpl" : "")
 823         );
 824
 825         $form->field(name => "name", required => 0);
 826         $form->field(name => "do", type => "hidden");
 827         $form->field(name => "page", type => "hidden");
 828         $form->field(name => "from", type => "hidden");
 829         $form->field(name => "password", type => "password", required => 0);
 830         $form->field(name => "confirm_password", type => "password", required => 0);
 831         $form->field(name => "email", required => 0);
 832         if ($q->param("do") ne "signin") {
 833                 $form->text("You need to log in before you can edit pages.");
 834         }
 835
 836         if ($form->submitted) {
 837                 # Set required fields based on how form was submitted.
 838                 my %required=(
 839                         "Login" => [qw(name password)],
 840                         "Register" => [qw(name password confirm_password email)],
 841                         "Mail Password" => [qw(name)],
 842                 );
 843                 foreach my $opt (@{$required{$form->submitted}}) {
 844                         $form->field(name => $opt, required => 1);
 845                 }
 846
 847                 # Validate password differently depending on how
 848                 # form was submitted.
 849                 if ($form->submitted eq 'Login') {
 850                         $form->field(
 851                                 name => "password",
 852                                 validate => sub {
 853                                         length $form->field("name") &&
 854                                         shift eq userinfo_get($form->field("name"), 'password');
 855                                 },
 856                         );
 857                         $form->field(name => "name", validate => '/^\w+$/');
 858                 }
 859                 else {
 860                         $form->field(name => "password", validate => 'VALUE');
 861                 }
 862                 # And make sure the entered name exists when logging
 863                 # in or sending email, and does not when registering.
 864                 if ($form->submitted eq 'Register') {
 865                         $form->field(
 866                                 name => "name",
 867                                 validate => sub {
 868                                         my $name=shift;
 869                                         length $name &&
 870                                         ! userinfo_get($name, "regdate");
 871                                 },
 872                         );
 873                 }
 874                 else {
 875                         $form->field(
 876                                 name => "name",
 877                                 validate => sub {
 878                                         my $name=shift;
 879                                         length $name &&
 880                                         userinfo_get($name, "regdate");
 881                                 },
 882                         );
 883                 }
 884         }
 885         else {
 886                 # First time settings.
 887                 $form->field(name => "name", comment => "use FirstnameLastName");
 888                 $form->field(name => "confirm_password", comment => "(only needed");
 889                 $form->field(name => "email",            comment => "for registration)");
 890                 if ($session->param("name")) {
 891                         $form->field(name => "name", value => $session->param("name"));
 892                 }
 893         }
 894
 895         if ($form->submitted && $form->validate) {
 896                 if ($form->submitted eq 'Login') {
 897                         $session->param("name", $form->field("name"));
 898                         if (defined $form->field("do") &&
 899                             $form->field("do") ne 'signin') {
 900                                 print $q->redirect(
 901                                         "$config{cgiurl}?do=".$form->field("do").
 902                                         "&page=".$form->field("page").
 903                                         "&from=".$form->field("from"));;
 904                         }
 905                         else {
 906                                 print $q->redirect($config{url});
 907                         }
 908                 }
 909                 elsif ($form->submitted eq 'Register') {
 910                         my $user_name=$form->field('name');
 911                         if (userinfo_set($user_name, {
 912                                            'email' => $form->field('email'),
 913                                            'password' => $form->field('password'),
 914                                            'regdate' => time
 915                                          })) {
 916                                 $form->field(name => "confirm_password", type => "hidden");
 917                                 $form->field(name => "email", type => "hidden");
 918                                 $form->text("Registration successful. Now you can Login.");
 919                                 print $session->header();
 920                                 print misctemplate($form->title, $form->render(submit => ["Login"]));
 921                         }
 922                         else {
 923                                 error("Error saving registration.");
 924                         }
 925                 }
 926                 elsif ($form->submitted eq 'Mail Password') {
 927                         my $user_name=$form->field("name");
 928                         my $template=HTML::Template->new(
 929                                 filename => "$config{templatedir}/passwordmail.tmpl"
 930                         );
 931                         $template->param(
 932                                 user_name => $user_name,
 933                                 user_password => userinfo_get($user_name, "password"),
 934                                 wikiurl => $config{url},
 935                                 wikiname => $config{wikiname},
 936                                 REMOTE_ADDR => $ENV{REMOTE_ADDR},
 937                         );
 938
 939                         eval q{use Mail::Sendmail};
 940                         my ($fromhost) = $config{cgiurl} =~ m!/([^/]+)!;
 941                         sendmail(
 942                                 To => userinfo_get($user_name, "email"),
 943                                 From => "$config{wikiname} admin <".(getpwuid($>))[0]."@".$fromhost.">",
 944                                 Subject => "$config{wikiname} information",
 945                                 Message => $template->output,
 946                         ) or error("Failed to send mail");
 947
 948                         $form->text("Your password has been emailed to you.");
 949                         $form->field(name => "name", required => 0);
 950                         print $session->header();
 951                         print misctemplate($form->title, $form->render(submit => ["Login", "Register", "Mail Password"]));
 952                 }
 953         }
 954         else {
 955                 print $session->header();
 956                 print misctemplate($form->title, $form->render(submit => ["Login", "Register", "Mail Password"]));
 957         }
 958 } #}}}
 959
 960 sub cgi_editpage ($$) { #{{{
 961         my $q=shift;
 962         my $session=shift;
 963
 964         eval q{use CGI::FormBuilder};
 965         my $form = CGI::FormBuilder->new(
 966                 fields => [qw(do from page content comments)],
 967                 header => 1,
 968                 method => 'POST',
 969                 validate => {
 970                         content => '/.+/',
 971                 },
 972                 required => [qw{content}],
 973                 javascript => 0,
 974                 params => $q,
 975                 action => $q->request_uri,
 976                 table => 0,
 977                 template => "$config{templatedir}/editpage.tmpl"
 978         );
 979
 980         my ($page)=$form->param('page')=~/$config{wiki_file_regexp}/;
 981         if (! defined $page || ! length $page || $page ne $q->param('page') ||
 982             $page=~/$config{wiki_file_prune_regexp}/ || $page=~/^\//) {
 983                 error("bad page name");
 984         }
 985         $page=lc($page);
 986
 987         $form->field(name => "do", type => 'hidden');
 988         $form->field(name => "from", type => 'hidden');
 989         $form->field(name => "page", value => "$page", force => 1);
 990         $form->field(name => "comments", type => "text", size => 80);
 991         $form->field(name => "content", type => "textarea", rows => 20,
 992                 cols => 80);
 993
 994         if ($form->submitted eq "Cancel") {
 995                 print $q->redirect("$config{url}/".htmlpage($page));
 996                 return;
 997         }
 998         if (! $form->submitted || ! $form->validate) {
 999                 if ($form->field("do") eq "create") {
1000                         if (exists $pagesources{lc($page)}) {
1001                                 # hmm, someone else made the page in the
1002                                 # meantime?
1003                                 print $q->redirect("$config{url}/".htmlpage($page));
1004                                 return;
1005                         }
1006
1007                         my @page_locs;
1008                         my ($from)=$form->param('from')=~/$config{wiki_file_regexp}/;
1009                         if (! defined $from || ! length $from ||
1010                             $from ne $form->param('from') ||
1011                             $from=~/$config{wiki_file_prune_regexp}/ || $from=~/^\//) {
1012                                 @page_locs=$page;
1013                         }
1014                         else {
1015                                 my $dir=$from."/";
1016                                 $dir=~s![^/]+/$!!;
1017                                 push @page_locs, $dir.$page;
1018                                 push @page_locs, "$from/$page";
1019                                 while (length $dir) {
1020                                         $dir=~s![^/]+/$!!;
1021                                         push @page_locs, $dir.$page;
1022                                 }
1023                         }
1024
1025                         $form->tmpl_param("page_select", 1);
1026                         $form->field(name => "page", type => 'select',
1027                                 options => \@page_locs);
1028                         $form->title("creating $page");
1029                 }
1030                 elsif ($form->field("do") eq "edit") {
1031                         my $content="";
1032                         if (exists $pagesources{lc($page)}) {
1033                                 $content=readfile("$config{srcdir}/$pagesources{lc($page)}");
1034                                 $content=~s/\n/\r\n/g;
1035                         }
1036                         $form->tmpl_param("page_select", 0);
1037                         $form->field(name => "content", value => $content,
1038                                 force => 1);
1039                         $form->field(name => "page", type => 'hidden');
1040                         $form->title("editing $page");
1041                 }
1042
1043                 $form->tmpl_param("can_commit", $config{svn});
1044                 $form->tmpl_param("indexlink", indexlink());
1045                 print $form->render(submit => ["Save Page", "Cancel"]);
1046         }
1047         else {
1048                 # save page
1049                 my $file=$page.$config{default_pageext};
1050                 my $newfile=1;
1051                 if (exists $pagesources{lc($page)}) {
1052                         $file=$pagesources{lc($page)};
1053                         $newfile=0;
1054                 }
1055
1056                 my $content=$form->field('content');
1057                 $content=~s/\r\n/\n/g;
1058                 $content=~s/\r/\n/g;
1059                 writefile("$config{srcdir}/$file", $content);
1060
1061                 my $message="web commit ";
1062                 if ($session->param("name")) {
1063                         $message.="by ".$session->param("name");
1064                 }
1065                 else {
1066                         $message.="from $ENV{REMOTE_ADDR}";
1067                 }
1068                 if (defined $form->field('comments') &&
1069                     length $form->field('comments')) {
1070                         $message.=": ".$form->field('comments');
1071                 }
1072
1073                 if ($config{svn}) {
1074                         if ($newfile) {
1075                                 rcs_add($file);
1076                         }
1077                         # presumably the commit will trigger an update
1078                         # of the wiki
1079                         rcs_commit($message);
1080                 }
1081                 else {
1082                         refresh();
1083                 }
1084
1085                 # The trailing question mark tries to avoid broken
1086                 # caches and get the most recent version of the page.
1087                 print $q->redirect("$config{url}/".htmlpage($page)."?updated");
1088         }
1089 } #}}}
1090
1091 sub cgi () { #{{{
1092         eval q{use CGI};
1093         eval q{use CGI::Session};
1094
1095         my $q=CGI->new;
1096
1097         my $do=$q->param('do');
1098         if (! defined $do || ! length $do) {
1099                 error("\"do\" parameter missing");
1100         }
1101
1102         # This does not need a session.
1103         if ($do eq 'recentchanges') {
1104                 cgi_recentchanges($q);
1105                 return;
1106         }
1107
1108         CGI::Session->name("ikiwiki_session");
1109
1110         my $oldmask=umask(077);
1111         my $session = CGI::Session->new("driver:db_file", $q,
1112                 { FileName => "$config{srcdir}/.ikiwiki/sessions.db" });
1113         umask($oldmask);
1114
1115         # Everything below this point needs the user to be signed in.
1116         if ((! $config{anonok} && ! defined $session->param("name") ||
1117                 ! userinfo_get($session->param("name"), "regdate")) || $do eq 'signin') {
1118                 cgi_signin($q, $session);
1119
1120                 # Force session flush with safe umask.
1121                 my $oldmask=umask(077);
1122                 $session->flush;
1123                 umask($oldmask);
1124
1125                 return;
1126         }
1127
1128         if ($do eq 'create' || $do eq 'edit') {
1129                 cgi_editpage($q, $session);
1130         }
1131         else {
1132                 error("unknown do parameter");
1133         }
1134 } #}}}
1135
1136 # main {{{
1137 gen_wrapper() if $config{wrapper};
1138 memoize('pagename');
1139 memoize('bestlink');
1140 loadindex() unless $config{rebuild};
1141 if ($config{cgi}) {
1142         cgi();
1143 }
1144 else {
1145         rcs_update() if $config{svn};
1146         refresh();
1147         saveindex();
1148 }
1149 #}}}