ikiwiki

   1 #!/usr/bin/perl -T
   2
   3 use warnings;
   4 use strict;
   5 use File::Find;
   6 use Memoize;
   7 use File::Spec;
   8
   9 BEGIN {
  10         $blosxom::version="is a proper perl module too much to ask?";
  11         do "/usr/bin/markdown";
  12 }
  13
  14 memoize('pagename');
  15 memoize('bestlink');
  16
  17 sub usage {
  18         die "usage: ikiwiki [options] source dest\n";
  19 }
  20
  21 my $link=qr/\[\[([^\s]+)\]\]/;
  22 my $verbose=0;
  23 my $rebuild=0;
  24 my $wikiname="wiki";
  25 if (grep /^-/, @ARGV) {
  26         eval {use Getopt::Long};
  27         GetOptions(
  28                 "wikiname=s" => \$wikiname,
  29                 "verbose|v" => \$verbose,
  30                 "rebuild" => \$rebuild,
  31         ) || usage();
  32 }
  33 usage() unless @ARGV == 2;
  34 my ($srcdir) = shift =~ /(.*)/; # untaint
  35 my ($destdir) = shift =~ /(.*)/; # untaint
  36
  37 my %links;
  38 my %oldlinks;
  39 my %oldpagemtime;
  40 my %renderedfiles;
  41 my %pagesources;
  42
  43 sub error ($) {
  44         die @_;
  45 }
  46
  47 sub debug ($) {
  48         print "@_\n" if $verbose;
  49 }
  50
  51 sub mtime ($) {
  52         my $page=shift;
  53
  54         return (stat($page))[9];
  55 }
  56
  57 sub basename {
  58         my $file=shift;
  59
  60         $file=~s!.*/!!;
  61         return $file;
  62 }
  63
  64 sub dirname {
  65         my $file=shift;
  66
  67         $file=~s!/?[^/]+$!!;
  68         return $file;
  69 }
  70
  71 sub pagetype ($) {
  72         my $page=shift;
  73
  74         if ($page =~ /\.mdwn$/) {
  75                 return ".mdwn";
  76         }
  77         else {
  78                 return "unknown";
  79         }
  80 }
  81
  82 sub pagename ($) {
  83         my $file=shift;
  84
  85         my $type=pagetype($file);
  86         my $page=$file;
  87         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
  88         return $page;
  89 }
  90
  91 sub htmlpage ($) {
  92         my $page=shift;
  93
  94         return $page.".html";
  95 }
  96
  97 sub readpage ($) {
  98         my $page=shift;
  99
 100         local $/=undef;
 101         open (PAGE, "$srcdir/$page") || error("failed to read $page: $!");
 102         my $ret=<PAGE>;
 103         close PAGE;
 104         return $ret;
 105 }
 106
 107 sub writepage ($$) {
 108         my $page=shift;
 109         my $content=shift;
 110
 111         my $dir=dirname("$destdir/$page");
 112         if (! -d $dir) {
 113                 my $d="";
 114                 foreach my $s (split(m!/+!, $dir)) {
 115                         $d.="$s/";
 116                         if (! -d $d) {
 117                                 mkdir($d) || error("failed to create directory $d: $!");
 118                         }
 119                 }
 120         }
 121
 122         open (PAGE, ">$destdir/$page") || error("failed to write $page: $!");
 123         print PAGE $content;
 124         close PAGE;
 125 }
 126
 127 sub findlinks {
 128         my $content=shift;
 129
 130         my @links;
 131         while ($content =~ /$link/g) {
 132                 push @links, lc($1);
 133         }
 134         return @links;
 135 }
 136
 137 # Given a page and the text of a link on the page, determine which existing
 138 # page that link best points to. Prefers pages under a subdirectory with
 139 # the same name as the source page, failing that goes down the directory tree
 140 # to the base looking for matching pages.
 141 sub bestlink ($$) {
 142         my $page=shift;
 143         my $link=lc(shift);
 144
 145         my $cwd=$page;
 146         do {
 147                 my $l=$cwd;
 148                 $l.="/" if length $l;
 149                 $l.=$link;
 150
 151                 if (exists $links{$l}) {
 152                         #debug("for $page, \"$link\", use $l");
 153                         return $l;
 154                 }
 155         } while $cwd=~s!/?[^/]+$!!;
 156
 157         print STDERR "warning: page $page, broken link: $link\n";
 158         return "";
 159 }
 160
 161 sub isinlinableimage ($) {
 162         my $file=shift;
 163
 164         $file=~/\.(png|gif|jpg|jpeg)$/;
 165 }
 166
 167 sub htmllink ($$) {
 168         my $page=shift;
 169         my $link=shift;
 170
 171         my $bestlink=bestlink($page, $link);
 172
 173         return $link if $page eq $bestlink;
 174
 175         # TODO BUG: %renderedfiles may not have it, if the linked to page
 176         # was also added and isn't yet rendered!
 177         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 178                 $bestlink=htmlpage($bestlink);
 179         }
 180         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 181                 return "<a href=\"?\">?</a>$link"
 182         }
 183
 184         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 185
 186         if (isinlinableimage($bestlink)) {
 187                 return "<img src=\"$bestlink\">";
 188         }
 189         return "<a href=\"$bestlink\">$link</a>";
 190 }
 191
 192 sub linkify ($$) {
 193         my $content=shift;
 194         my $file=shift;
 195
 196         $content =~ s/$link/htmllink(pagename($file), $1)/eg;
 197
 198         return $content;
 199 }
 200
 201 sub htmlize ($$) {
 202         my $type=shift;
 203         my $content=shift;
 204
 205         if ($type eq '.mdwn') {
 206                 return Markdown::Markdown($content);
 207         }
 208         else {
 209                 error("htmlization of $type not supported");
 210         }
 211 }
 212
 213 sub linkbacks ($$) {
 214         my $content=shift;
 215         my $page=shift;
 216
 217         my @links;
 218         foreach my $p (keys %links) {
 219                 if (grep { length $_ && bestlink($p, $_) eq $page } @{$links{$p}}) {
 220                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
 221                         # TODO: if $p is joey/foo/bar and
 222                         # the $page is joey/foo/baz, make the link text
 223                         # just be "bar".
 224                         push @links, "<a href=\"$href\">$p</a>";
 225                 }
 226         }
 227
 228         $content.="<hr><p>Links: ".join(" ", sort @links)."</p>\n" if @links;
 229         return $content;
 230 }
 231
 232 sub finalize ($$) {
 233         my $content=shift;
 234         my $page=shift;
 235
 236         my $title=basename($page);
 237         $title=~s/_/ /g;
 238
 239         my $pagelink="";
 240         my $path="";
 241         foreach my $dir (reverse split("/", $page)) {
 242                 if (length($pagelink)) {
 243                         $pagelink="<a href=\"$path$dir.html\">$dir</a>/ $pagelink";
 244                 }
 245                 else {
 246                         $pagelink=$dir;
 247                 }
 248                 $path.="../";
 249         }
 250         $path=~s/\.\.\/$/index.html/;
 251         $pagelink="<a href=\"$path\">$wikiname</a>/ $pagelink";
 252
 253         $content="<html>\n<head><title>$title</title></head>\n<body>\n".
 254                   "<h1>$pagelink</h1>\n".
 255                   $content.
 256                   "</body>\n</html>\n";
 257
 258         return $content;
 259 }
 260
 261 sub render ($) {
 262         my $file=shift;
 263
 264         my $type=pagetype($file);
 265         my $content=readpage($file);
 266         if ($type ne 'unknown') {
 267                 my $page=pagename($file);
 268
 269                 $links{$page}=[findlinks($content)];
 270
 271                 $content=linkify($content, $file);
 272                 $content=htmlize($type, $content);
 273                 $content=linkbacks($content, $page);
 274                 $content=finalize($content, $page);
 275
 276                 writepage(htmlpage($page), $content);
 277                 $oldpagemtime{$page}=time;
 278                 $renderedfiles{$page}=htmlpage($page);
 279         }
 280         else {
 281                 $links{$file}=[];
 282                 writepage($file, $content);
 283                 $oldpagemtime{$file}=time;
 284                 $renderedfiles{$file}=$file;
 285         }
 286 }
 287
 288 sub loadindex () {
 289         open (IN, "$srcdir/.index") || return;
 290         while (<IN>) {
 291                 ($_)=/(.*)/; # untaint
 292                 chomp;
 293                 my ($mtime, $file, $rendered, @links)=split(' ', $_);
 294                 my $page=pagename($file);
 295                 $pagesources{$page}=$file;
 296                 $oldpagemtime{$page}=$mtime;
 297                 $oldlinks{$page}=[@links];
 298                 $links{$page}=[@links];
 299                 $renderedfiles{$page}=$rendered;
 300         }
 301         close IN;
 302 }
 303
 304 sub saveindex () {
 305         open (OUT, ">$srcdir/.index") || error("cannot write to .index: $!");
 306         foreach my $page (keys %oldpagemtime) {
 307         print OUT "$oldpagemtime{$page} $pagesources{$page} $renderedfiles{$page} ".
 308                   join(" ", @{$links{$page}})."\n"
 309                         if $oldpagemtime{$page};
 310         }
 311         close OUT;
 312 }
 313
 314 sub prune ($) {
 315         my $file=shift;
 316
 317         unlink($file);
 318         my $dir=dirname($file);
 319         while (rmdir($dir)) {
 320                 $dir=dirname($dir);
 321         }
 322 }
 323
 324 sub refresh () {
 325         # Find existing pages.
 326         my %exists;
 327         my @files;
 328         find({
 329                 no_chdir => 1,
 330                 wanted => sub {
 331                         if (/\/\.svn\//) {
 332                                 $File::Find::prune=1;
 333                         }
 334                         elsif (! -d $_ && ! /\.html$/ && ! /\/\./) {
 335                                 my ($f)=/(^[-A-Za-z0-9_.:\/+]+$)/; # untaint
 336                                 if (! defined $f) {
 337                                         warn("skipping bad filename $_\n");
 338                                 }
 339                                 else {
 340                                         $f=~s/^\Q$srcdir\E\/?//;
 341                                         push @files, $f;
 342                                         $exists{pagename($f)}=1;
 343                                 }
 344                         }
 345                 },
 346         }, $srcdir);
 347
 348         my %rendered;
 349
 350         # check for added or removed pages
 351         my @add;
 352         foreach my $file (@files) {
 353                 my $page=pagename($file);
 354                 if (! $oldpagemtime{$page}) {
 355                         debug("new page $page");
 356                         push @add, $file;
 357                         $links{$page}=[];
 358                         $pagesources{$page}=$file;
 359                 }
 360         }
 361         my @del;
 362         foreach my $page (keys %oldpagemtime) {
 363                 if (! $exists{$page}) {
 364                         debug("removing old page $page");
 365                         push @del, $renderedfiles{$page};
 366                         prune($destdir."/".$renderedfiles{$page});
 367                         delete $renderedfiles{$page};
 368                         $oldpagemtime{$page}=0;
 369                         delete $pagesources{$page};
 370                 }
 371         }
 372
 373         # render any updated files
 374         foreach my $file (@files) {
 375                 my $page=pagename($file);
 376
 377                 if (! exists $oldpagemtime{$page} ||
 378                     mtime("$srcdir/$file") > $oldpagemtime{$page}) {
 379                         debug("rendering changed file $file");
 380                         render($file);
 381                         $rendered{$file}=1;
 382                 }
 383         }
 384
 385         # if any files were added or removed, check to see if each page
 386         # needs an update due to linking to them
 387         # TODO: inefficient; pages may get rendered above and again here;
 388         # problem is the bestlink may have changes and we won't know until
 389         # now
 390         if (@add || @del) {
 391 FILE:           foreach my $file (@files) {
 392                         my $page=pagename($file);
 393                         foreach my $f (@add, @del) {
 394                                 my $p=pagename($f);
 395                                 foreach my $link (@{$links{$page}}) {
 396                                         if (bestlink($page, $link) eq $p) {
 397                                                 debug("rendering $file, which links to $p");
 398                                                 render($file);
 399                                                 $rendered{$file}=1;
 400                                                 next FILE;
 401                                         }
 402                                 }
 403                         }
 404                 }
 405         }
 406
 407         # handle linkbacks; if a page has added/removed links, update the
 408         # pages it links to
 409         # TODO: inefficient; pages may get rendered above and again here;
 410         # problem is the linkbacks could be wrong in the first pass render
 411         # above.
 412         if (%rendered) {
 413                 my %linkchanged;
 414                 foreach my $file (keys %rendered, @del) {
 415                         my $page=pagename($file);
 416                         if (exists $links{$page}) {
 417                                 foreach my $link (@{$links{$page}}) {
 418                                         $link=bestlink($page, $link);
 419                                         if (length $link &&
 420                                             ! exists $oldlinks{$page} ||
 421                                             ! grep { $_ eq $link } @{$oldlinks{$page}}) {
 422                                                 $linkchanged{$link}=1;
 423                                         }
 424                                 }
 425                         }
 426                         if (exists $oldlinks{$page}) {
 427                                 foreach my $link (@{$oldlinks{$page}}) {
 428                                         $link=bestlink($page, $link);
 429                                         if (length $link &&
 430                                             ! exists $links{$page} ||
 431                                             ! grep { $_ eq $link } @{$links{$page}}) {
 432                                                 $linkchanged{$link}=1;
 433                                         }
 434                                 }
 435                         }
 436                 }
 437                 foreach my $link (keys %linkchanged) {
 438                         my $linkfile=$pagesources{$link};
 439                         if (defined $linkfile) {
 440                                 debug("rendering $linkfile, to update its linkbacks");
 441                                 render($linkfile);
 442                         }
 443                 }
 444         }
 445 }
 446
 447 loadindex() unless $rebuild;
 448 refresh();
 449 saveindex();