IkiWiki/Plugin/rename.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::rename;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 2.00;
   7
   8 sub import { #{{{
   9         hook(type => "formbuilder_setup", id => "rename", call => \&formbuilder_setup);
  10         hook(type => "formbuilder", id => "rename", call => \&formbuilder);
  11         hook(type => "sessioncgi", id => "rename", call => \&sessioncgi);
  12
  13 } # }}}
  14
  15 sub check_canrename ($$$$$$$) { #{{{
  16         my $src=shift;
  17         my $srcfile=shift;
  18         my $dest=shift;
  19         my $destfile=shift;
  20         my $q=shift;
  21         my $session=shift;
  22         my $attachment=shift;
  23
  24         # Must be a known source file.
  25         if (! exists $pagesources{$src}) {
  26                 error(sprintf(gettext("%s does not exist"),
  27                         htmllink("", "", $src, noimageinline => 1)));
  28         }
  29
  30         # Must exist on disk, and be a regular file.
  31         if (! -e "$config{srcdir}/$srcfile") {
  32                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be renamed"), $srcfile));
  33         }
  34         elsif (-l "$config{srcdir}/$srcfile" && ! -f _) {
  35                 error(sprintf(gettext("%s is not a file"), $srcfile));
  36         }
  37
  38         # Must be editable.
  39         IkiWiki::check_canedit($src, $q, $session);
  40         if ($attachment) {
  41                 IkiWiki::Plugin::attachment::check_canattach($session, $src, $srcfile);
  42         }
  43
  44         # Dest checks can be omitted by passing undef.
  45         if (defined $dest) {
  46                 if ($src eq $dest || $srcfile eq $destfile) {
  47                         error(gettext("no change to the file name was specified"));
  48                 }
  49
  50                 # Must be a legal filename, and not absolute.
  51                 if (IkiWiki::file_pruned($destfile, $config{srcdir}) ||
  52                     $destfile=~/^\//) {
  53                         error(sprintf(gettext("illegal name")));
  54                 }
  55
  56                 # Must not be a known source file.
  57                 if (exists $pagesources{$dest}) {
  58                         error(sprintf(gettext("%s already exists"),
  59                                 htmllink("", "", $dest, noimageinline => 1)));
  60                 }
  61
  62                 # Must not exist on disk already.
  63                 if (-l "$config{srcdir}/$destfile" || -e _) {
  64                         error(sprintf(gettext("%s already exists on disk"), $destfile));
  65                 }
  66
  67                 # Must be editable.
  68                 IkiWiki::check_canedit($dest, $q, $session);
  69                 if ($attachment) {
  70                         # Note that $srcfile is used here, not $destfile,
  71                         # because it wants the current file, to check it.
  72                         IkiWiki::Plugin::attachment::check_canattach($session, $dest, $srcfile);
  73                 }
  74         }
  75 } #}}}
  76
  77 sub rename_form ($$$) { #{{{
  78         my $q=shift;
  79         my $session=shift;
  80         my $page=shift;
  81
  82         eval q{use CGI::FormBuilder};
  83         error($@) if $@;
  84         my $f = CGI::FormBuilder->new(
  85                 name => "rename",
  86                 title => sprintf(gettext("rename %s"), IkiWiki::pagetitle($page)),
  87                 header => 0,
  88                 charset => "utf-8",
  89                 method => 'POST',
  90                 javascript => 0,
  91                 params => $q,
  92                 action => $config{cgiurl},
  93                 stylesheet => IkiWiki::baseurl()."style.css",
  94                 fields => [qw{do page new_name attachment}],
  95         );
  96
  97         $f->field(name => "do", type => "hidden", value => "rename", force => 1);
  98         $f->field(name => "page", type => "hidden", value => $page, force => 1);
  99         $f->field(name => "new_name", value => IkiWiki::pagetitle($page), size => 60);
 100         $f->field(name => "attachment", type => "hidden");
 101
 102         return $f, ["Rename", "Cancel"];
 103 } #}}}
 104
 105 sub rename_start ($$$$) {
 106         my $q=shift;
 107         my $session=shift;
 108         my $attachment=shift;
 109         my $page=shift;
 110
 111         check_canrename($page, $pagesources{$page}, undef, undef,
 112                 $q, $session, $attachment);
 113
 114         # Save current form state to allow returning to it later
 115         # without losing any edits.
 116         # (But don't save what button was submitted, to avoid
 117         # looping back to here.)
 118         # Note: "_submit" is CGI::FormBuilder internals.
 119         $q->param(-name => "_submit", -value => "");
 120         $session->param(postrename => scalar $q->Vars);
 121         IkiWiki::cgi_savesession($session);
 122
 123         my ($f, $buttons)=rename_form($q, $session, $page);
 124         if (defined $attachment) {
 125                 $f->field(name => "attachment", value => $attachment, force => 1);
 126         }
 127
 128         IkiWiki::showform($f, $buttons, $session, $q);
 129         exit 0;
 130 }
 131
 132 my $renamesummary;
 133 sub postrename ($;$$$) {
 134         my $session=shift;
 135         my $src=shift;
 136         my $dest=shift;
 137         my $attachment=shift;
 138
 139         # Load saved form state and return to edit page.
 140         my $postrename=CGI->new($session->param("postrename"));
 141         $session->clear("postrename");
 142         IkiWiki::cgi_savesession($session);
 143
 144         if (defined $src) {
 145                 # Generate a rename summary, that will be shown at the top
 146                 # of the edit template.
 147                 my $template=template("renamesummary.tmpl");
 148                 $template->param(src => $src);
 149                 $template->param(dest => $dest);
 150                 $renamesummary=$template->output;
 151         }
 152
 153         if (defined $dest && ! $attachment) {
 154                 # They renamed the page they were editing. This requires
 155                 # fixups to the edit form state.
 156                 # Tweak the edit form to be editing the new page.
 157                 $postrename->param("page", $dest);
 158                 # Get a new edit token; old one might not be valid for the
 159                 # renamed file.
 160                 $postrename->param("rcsinfo", IkiWiki::rcs_prepedit($pagesources{$dest}));
 161         }
 162
 163         IkiWiki::cgi_editpage($postrename, $session);
 164 }
 165
 166 sub formbuilder_setup (@) { #{{{
 167         my %params=@_;
 168         my $form=$params{form};
 169         my $q=$params{cgi};
 170
 171         if (defined $form->field("do") && $form->field("do") eq "edit") {
 172                 # Rename button for the page, and also for attachments.
 173                 push @{$params{buttons}}, "Rename";
 174                 $form->tmpl_param("field-rename" => '<input name="_submit" type="submit" value="Rename Attachment" />');
 175
 176                 if (defined $renamesummary) {
 177                         $form->tmpl_param(message => $renamesummary);
 178                 }
 179         }
 180 } #}}}
 181
 182 sub formbuilder (@) { #{{{
 183         my %params=@_;
 184         my $form=$params{form};
 185
 186         if (defined $form->field("do") && $form->field("do") eq "edit") {
 187                 my $q=$params{cgi};
 188                 my $session=$params{session};
 189
 190                 if ($form->submitted eq "Rename") {
 191                         rename_start($q, $session, 0, $form->field("page"));
 192                 }
 193                 elsif ($form->submitted eq "Rename Attachment") {
 194                         my @selected=$q->param("attachment_select");
 195                         if (@selected > 1) {
 196                                 error(gettext("Only one attachment can be renamed at a time."));
 197                         }
 198                         elsif (! @selected) {
 199                                 error(gettext("Please select the attachment to rename."))
 200                         }
 201                         rename_start($q, $session, 1, $selected[0]);
 202                 }
 203         }
 204 } #}}}
 205
 206 sub sessioncgi ($$) { #{{{
 207         my $q=shift;
 208
 209         if ($q->param("do") eq 'rename') {
 210                 my $session=shift;
 211                 my ($form, $buttons)=rename_form($q, $session, $q->param("page"));
 212                 IkiWiki::decode_form_utf8($form);
 213
 214                 if ($form->submitted eq 'Cancel') {
 215                         postrename($session);
 216                 }
 217                 elsif ($form->submitted eq 'Rename' && $form->validate) {
 218                         # These untaints are safe because of the checks
 219                         # performed in check_canrename below.
 220                         my $src=$q->param("page");
 221                         my $srcfile=IkiWiki::possibly_foolish_untaint($pagesources{$src});
 222                         my $dest=IkiWiki::possibly_foolish_untaint(IkiWiki::titlepage($q->param("new_name")));
 223
 224                         # The extension of dest is the same as src if it's
 225                         # a page. If it's an extension, the extension is
 226                         # already included.
 227                         my $destfile=$dest;
 228                         if (! $q->param("attachment")) {
 229                                 my ($ext)=$srcfile=~/(\.[^.]+)$/;
 230                                 $destfile.=$ext;
 231                         }
 232
 233                         check_canrename($src, $srcfile, $dest, $destfile,
 234                                 $q, $session, $q->param("attachment"));
 235
 236                         # Ensures that the dest directory exists and is ok.
 237                         IkiWiki::prep_writefile($destfile, $config{srcdir});
 238
 239                         # Do rename, and update the wiki.
 240                         require IkiWiki::Render;
 241                         if ($config{rcs}) {
 242                                 IkiWiki::disable_commit_hook();
 243                                 IkiWiki::rcs_rename($srcfile, $destfile);
 244                                 IkiWiki::rcs_commit_staged(
 245                                         sprintf(gettext("rename %s to %s"), $src, $dest),
 246                                         $session->param("name"), $ENV{REMOTE_ADDR});
 247                                 IkiWiki::enable_commit_hook();
 248                                 IkiWiki::rcs_update();
 249                         }
 250                         else {
 251                                 if (! rename("$config{srcdir}/$srcfile", "$config{srcdir}/$destfile")) {
 252                                         error("rename: $!");
 253                                 }
 254                         }
 255                         IkiWiki::refresh();
 256                         IkiWiki::saveindex();
 257
 258                         postrename($session, $src, $dest, $q->param("attachment"));
 259                 }
 260                 else {
 261                         IkiWiki::showform($form, $buttons, $session, $q);
 262                 }
 263
 264                 exit 0;
 265         }
 266 }
 267
 268 1