IkiWiki/Plugin/comments.pm

   1 #!/usr/bin/perl
   2 # Copyright © 2006-2008 Joey Hess <joey@ikiwiki.info>
   3 # Copyright © 2008 Simon McVittie <http://smcv.pseudorandom.co.uk/>
   4 # Licensed under the GNU GPL, version 2, or any later version published by the
   5 # Free Software Foundation
   6 package IkiWiki::Plugin::comments;
   7
   8 use warnings;
   9 use strict;
  10 use IkiWiki 3.00;
  11 use Encode;
  12 use POSIX qw(strftime);
  13
  14 use constant PREVIEW => "Preview";
  15 use constant POST_COMMENT => "Post comment";
  16 use constant CANCEL => "Cancel";
  17
  18 my $postcomment;
  19 my %commentstate;
  20
  21 sub import {
  22         hook(type => "checkconfig", id => 'comments',  call => \&checkconfig);
  23         hook(type => "getsetup", id => 'comments',  call => \&getsetup);
  24         hook(type => "preprocess", id => '_comment', call => \&preprocess);
  25         hook(type => "sessioncgi", id => 'comment', call => \&sessioncgi);
  26         hook(type => "htmlize", id => "_comment", call => \&htmlize);
  27         hook(type => "pagetemplate", id => "comments", call => \&pagetemplate);
  28         hook(type => "formbuilder_setup", id => "comments", call => \&formbuilder_setup);
  29         # Load goto to fix up user page links for logged-in commenters
  30         IkiWiki::loadplugin("goto");
  31         IkiWiki::loadplugin("inline");
  32 }
  33
  34 sub getsetup () {
  35         return
  36                 plugin => {
  37                         safe => 1,
  38                         rebuild => 1,
  39                 },
  40                 comments_pagespec => {
  41                         type => 'pagespec',
  42                         example => 'blog/* and !*/Discussion',
  43                         description => 'PageSpec of pages where comments are allowed',
  44                         link => 'ikiwiki/PageSpec',
  45                         safe => 1,
  46                         rebuild => 1,
  47                 },
  48                 comments_closed_pagespec => {
  49                         type => 'pagespec',
  50                         example => 'blog/controversial or blog/flamewar',
  51                         description => 'PageSpec of pages where posting new comments is not allowed',
  52                         link => 'ikiwiki/PageSpec',
  53                         safe => 1,
  54                         rebuild => 1,
  55                 },
  56                 comments_pagename => {
  57                         type => 'string',
  58                         default => 'comment_',
  59                         description => 'Base name for comments, e.g. "comment_" for pages like "sandbox/comment_12"',
  60                         safe => 0, # manual page moving required
  61                         rebuild => undef,
  62                 },
  63                 comments_allowdirectives => {
  64                         type => 'boolean',
  65                         example => 0,
  66                         description => 'Interpret directives in comments?',
  67                         safe => 1,
  68                         rebuild => 0,
  69                 },
  70                 comments_allowauthor => {
  71                         type => 'boolean',
  72                         example => 0,
  73                         description => 'Allow anonymous commenters to set an author name?',
  74                         safe => 1,
  75                         rebuild => 0,
  76                 },
  77                 comments_commit => {
  78                         type => 'boolean',
  79                         example => 1,
  80                         description => 'commit comments to the VCS',
  81                         # old uncommitted comments are likely to cause
  82                         # confusion if this is changed
  83                         safe => 0,
  84                         rebuild => 0,
  85                 },
  86 }
  87
  88 sub checkconfig () {
  89         $config{comments_commit} = 1
  90                 unless defined $config{comments_commit};
  91         $config{comments_pagespec} = ''
  92                 unless defined $config{comments_pagespec};
  93         $config{comments_closed_pagespec} = ''
  94                 unless defined $config{comments_closed_pagespec};
  95         $config{comments_pagename} = 'comment_'
  96                 unless defined $config{comments_pagename};
  97 }
  98
  99 sub htmlize {
 100         my %params = @_;
 101         return $params{content};
 102 }
 103
 104 # FIXME: copied verbatim from meta
 105 sub safeurl ($) {
 106         my $url=shift;
 107         if (exists $IkiWiki::Plugin::htmlscrubber::{safe_url_regexp} &&
 108             defined $IkiWiki::Plugin::htmlscrubber::safe_url_regexp) {
 109                 return $url=~/$IkiWiki::Plugin::htmlscrubber::safe_url_regexp/;
 110         }
 111         else {
 112                 return 1;
 113         }
 114 }
 115
 116 sub preprocess {
 117         my %params = @_;
 118         my $page = $params{page};
 119
 120         my $format = $params{format};
 121         if (defined $format && ! exists $IkiWiki::hooks{htmlize}{$format}) {
 122                 error(sprintf(gettext("unsupported page format %s"), $format));
 123         }
 124
 125         my $content = $params{content};
 126         if (! defined $content) {
 127                 error(gettext("comment must have content"));
 128         }
 129         $content =~ s/\\"/"/g;
 130
 131         $content = IkiWiki::filter($page, $params{destpage}, $content);
 132
 133         if ($config{comments_allowdirectives}) {
 134                 $content = IkiWiki::preprocess($page, $params{destpage},
 135                         $content);
 136         }
 137
 138         # no need to bother with htmlize if it's just HTML
 139         $content = IkiWiki::htmlize($page, $params{destpage}, $format, $content)
 140                 if defined $format;
 141
 142         IkiWiki::run_hooks(sanitize => sub {
 143                 $content = shift->(
 144                         page => $page,
 145                         destpage => $params{destpage},
 146                         content => $content,
 147                 );
 148         });
 149
 150         # set metadata, possibly overriding [[!meta]] directives from the
 151         # comment itself
 152
 153         my $commentuser;
 154         my $commentip;
 155         my $commentauthor;
 156         my $commentauthorurl;
 157         my $commentopenid;
 158         if (defined $params{username}) {
 159                 $commentuser = $params{username};
 160
 161                 my $oiduser = eval { IkiWiki::openiduser($commentuser) };
 162
 163                 if (defined $oiduser) {
 164                         # looks like an OpenID
 165                         $commentauthorurl = $commentuser;
 166                         $commentauthor = $oiduser;
 167                         $commentopenid = $commentuser;
 168                 }
 169                 else {
 170                         $commentauthorurl = IkiWiki::cgiurl(
 171                                 do => 'goto',
 172                                 page => (length $config{userdir}
 173                                         ? "$config{userdir}/$commentuser"
 174                                         : "$commentuser"));
 175
 176                         $commentauthor = $commentuser;
 177                 }
 178         }
 179         else {
 180                 if (defined $params{ip}) {
 181                         $commentip = $params{ip};
 182                 }
 183                 $commentauthor = gettext("Anonymous");
 184         }
 185
 186         $commentstate{$page}{commentuser} = $commentuser;
 187         $commentstate{$page}{commentopenid} = $commentopenid;
 188         $commentstate{$page}{commentip} = $commentip;
 189         $commentstate{$page}{commentauthor} = $commentauthor;
 190         $commentstate{$page}{commentauthorurl} = $commentauthorurl;
 191         if (! defined $pagestate{$page}{meta}{author}) {
 192                 $pagestate{$page}{meta}{author} = $commentauthor;
 193         }
 194         if (! defined $pagestate{$page}{meta}{authorurl}) {
 195                 $pagestate{$page}{meta}{authorurl} = $commentauthorurl;
 196         }
 197
 198         if ($config{comments_allowauthor}) {
 199                 if (defined $params{claimedauthor}) {
 200                         $pagestate{$page}{meta}{author} = $params{claimedauthor};
 201                 }
 202
 203                 if (defined $params{url}) {
 204                         my $url=$params{url};
 205
 206                         eval q{use URI::Heuristic};
 207                         if (! $@) {
 208                                 $url=URI::Heuristic::uf_uristr($url);
 209                         }
 210
 211                         if (safeurl($url)) {
 212                                 $pagestate{$page}{meta}{authorurl} = $url;
 213                         }
 214                 }
 215         }
 216         else {
 217                 $pagestate{$page}{meta}{author} = $commentauthor;
 218                 $pagestate{$page}{meta}{authorurl} = $commentauthorurl;
 219         }
 220
 221         if (defined $params{subject}) {
 222                 $pagestate{$page}{meta}{title} = $params{subject};
 223         }
 224
 225         if ($params{page} =~ m/\/(\Q$config{comments_pagename}\E\d+)$/) {
 226                 $pagestate{$page}{meta}{permalink} = urlto(IkiWiki::dirname($params{page}), undef, 1).
 227                         "#".$params{page};
 228         }
 229
 230         eval q{use Date::Parse};
 231         if (! $@) {
 232                 my $time = str2time($params{date});
 233                 $IkiWiki::pagectime{$page} = $time if defined $time;
 234         }
 235
 236         return $content;
 237 }
 238
 239 sub sessioncgi ($$) {
 240         my $cgi=shift;
 241         my $session=shift;
 242
 243         my $do = $cgi->param('do');
 244         if ($do eq 'comment') {
 245                 editcomment($cgi, $session);
 246         }
 247         elsif ($do eq 'commentmoderation') {
 248                 commentmoderation($cgi, $session);
 249         }
 250 }
 251
 252 # Mostly cargo-culted from IkiWiki::plugin::editpage
 253 sub editcomment ($$) {
 254         my $cgi=shift;
 255         my $session=shift;
 256
 257         IkiWiki::decode_cgi_utf8($cgi);
 258
 259         eval q{use CGI::FormBuilder};
 260         error($@) if $@;
 261
 262         my @buttons = (POST_COMMENT, PREVIEW, CANCEL);
 263         my $form = CGI::FormBuilder->new(
 264                 fields => [qw{do sid page subject editcontent type author url}],
 265                 charset => 'utf-8',
 266                 method => 'POST',
 267                 required => [qw{editcontent}],
 268                 javascript => 0,
 269                 params => $cgi,
 270                 action => $config{cgiurl},
 271                 header => 0,
 272                 table => 0,
 273                 template => scalar IkiWiki::template_params('editcomment.tmpl'),
 274         );
 275
 276         IkiWiki::decode_form_utf8($form);
 277         IkiWiki::run_hooks(formbuilder_setup => sub {
 278                         shift->(title => "comment", form => $form, cgi => $cgi,
 279                                 session => $session, buttons => \@buttons);
 280                 });
 281         IkiWiki::decode_form_utf8($form);
 282
 283         my $type = $form->param('type');
 284         if (defined $type && length $type && $IkiWiki::hooks{htmlize}{$type}) {
 285                 $type = IkiWiki::possibly_foolish_untaint($type);
 286         }
 287         else {
 288                 $type = $config{default_pageext};
 289         }
 290         my @page_types;
 291         if (exists $IkiWiki::hooks{htmlize}) {
 292                 @page_types = grep { ! /^_/ } keys %{$IkiWiki::hooks{htmlize}};
 293         }
 294
 295         $form->field(name => 'do', type => 'hidden');
 296         $form->field(name => 'sid', type => 'hidden', value => $session->id,
 297                 force => 1);
 298         $form->field(name => 'page', type => 'hidden');
 299         $form->field(name => 'subject', type => 'text', size => 72);
 300         $form->field(name => 'editcontent', type => 'textarea', rows => 10);
 301         $form->field(name => "type", value => $type, force => 1,
 302                 type => 'select', options => \@page_types);
 303
 304         $form->tmpl_param(username => $session->param('name'));
 305
 306         if ($config{comments_allowauthor} and
 307             ! defined $session->param('name')) {
 308                 $form->tmpl_param(allowauthor => 1);
 309                 $form->field(name => 'author', type => 'text', size => '40');
 310                 $form->field(name => 'url', type => 'text', size => '40');
 311         }
 312         else {
 313                 $form->tmpl_param(allowauthor => 0);
 314                 $form->field(name => 'author', type => 'hidden', value => '',
 315                         force => 1);
 316                 $form->field(name => 'url', type => 'hidden', value => '',
 317                         force => 1);
 318         }
 319
 320         # The untaint is OK (as in editpage) because we're about to pass
 321         # it to file_pruned anyway
 322         my $page = $form->field('page');
 323         $page = IkiWiki::possibly_foolish_untaint($page);
 324         if (! defined $page || ! length $page ||
 325                 IkiWiki::file_pruned($page, $config{srcdir})) {
 326                 error(gettext("bad page name"));
 327         }
 328
 329         my $baseurl = urlto($page, undef, 1);
 330
 331         $form->title(sprintf(gettext("commenting on %s"),
 332                         IkiWiki::pagetitle($page)));
 333
 334         $form->tmpl_param('helponformattinglink',
 335                 htmllink($page, $page, 'ikiwiki/formatting',
 336                         noimageinline => 1,
 337                         linktext => 'FormattingHelp'),
 338                         allowdirectives => $config{allow_directives});
 339
 340         if ($form->submitted eq CANCEL) {
 341                 # bounce back to the page they wanted to comment on, and exit.
 342                 # CANCEL need not be considered in future
 343                 IkiWiki::redirect($cgi, urlto($page, undef, 1));
 344                 exit;
 345         }
 346
 347         if (not exists $pagesources{$page}) {
 348                 error(sprintf(gettext(
 349                         "page '%s' doesn't exist, so you can't comment"),
 350                         $page));
 351         }
 352
 353         if (pagespec_match($page, $config{comments_closed_pagespec},
 354                 location => $page)) {
 355                 error(sprintf(gettext(
 356                         "comments on page '%s' are closed"),
 357                         $page));
 358         }
 359
 360         # Set a flag to indicate that we're posting a comment,
 361         # so that postcomment() can tell it should match.
 362         $postcomment=1;
 363         IkiWiki::check_canedit($page, $cgi, $session);
 364         $postcomment=0;
 365
 366         my $location=unique_comment_location($page, $config{srcdir});
 367
 368         my $content = "[[!_comment format=$type\n";
 369
 370         # FIXME: handling of double quotes probably wrong?
 371         if (defined $session->param('name')) {
 372                 my $username = $session->param('name');
 373                 $username =~ s/"/&quot;/g;
 374                 $content .= " username=\"$username\"\n";
 375         }
 376         elsif (defined $ENV{REMOTE_ADDR}) {
 377                 my $ip = $ENV{REMOTE_ADDR};
 378                 if ($ip =~ m/^([.0-9]+)$/) {
 379                         $content .= " ip=\"$1\"\n";
 380                 }
 381         }
 382
 383         if ($config{comments_allowauthor}) {
 384                 my $author = $form->field('author');
 385                 if (defined $author && length $author) {
 386                         $author =~ s/"/&quot;/g;
 387                         $content .= " claimedauthor=\"$author\"\n";
 388                 }
 389                 my $url = $form->field('url');
 390                 if (defined $url && length $url) {
 391                         $url =~ s/"/&quot;/g;
 392                         $content .= " url=\"$url\"\n";
 393                 }
 394         }
 395
 396         my $subject = $form->field('subject');
 397         if (defined $subject && length $subject) {
 398                 $subject =~ s/"/&quot;/g;
 399                 $content .= " subject=\"$subject\"\n";
 400         }
 401
 402         $content .= " date=\"" . decode_utf8(strftime('%Y-%m-%dT%H:%M:%SZ', gmtime)) . "\"\n";
 403
 404         my $editcontent = $form->field('editcontent') || '';
 405         $editcontent =~ s/\r\n/\n/g;
 406         $editcontent =~ s/\r/\n/g;
 407         $editcontent =~ s/"/\\"/g;
 408         $content .= " content=\"\"\"\n$editcontent\n\"\"\"]]\n";
 409
 410         # This is essentially a simplified version of editpage:
 411         # - the user does not control the page that's created, only the parent
 412         # - it's always a create operation, never an edit
 413         # - this means that conflicts should never happen
 414         # - this means that if they do, rocks fall and everyone dies
 415
 416         if ($form->submitted eq PREVIEW) {
 417                 my $preview=previewcomment($content, $location, $page, time);
 418                 IkiWiki::run_hooks(format => sub {
 419                         $preview = shift->(page => $page,
 420                                 content => $preview);
 421                 });
 422                 $form->tmpl_param(page_preview => $preview);
 423         }
 424         else {
 425                 $form->tmpl_param(page_preview => "");
 426         }
 427
 428         if ($form->submitted eq POST_COMMENT && $form->validate) {
 429                 IkiWiki::checksessionexpiry($cgi, $session);
 430
 431                 $postcomment=1;
 432                 my $ok=IkiWiki::check_content(content => $form->field('editcontent'),
 433                         subject => $form->field('subject'),
 434                         $config{comments_allowauthor} ? (
 435                                 author => $form->field('author'),
 436                                 url => $form->field('url'),
 437                         ) : (),
 438                         page => $location,
 439                         cgi => $cgi,
 440                         session => $session,
 441                         nonfatal => 1,
 442                 );
 443                 $postcomment=0;
 444
 445                 if (! $ok) {
 446                         my $penddir=$config{wikistatedir}."/comments_pending";
 447                         $location=unique_comment_location($page, $penddir);
 448                         writefile("$location._comment", $penddir, $content);
 449                         IkiWiki::printheader($session);
 450                         print IkiWiki::misctemplate(gettext(gettext("comment stored for moderation")),
 451                                 "<p>".
 452                                 gettext("Your comment will be posted after moderator review").
 453                                 "</p>");
 454                         exit;
 455                 }
 456
 457                 # FIXME: could probably do some sort of graceful retry
 458                 # on error? Would require significant unwinding though
 459                 my $file = "$location._comment";
 460                 writefile($file, $config{srcdir}, $content);
 461
 462                 my $conflict;
 463
 464                 if ($config{rcs} and $config{comments_commit}) {
 465                         my $message = gettext("Added a comment");
 466                         if (defined $form->field('subject') &&
 467                                 length $form->field('subject')) {
 468                                 $message = sprintf(
 469                                         gettext("Added a comment: %s"),
 470                                         $form->field('subject'));
 471                         }
 472
 473                         IkiWiki::rcs_add($file);
 474                         IkiWiki::disable_commit_hook();
 475                         $conflict = IkiWiki::rcs_commit_staged($message,
 476                                 $session->param('name'), $ENV{REMOTE_ADDR});
 477                         IkiWiki::enable_commit_hook();
 478                         IkiWiki::rcs_update();
 479                 }
 480
 481                 # Now we need a refresh
 482                 require IkiWiki::Render;
 483                 IkiWiki::refresh();
 484                 IkiWiki::saveindex();
 485
 486                 # this should never happen, unless a committer deliberately
 487                 # breaks it or something
 488                 error($conflict) if defined $conflict;
 489
 490                 # Jump to the new comment on the page.
 491                 # The trailing question mark tries to avoid broken
 492                 # caches and get the most recent version of the page.
 493                 IkiWiki::redirect($cgi, urlto($page, undef, 1)."?updated#$location");
 494
 495         }
 496         else {
 497                 IkiWiki::showform ($form, \@buttons, $session, $cgi,
 498                         forcebaseurl => $baseurl);
 499         }
 500
 501         exit;
 502 }
 503
 504 sub commentmoderation ($$) {
 505         my $cgi=shift;
 506         my $session=shift;
 507
 508         IkiWiki::needsignin($cgi, $session);
 509         if (! IkiWiki::is_admin($session->param("name"))) {
 510                 error(gettext("you are not logged in as an admin"));
 511         }
 512
 513         IkiWiki::decode_cgi_utf8($cgi);
 514
 515         if (defined $cgi->param('sid')) {
 516                 IkiWiki::checksessionexpiry($cgi, $session);
 517
 518                 my $rejectalldefer=$cgi->param('rejectalldefer');
 519
 520                 my %vars=$cgi->Vars;
 521                 my $added=0;
 522                 foreach my $id (keys %vars) {
 523                         if ($id =~ /(.*)\Q._comment\E$/) {
 524                                 my $action=$cgi->param($id);
 525                                 next if $action eq 'Defer' && ! $rejectalldefer;
 526
 527                                 # Make sure that the id is of a legal
 528                                 # pending comment before untainting.
 529                                 my ($f)= $id =~ /$config{wiki_file_regexp}/;
 530                                 if (! defined $f || ! length $f ||
 531                                     IkiWiki::file_pruned($f, $config{srcdir})) {
 532                                         error("illegal file");
 533                                 }
 534
 535                                 my $page=IkiWiki::possibly_foolish_untaint(IkiWiki::dirname($1));
 536                                 my $file="$config{wikistatedir}/comments_pending/".
 537                                         IkiWiki::possibly_foolish_untaint($id);
 538
 539                                 if ($action eq 'Accept') {
 540                                         my $content=eval { readfile($file) };
 541                                         next if $@; # file vanished since form was displayed
 542                                         my $dest=unique_comment_location($page, $config{srcdir})."._comment";
 543                                         writefile($dest, $config{srcdir}, $content);
 544                                         if ($config{rcs} and $config{comments_commit}) {
 545                                                 IkiWiki::rcs_add($dest);
 546                                         }
 547                                         $added++;
 548                                 }
 549
 550                                 # This removes empty subdirs, so the
 551                                 # .ikiwiki/comments_pending dir will
 552                                 # go away when all are moderated.
 553                                 require IkiWiki::Render;
 554                                 IkiWiki::prune($file);
 555                         }
 556                 }
 557
 558                 if ($added) {
 559                         my $conflict;
 560                         if ($config{rcs} and $config{comments_commit}) {
 561                                 my $message = gettext("Comment moderation");
 562                                 IkiWiki::disable_commit_hook();
 563                                 $conflict=IkiWiki::rcs_commit_staged($message,
 564                                         $session->param('name'), $ENV{REMOTE_ADDR});
 565                                 IkiWiki::enable_commit_hook();
 566                                 IkiWiki::rcs_update();
 567                         }
 568
 569                         # Now we need a refresh
 570                         require IkiWiki::Render;
 571                         IkiWiki::refresh();
 572                         IkiWiki::saveindex();
 573
 574                         error($conflict) if defined $conflict;
 575                 }
 576         }
 577
 578         my @comments=map {
 579                 my ($id, $ctime)=@{$_};
 580                 my $file="$config{wikistatedir}/comments_pending/$id";
 581                 my $content=readfile($file);
 582                 my $preview=previewcomment($content, $id,
 583                         IkiWiki::dirname($_), $ctime);
 584                 {
 585                         id => $id,
 586                         view => $preview,
 587                 }
 588         } sort { $b->[1] <=> $a->[1] } comments_pending();
 589
 590         my $template=template("commentmoderation.tmpl");
 591         $template->param(
 592                 sid => $session->id,
 593                 comments => \@comments,
 594         );
 595         IkiWiki::printheader($session);
 596         my $out=$template->output;
 597         IkiWiki::run_hooks(format => sub {
 598                 $out = shift->(page => "", content => $out);
 599         });
 600         print IkiWiki::misctemplate(gettext("comment moderation"), $out);
 601         exit;
 602 }
 603
 604 sub formbuilder_setup (@) {
 605         my %params=@_;
 606
 607         my $form=$params{form};
 608         if ($form->title eq "preferences" &&
 609             IkiWiki::is_admin($params{session}->param("name"))) {
 610                 push @{$params{buttons}}, "Comment Moderation";
 611                 if ($form->submitted && $form->submitted eq "Comment Moderation") {
 612                         commentmoderation($params{cgi}, $params{session});
 613                 }
 614         }
 615 }
 616
 617 sub comments_pending () {
 618         my $dir="$config{wikistatedir}/comments_pending/";
 619         return unless -d $dir;
 620
 621         my @ret;
 622         eval q{use File::Find};
 623         error($@) if $@;
 624         find({
 625                 no_chdir => 1,
 626                 wanted => sub {
 627                         $_=decode_utf8($_);
 628                         if (IkiWiki::file_pruned($_, $dir)) {
 629                                 $File::Find::prune=1;
 630                         }
 631                         elsif (! -l $_ && ! -d _) {
 632                                 $File::Find::prune=0;
 633                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 634                                 if (defined $f && $f =~ /\Q._comment\E$/) {
 635                                         my $ctime=(stat($f))[10];
 636                                         $f=~s/^\Q$dir\E\/?//;
 637                                         push @ret, [$f, $ctime];
 638                                 }
 639                         }
 640                 }
 641         }, $dir);
 642
 643         return @ret;
 644 }
 645
 646 sub previewcomment ($$$) {
 647         my $content=shift;
 648         my $location=shift;
 649         my $page=shift;
 650         my $time=shift;
 651
 652         my $preview = IkiWiki::htmlize($location, $page, '_comment',
 653                         IkiWiki::linkify($location, $page,
 654                         IkiWiki::preprocess($location, $page,
 655                         IkiWiki::filter($location, $page, $content), 0, 1)));
 656
 657         my $template = template("comment.tmpl");
 658         $template->param(content => $preview);
 659         $template->param(ctime => displaytime($time));
 660
 661         IkiWiki::run_hooks(pagetemplate => sub {
 662                 shift->(page => $location,
 663                         destpage => $page,
 664                         template => $template);
 665         });
 666
 667         $template->param(have_actions => 0);
 668
 669         return $template->output;
 670 }
 671
 672 sub commentsshown ($) {
 673         my $page=shift;
 674
 675         return ! pagespec_match($page, "internal(*/$config{comments_pagename}*)",
 676                                 location => $page) &&
 677                pagespec_match($page, $config{comments_pagespec},
 678                               location => $page);
 679 }
 680
 681 sub commentsopen ($) {
 682         my $page = shift;
 683
 684         return length $config{cgiurl} > 0 &&
 685                (! length $config{comments_closed_pagespec} ||
 686                 ! pagespec_match($page, $config{comments_closed_pagespec},
 687                                  location => $page));
 688 }
 689
 690 sub pagetemplate (@) {
 691         my %params = @_;
 692
 693         my $page = $params{page};
 694         my $template = $params{template};
 695         my $shown = ($template->query(name => 'commentslink') ||
 696                      $template->query(name => 'commentsurl') ||
 697                      $template->query(name => 'atomcommentsurl') ||
 698                      $template->query(name => 'comments')) &&
 699                     commentsshown($page);
 700
 701         if ($template->query(name => 'comments')) {
 702                 my $comments = undef;
 703                 if ($shown) {
 704                         $comments = IkiWiki::preprocess_inline(
 705                                 pages => "internal($page/$config{comments_pagename}*)",
 706                                 template => 'comment',
 707                                 show => 0,
 708                                 reverse => 'yes',
 709                                 page => $page,
 710                                 destpage => $params{destpage},
 711                                 feedfile => 'comments',
 712                                 emptyfeeds => 'no',
 713                         );
 714                 }
 715
 716                 if (defined $comments && length $comments) {
 717                         $template->param(comments => $comments);
 718                 }
 719
 720                 if ($shown && commentsopen($page)) {
 721                         my $addcommenturl = IkiWiki::cgiurl(do => 'comment',
 722                                 page => $page);
 723                         $template->param(addcommenturl => $addcommenturl);
 724                 }
 725         }
 726
 727         if ($template->query(name => 'commentsurl')) {
 728                 if ($shown) {
 729                         $template->param(commentsurl =>
 730                                 urlto($page, undef, 1).'#comments');
 731                 }
 732         }
 733
 734         if ($template->query(name => 'atomcommentsurl') && $config{usedirs}) {
 735                 if ($shown) {
 736                         # This will 404 until there are some comments, but I
 737                         # think that's probably OK...
 738                         $template->param(atomcommentsurl =>
 739                                 urlto($page, undef, 1).'comments.atom');
 740                 }
 741         }
 742
 743         if ($template->query(name => 'commentslink')) {
 744                 # XXX Would be nice to say how many comments there are in
 745                 # the link. But, to update the number, blog pages
 746                 # would have to update whenever comments of any inlines
 747                 # page are added, which is not currently done.
 748                 if ($shown) {
 749                         $template->param(commentslink =>
 750                                 htmllink($page, $params{destpage}, $page,
 751                                         linktext => gettext("Comments"),
 752                                         anchor => "comments",
 753                                         noimageinline => 1));
 754                 }
 755         }
 756
 757         # everything below this point is only relevant to the comments
 758         # themselves
 759         if (!exists $commentstate{$page}) {
 760                 return;
 761         }
 762
 763         if ($template->query(name => 'commentuser')) {
 764                 $template->param(commentuser =>
 765                         $commentstate{$page}{commentuser});
 766         }
 767
 768         if ($template->query(name => 'commentopenid')) {
 769                 $template->param(commentopenid =>
 770                         $commentstate{$page}{commentopenid});
 771         }
 772
 773         if ($template->query(name => 'commentip')) {
 774                 $template->param(commentip =>
 775                         $commentstate{$page}{commentip});
 776         }
 777
 778         if ($template->query(name => 'commentauthor')) {
 779                 $template->param(commentauthor =>
 780                         $commentstate{$page}{commentauthor});
 781         }
 782
 783         if ($template->query(name => 'commentauthorurl')) {
 784                 $template->param(commentauthorurl =>
 785                         $commentstate{$page}{commentauthorurl});
 786         }
 787
 788         if ($template->query(name => 'removeurl') &&
 789             IkiWiki::Plugin::remove->can("check_canremove") &&
 790             length $config{cgiurl}) {
 791                 $template->param(removeurl => IkiWiki::cgiurl(do => 'remove',
 792                         page => $page));
 793                 $template->param(have_actions => 1);
 794         }
 795 }
 796
 797 sub unique_comment_location ($) {
 798         my $page=shift;
 799         my $dir=shift;
 800
 801         my $location;
 802         my $i = 0;
 803         do {
 804                 $i++;
 805                 $location = "$page/$config{comments_pagename}$i";
 806         } while (-e "$dir/$location._comment");
 807
 808         return $location;
 809 }
 810
 811 package IkiWiki::PageSpec;
 812
 813 sub match_postcomment ($$;@) {
 814         my $page = shift;
 815         my $glob = shift;
 816
 817         if (! $postcomment) {
 818                 return IkiWiki::FailReason->new("not posting a comment");
 819         }
 820         return match_glob($page, $glob);
 821 }
 822
 823 1