IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                 },
  53                 rss => {
  54                         type => "boolean",
  55                         example => 0,
  56                         description => "enable rss feeds by default?",
  57                         safe => 1,
  58                         rebuild => 1,
  59                 },
  60                 atom => {
  61                         type => "boolean",
  62                         example => 0,
  63                         description => "enable atom feeds by default?",
  64                         safe => 1,
  65                         rebuild => 1,
  66                 },
  67                 allowrss => {
  68                         type => "boolean",
  69                         example => 0,
  70                         description => "allow rss feeds to be used?",
  71                         safe => 1,
  72                         rebuild => 1,
  73                 },
  74                 allowatom => {
  75                         type => "boolean",
  76                         example => 0,
  77                         description => "allow atom feeds to be used?",
  78                         safe => 1,
  79                         rebuild => 1,
  80                 },
  81                 pingurl => {
  82                         type => "string",
  83                         example => "http://rpc.technorati.com/rpc/ping",
  84                         description => "urls to ping (using XML-RPC) on feed update",
  85                         safe => 1,
  86                         rebuild => 0,
  87                 },
  88 }
  89
  90 sub checkconfig () {
  91         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  92                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  93         }
  94         if ($config{rss}) {
  95                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  96         }
  97         if ($config{atom}) {
  98                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
  99         }
 100         if (! exists $config{pingurl}) {
 101                 $config{pingurl}=[];
 102         }
 103 }
 104
 105 sub format (@) {
 106         my %params=@_;
 107
 108         # Fill in the inline content generated earlier. This is actually an
 109         # optimisation.
 110         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 111                 delete @inline[$1,]
 112         }eg;
 113         return $params{content};
 114 }
 115
 116 sub sessioncgi ($$) {
 117         my $q=shift;
 118         my $session=shift;
 119
 120         if ($q->param('do') eq 'blog') {
 121                 my $page=titlepage(decode_utf8($q->param('title')));
 122                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 123                 # if the page already exists, munge it to be unique
 124                 my $from=$q->param('from');
 125                 my $add="";
 126                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 127                         $add=1 unless length $add;
 128                         $add++;
 129                 }
 130                 $q->param('page', $page.$add);
 131                 # now go create the page
 132                 $q->param('do', 'create');
 133                 # make sure the editpage plugin in loaded
 134                 if (IkiWiki->can("cgi_editpage")) {
 135                         IkiWiki::cgi_editpage($q, $session);
 136                 }
 137                 else {
 138                         error(gettext("page editing not allowed"));
 139                 }
 140                 exit;
 141         }
 142 }
 143
 144 # Back to ikiwiki namespace for the rest, this code is very much
 145 # internal to ikiwiki even though it's separated into a plugin.
 146 package IkiWiki;
 147
 148 my %toping;
 149 my %feedlinks;
 150
 151 sub preprocess_inline (@) {
 152         my %params=@_;
 153
 154         if (! exists $params{pages} && ! exists $params{pagenames}) {
 155                 error gettext("missing pages parameter");
 156         }
 157         my $raw=yesno($params{raw});
 158         my $archive=yesno($params{archive});
 159         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 160         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 161         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 162         my $feeds=exists $params{feeds} ? yesno($params{feeds}) : !$quick;
 163         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 164         my $feedonly=yesno($params{feedonly});
 165         if (! exists $params{show} && ! $archive) {
 166                 $params{show}=10;
 167         }
 168         if (! exists $params{feedshow} && exists $params{show}) {
 169                 $params{feedshow}=$params{show};
 170         }
 171         my $desc;
 172         if (exists $params{description}) {
 173                 $desc = $params{description}
 174         }
 175         else {
 176                 $desc = $config{wikiname};
 177         }
 178         my $actions=yesno($params{actions});
 179         if (exists $params{template}) {
 180                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 181         }
 182         else {
 183                 $params{template} = $archive ? "archivepage" : "inlinepage";
 184         }
 185
 186         my @list;
 187
 188         if (exists $params{pagenames}) {
 189                 foreach my $p (qw(sort pages)) {
 190                         if (exists $params{$p}) {
 191                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 192                                         "pagenames", $p);
 193                         }
 194                 }
 195
 196                 @list = map { bestlink($params{page}, $_) }
 197                         split ' ', $params{pagenames};
 198
 199                 foreach my $p (@list) {
 200                         add_depends($params{page}, $p, deptype($quick ? "presence" : "content"));
 201                 }
 202         }
 203         else {
 204                 add_depends($params{page}, $params{pages},
 205                         deptype($quick ? "presence" : "content"));
 206
 207                 @list = pagespec_match_list(
 208                         [ grep { $_ ne $params{page} } keys %pagesources ],
 209                         $params{pages}, location => $params{page});
 210
 211                 if (exists $params{sort} && $params{sort} eq 'title') {
 212                         @list=sort { pagetitle(basename($a)) cmp pagetitle(basename($b)) } @list;
 213                 }
 214                 elsif (exists $params{sort} && $params{sort} eq 'title_natural') {
 215                         eval q{use Sort::Naturally};
 216                         if ($@) {
 217                                 error(gettext("Sort::Naturally needed for title_natural sort"));
 218                         }
 219                         @list=sort { Sort::Naturally::ncmp(pagetitle(basename($a)), pagetitle(basename($b))) } @list;
 220                 }
 221                 elsif (exists $params{sort} && $params{sort} eq 'mtime') {
 222                         @list=sort { $pagemtime{$b} <=> $pagemtime{$a} } @list;
 223                 }
 224                 elsif (! exists $params{sort} || $params{sort} eq 'age') {
 225                         @list=sort { $pagectime{$b} <=> $pagectime{$a} } @list;
 226                 }
 227                 else {
 228                         error sprintf(gettext("unknown sort type %s"), $params{sort});
 229                 }
 230         }
 231
 232         if (yesno($params{reverse})) {
 233                 @list=reverse(@list);
 234         }
 235
 236         if (exists $params{skip}) {
 237                 @list=@list[$params{skip} .. scalar @list - 1];
 238         }
 239
 240         my @feedlist;
 241         if ($feeds) {
 242                 if (exists $params{feedshow} &&
 243                     $params{feedshow} && @list > $params{feedshow}) {
 244                         @feedlist=@list[0..$params{feedshow} - 1];
 245                 }
 246                 else {
 247                         @feedlist=@list;
 248                 }
 249         }
 250
 251         if ($params{show} && @list > $params{show}) {
 252                 @list=@list[0..$params{show} - 1];
 253         }
 254
 255         if ($feeds && exists $params{feedpages}) {
 256                 @feedlist=pagespec_match_list(\@feedlist, $params{feedpages}, location => $params{page});
 257         }
 258
 259         my ($feedbase, $feednum);
 260         if ($feeds) {
 261                 # Ensure that multiple feeds on a page go to unique files.
 262
 263                 # Feedfile can lead to conflicts if usedirs is not enabled,
 264                 # so avoid supporting it in that case.
 265                 delete $params{feedfile} if ! $config{usedirs};
 266                 # Tight limits on legal feedfiles, to avoid security issues
 267                 # and conflicts.
 268                 if (defined $params{feedfile}) {
 269                         if ($params{feedfile} =~ /\// ||
 270                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 271                                 error("illegal feedfile");
 272                         }
 273                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 274                 }
 275                 $feedbase=targetpage($params{destpage}, "", $params{feedfile});
 276
 277                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 278                 if (exists $knownfeeds{$feedid}) {
 279                         $feednum=$knownfeeds{$feedid};
 280                 }
 281                 else {
 282                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 283                                 if ($feeds) {
 284                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 285                                 }
 286                         }
 287                         else {
 288                                 $feednum=$knownfeeds{$feedid}="";
 289                                 if ($feeds) {
 290                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 291                                 }
 292                         }
 293                 }
 294         }
 295
 296         my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
 297         my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
 298
 299         my $ret="";
 300
 301         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 302             (exists $params{postform} && yesno($params{postform}))) &&
 303             IkiWiki->can("cgi_editpage")) {
 304                 # Add a blog post form, with feed buttons.
 305                 my $formtemplate=template("blogpost.tmpl", blind_cache => 1);
 306                 $formtemplate->param(cgiurl => $config{cgiurl});
 307                 $formtemplate->param(rootpage => rootpage(%params));
 308                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 309                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 310                 if (exists $params{postformtext}) {
 311                         $formtemplate->param(postformtext =>
 312                                 $params{postformtext});
 313                 }
 314                 else {
 315                         $formtemplate->param(postformtext =>
 316                                 gettext("Add a new post titled:"));
 317                 }
 318                 $ret.=$formtemplate->output;
 319
 320                 # The post form includes the feed buttons, so
 321                 # emptyfeeds cannot be hidden.
 322                 $emptyfeeds=1;
 323         }
 324         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 325                 # Add feed buttons.
 326                 my $linktemplate=template("feedlink.tmpl", blind_cache => 1);
 327                 $linktemplate->param(rssurl => $rssurl) if $rss;
 328                 $linktemplate->param(atomurl => $atomurl) if $atom;
 329                 $ret.=$linktemplate->output;
 330         }
 331
 332         if (! $feedonly) {
 333                 require HTML::Template;
 334                 my @params=IkiWiki::template_params($params{template}.".tmpl", blind_cache => 1);
 335                 if (! @params) {
 336                         error sprintf(gettext("nonexistant template %s"), $params{template});
 337                 }
 338                 my $template=HTML::Template->new(@params) unless $raw;
 339
 340                 foreach my $page (@list) {
 341                         my $file = $pagesources{$page};
 342                         my $type = pagetype($file);
 343                         if (! $raw || ($raw && ! defined $type)) {
 344                                 unless ($archive && $quick) {
 345                                         # Get the content before populating the
 346                                         # template, since getting the content uses
 347                                         # the same template if inlines are nested.
 348                                         my $content=get_inline_content($page, $params{destpage});
 349                                         $template->param(content => $content);
 350                                 }
 351                                 $template->param(pageurl => urlto($page, $params{destpage}));
 352                                 $template->param(inlinepage => $page);
 353                                 $template->param(title => pagetitle(basename($page)));
 354                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}));
 355                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 356                                 $template->param(first => 1) if $page eq $list[0];
 357                                 $template->param(last => 1) if $page eq $list[$#list];
 358
 359                                 if ($actions) {
 360                                         my $file = $pagesources{$page};
 361                                         my $type = pagetype($file);
 362                                         if ($config{discussion}) {
 363                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/ &&
 364                                                     (length $config{cgiurl} ||
 365                                                      exists $links{$page."/".$config{discussionpage}})) {
 366                                                         $template->param(have_actions => 1);
 367                                                         $template->param(discussionlink =>
 368                                                                 htmllink($page,
 369                                                                         $params{destpage},
 370                                                                         $config{discussionpage},
 371                                                                         noimageinline => 1,
 372                                                                         forcesubpage => 1));
 373                                                 }
 374                                         }
 375                                         if (length $config{cgiurl} && defined $type) {
 376                                                 $template->param(have_actions => 1);
 377                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 378                                         }
 379                                 }
 380
 381                                 run_hooks(pagetemplate => sub {
 382                                         shift->(page => $page, destpage => $params{destpage},
 383                                                 template => $template,);
 384                                 });
 385
 386                                 $ret.=$template->output;
 387                                 $template->clear_params;
 388                         }
 389                         else {
 390                                 if (defined $type) {
 391                                         $ret.="\n".
 392                                               linkify($page, $params{destpage},
 393                                               preprocess($page, $params{destpage},
 394                                               filter($page, $params{destpage},
 395                                               readfile(srcfile($file)))));
 396                                 }
 397                         }
 398                 }
 399         }
 400
 401         if ($feeds && ($emptyfeeds || @feedlist)) {
 402                 if ($rss) {
 403                         my $rssp=$feedbase."rss".$feednum;
 404                         will_render($params{destpage}, $rssp);
 405                         if (! $params{preview}) {
 406                                 writefile($rssp, $config{destdir},
 407                                         genfeed("rss",
 408                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
 409                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 410                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
 411                         }
 412                 }
 413                 if ($atom) {
 414                         my $atomp=$feedbase."atom".$feednum;
 415                         will_render($params{destpage}, $atomp);
 416                         if (! $params{preview}) {
 417                                 writefile($atomp, $config{destdir},
 418                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
 419                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 420                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
 421                         }
 422                 }
 423         }
 424
 425         return $ret if $raw || $nested;
 426         push @inline, $ret;
 427         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 428 }
 429
 430 sub pagetemplate_inline (@) {
 431         my %params=@_;
 432         my $page=$params{page};
 433         my $template=$params{template};
 434
 435         $template->param(feedlinks => $feedlinks{$page})
 436                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 437 }
 438
 439 sub get_inline_content ($$) {
 440         my $page=shift;
 441         my $destpage=shift;
 442
 443         my $file=$pagesources{$page};
 444         my $type=pagetype($file);
 445         if (defined $type) {
 446                 $nested++;
 447                 my $ret=htmlize($page, $destpage, $type,
 448                        linkify($page, $destpage,
 449                        preprocess($page, $destpage,
 450                        filter($page, $destpage,
 451                        readfile(srcfile($file))))));
 452                 $nested--;
 453                 return $ret;
 454         }
 455         else {
 456                 return "";
 457         }
 458 }
 459
 460 sub date_822 ($) {
 461         my $time=shift;
 462
 463         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 464         POSIX::setlocale(&POSIX::LC_TIME, "C");
 465         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 466         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 467         return $ret;
 468 }
 469
 470 sub date_3339 ($) {
 471         my $time=shift;
 472
 473         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 474         POSIX::setlocale(&POSIX::LC_TIME, "C");
 475         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
 476         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 477         return $ret;
 478 }
 479
 480 sub absolute_urls ($$) {
 481         # sucky sub because rss sucks
 482         my $content=shift;
 483         my $baseurl=shift;
 484
 485         my $url=$baseurl;
 486         $url=~s/[^\/]+$//;
 487
 488         # what is the non path part of the url?
 489         my $top_uri = URI->new($url);
 490         $top_uri->path_query(""); # reset the path
 491         my $urltop = $top_uri->as_string;
 492
 493         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
 494         # relative to another wiki page
 495         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)([^\/][^"]*)"/$1 href="$url$2"/mig;
 496         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)([^\/][^"]*)"/$1 src="$url$2"/mig;
 497         # relative to the top of the site
 498         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)(\/[^"]*)"/$1 href="$urltop$2"/mig;
 499         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)(\/[^"]*)"/$1 src="$urltop$2"/mig;
 500         return $content;
 501 }
 502
 503 sub genfeed ($$$$$@) {
 504         my $feedtype=shift;
 505         my $feedurl=shift;
 506         my $feeddesc=shift;
 507         my $guid=shift;
 508         my $page=shift;
 509         my @pages=@_;
 510
 511         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 512
 513         my $itemtemplate=template($feedtype."item.tmpl", blind_cache => 1);
 514         my $content="";
 515         my $lasttime = 0;
 516         foreach my $p (@pages) {
 517                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 518                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 519
 520                 $itemtemplate->param(
 521                         title => pagetitle(basename($p)),
 522                         url => $u,
 523                         permalink => $u,
 524                         cdate_822 => date_822($pagectime{$p}),
 525                         mdate_822 => date_822($pagemtime{$p}),
 526                         cdate_3339 => date_3339($pagectime{$p}),
 527                         mdate_3339 => date_3339($pagemtime{$p}),
 528                 );
 529
 530                 if (exists $pagestate{$p}) {
 531                         if (exists $pagestate{$p}{meta}{guid}) {
 532                                 $itemtemplate->param(guid => $pagestate{$p}{meta}{guid});
 533                         }
 534
 535                         if (exists $pagestate{$p}{meta}{updated}) {
 536                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 537                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 538                         }
 539                 }
 540
 541                 if ($itemtemplate->query(name => "enclosure")) {
 542                         my $file=$pagesources{$p};
 543                         my $type=pagetype($file);
 544                         if (defined $type) {
 545                                 $itemtemplate->param(content => $pcontent);
 546                         }
 547                         else {
 548                                 my $size=(srcfile_stat($file))[8];
 549                                 my $mime="unknown";
 550                                 eval q{use File::MimeInfo};
 551                                 if (! $@) {
 552                                         $mime = mimetype($file);
 553                                 }
 554                                 $itemtemplate->param(
 555                                         enclosure => $u,
 556                                         type => $mime,
 557                                         length => $size,
 558                                 );
 559                         }
 560                 }
 561                 else {
 562                         $itemtemplate->param(content => $pcontent);
 563                 }
 564
 565                 run_hooks(pagetemplate => sub {
 566                         shift->(page => $p, destpage => $page,
 567                                 template => $itemtemplate);
 568                 });
 569
 570                 $content.=$itemtemplate->output;
 571                 $itemtemplate->clear_params;
 572
 573                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 574         }
 575
 576         my $template=template($feedtype."page.tmpl", blind_cache => 1);
 577         $template->param(
 578                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 579                 wikiname => $config{wikiname},
 580                 pageurl => $url,
 581                 content => $content,
 582                 feeddesc => $feeddesc,
 583                 guid => $guid,
 584                 feeddate => date_3339($lasttime),
 585                 feedurl => $feedurl,
 586                 version => $IkiWiki::version,
 587         );
 588         run_hooks(pagetemplate => sub {
 589                 shift->(page => $page, destpage => $page,
 590                         template => $template);
 591         });
 592
 593         return $template->output;
 594 }
 595
 596 sub pingurl (@) {
 597         return unless @{$config{pingurl}} && %toping;
 598
 599         eval q{require RPC::XML::Client};
 600         if ($@) {
 601                 debug(gettext("RPC::XML::Client not found, not pinging"));
 602                 return;
 603         }
 604
 605         # daemonize here so slow pings don't slow down wiki updates
 606         defined(my $pid = fork) or error("Can't fork: $!");
 607         return if $pid;
 608         chdir '/';
 609         POSIX::setsid() or error("Can't start a new session: $!");
 610         open STDIN, '/dev/null';
 611         open STDOUT, '>/dev/null';
 612         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 613
 614         # Don't need to keep a lock on the wiki as a daemon.
 615         IkiWiki::unlockwiki();
 616
 617         foreach my $page (keys %toping) {
 618                 my $title=pagetitle(basename($page), 0);
 619                 my $url=urlto($page, "", 1);
 620                 foreach my $pingurl (@{$config{pingurl}}) {
 621                         debug("Pinging $pingurl for $page");
 622                         eval {
 623                                 my $client = RPC::XML::Client->new($pingurl);
 624                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 625                                         $title, $url);
 626                                 my $res = $client->send_request($req);
 627                                 if (! ref $res) {
 628                                         error("Did not receive response to ping");
 629                                 }
 630                                 my $r=$res->value;
 631                                 if (! exists $r->{flerror} || $r->{flerror}) {
 632                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 633                                 }
 634                         };
 635                         if ($@) {
 636                                 error "Ping failed: $@";
 637                         }
 638                 }
 639         }
 640
 641         exit 0; # daemon done
 642 }
 643
 644
 645 sub rootpage (@) {
 646         my %params=@_;
 647
 648         my $rootpage;
 649         if (exists $params{rootpage}) {
 650                 $rootpage=bestlink($params{page}, $params{rootpage});
 651                 if (!length $rootpage) {
 652                         $rootpage=$params{rootpage};
 653                 }
 654         }
 655         else {
 656                 $rootpage=$params{page};
 657         }
 658         return $rootpage;
 659 }
 660
 661 1