IkiWiki/Wrapper.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use File::Spec;
   8 use Data::Dumper;
   9 use IkiWiki;
  10
  11 sub gen_wrapper () { #{{{
  12         $config{srcdir}=File::Spec->rel2abs($config{srcdir});
  13         $config{destdir}=File::Spec->rel2abs($config{destdir});
  14         my $this=File::Spec->rel2abs($0);
  15         if (! -x $this) {
  16                 error(sprintf(gettext("%s doesn't seem to be executable"), $this));
  17         }
  18
  19         if ($config{setup}) {
  20                 error(gettext("cannot create a wrapper that uses a setup file"));
  21         }
  22         my $wrapper=possibly_foolish_untaint($config{wrapper});
  23         if (! defined $wrapper || ! length $wrapper) {
  24                 error(gettext("wrapper filename not specified"));
  25         }
  26         delete $config{wrapper};
  27
  28         my @envsave;
  29         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
  30                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
  31                        HTTP_COOKIE REMOTE_USER HTTPS} if $config{cgi};
  32         my $envsave="";
  33         foreach my $var (@envsave) {
  34                 $envsave.=<<"EOF"
  35         if ((s=getenv("$var")))
  36                 addenv("$var", s);
  37 EOF
  38         }
  39
  40         my $test_receive="";
  41         if ($config{test_receive}) {
  42                 require IkiWiki::Receive;
  43                 $test_receive=IkiWiki::Receive::gen_wrapper();
  44         }
  45
  46         $Data::Dumper::Indent=0; # no newlines
  47         my $configstring=Data::Dumper->Dump([\%config], ['*config']);
  48         $configstring=~s/\\/\\\\/g;
  49         $configstring=~s/"/\\"/g;
  50         $configstring=~s/\n/\\n/g;
  51
  52         #translators: The first parameter is a filename, and the second is
  53         #translators: a (probably not translated) error message.
  54         open(OUT, ">$wrapper.c") || error(sprintf(gettext("failed to write %s: %s"), "$wrapper.c", $!));;
  55         print OUT <<"EOF";
  56 /* A wrapper for ikiwiki, can be safely made suid. */
  57 #include <stdio.h>
  58 #include <sys/types.h>
  59 #include <unistd.h>
  60 #include <stdlib.h>
  61 #include <string.h>
  62
  63 extern char **environ;
  64 char *newenviron[$#envsave+6];
  65 int i=0;
  66
  67 addenv(char *var, char *val) {
  68         char *s=malloc(strlen(var)+1+strlen(val)+1);
  69         if (!s)
  70                 perror("malloc");
  71         sprintf(s, "%s=%s", var, val);
  72         newenviron[i++]=s;
  73 }
  74
  75 int main (int argc, char **argv) {
  76         char *s;
  77
  78 $test_receive
  79 $envsave
  80         newenviron[i++]="HOME=$ENV{HOME}";
  81         newenviron[i++]="WRAPPED_OPTIONS=$configstring";
  82         newenviron[i]=NULL;
  83         environ=newenviron;
  84
  85         if (setregid(getegid(), -1) != 0 &&
  86             setregid(getegid(), -1) != 0) {
  87                 perror("failed to drop real gid");
  88                 exit(1);
  89         }
  90         if (setreuid(geteuid(), -1) != 0 &&
  91             setreuid(geteuid(), -1) != 0) {
  92                 perror("failed to drop real uid");
  93                 exit(1);
  94         }
  95
  96         execl("$this", "$this", NULL);
  97         perror("exec $this");
  98         exit(1);
  99 }
 100 EOF
 101         close OUT;
 102
 103         my $cc=exists $ENV{CC} ? possibly_foolish_untaint($ENV{CC}) : 'cc';
 104         if (system($cc, "$wrapper.c", "-o", "$wrapper.new") != 0) {
 105                 #translators: The parameter is a C filename.
 106                 error(sprintf(gettext("failed to compile %s"), "$wrapper.c"));
 107         }
 108         unlink("$wrapper.c");
 109         if (defined $config{wrappergroup}) {
 110                 my $gid=(getgrnam($config{wrappergroup}))[2];
 111                 if (! defined $gid) {
 112                         error(sprintf("bad wrappergroup"));
 113                 }
 114                 if (! chown(-1, $gid, "$wrapper.new")) {
 115                         error("chown $wrapper.new: $!");
 116                 }
 117         }
 118         if (defined $config{wrappermode} &&
 119             ! chmod(oct($config{wrappermode}), "$wrapper.new")) {
 120                 error("chmod $wrapper.new: $!");
 121         }
 122         if (! rename("$wrapper.new", $wrapper)) {
 123                 error("rename $wrapper.new $wrapper: $!");
 124         }
 125         #translators: The parameter is a filename.
 126         printf(gettext("successfully generated %s"), $wrapper);
 127         print "\n";
 128 } #}}}
 129
 130 1