IkiWiki/Plugin/comments.pm

   1 #!/usr/bin/perl
   2 # Copyright © 2006-2008 Joey Hess <joey@ikiwiki.info>
   3 # Copyright © 2008 Simon McVittie <http://smcv.pseudorandom.co.uk/>
   4 # Licensed under the GNU GPL, version 2, or any later version published by the
   5 # Free Software Foundation
   6 package IkiWiki::Plugin::comments;
   7
   8 use warnings;
   9 use strict;
  10 use IkiWiki 3.00;
  11 use Encode;
  12 use POSIX qw(strftime);
  13
  14 use constant PREVIEW => "Preview";
  15 use constant POST_COMMENT => "Post comment";
  16 use constant CANCEL => "Cancel";
  17
  18 my $postcomment;
  19 my %commentstate;
  20
  21 sub import {
  22         hook(type => "checkconfig", id => 'comments',  call => \&checkconfig);
  23         hook(type => "getsetup", id => 'comments',  call => \&getsetup);
  24         hook(type => "preprocess", id => 'comment', call => \&preprocess);
  25         # here for backwards compatability with old comments
  26         hook(type => "preprocess", id => '_comment', call => \&preprocess);
  27         hook(type => "sessioncgi", id => 'comment', call => \&sessioncgi);
  28         hook(type => "htmlize", id => "_comment", call => \&htmlize);
  29         hook(type => "htmlize", id => "_comment_pending",
  30                 call => \&htmlize_pending);
  31         hook(type => "pagetemplate", id => "comments", call => \&pagetemplate);
  32         hook(type => "formbuilder_setup", id => "comments",
  33                 call => \&formbuilder_setup);
  34         # Load goto to fix up user page links for logged-in commenters
  35         IkiWiki::loadplugin("goto");
  36         IkiWiki::loadplugin("inline");
  37 }
  38
  39 sub getsetup () {
  40         return
  41                 plugin => {
  42                         safe => 1,
  43                         rebuild => 1,
  44                         section => "web",
  45                 },
  46                 comments_pagespec => {
  47                         type => 'pagespec',
  48                         example => 'blog/* and !*/Discussion',
  49                         description => 'PageSpec of pages where comments are allowed',
  50                         link => 'ikiwiki/PageSpec',
  51                         safe => 1,
  52                         rebuild => 1,
  53                 },
  54                 comments_closed_pagespec => {
  55                         type => 'pagespec',
  56                         example => 'blog/controversial or blog/flamewar',
  57                         description => 'PageSpec of pages where posting new comments is not allowed',
  58                         link => 'ikiwiki/PageSpec',
  59                         safe => 1,
  60                         rebuild => 1,
  61                 },
  62                 comments_pagename => {
  63                         type => 'string',
  64                         default => 'comment_',
  65                         description => 'Base name for comments, e.g. "comment_" for pages like "sandbox/comment_12"',
  66                         safe => 0, # manual page moving required
  67                         rebuild => undef,
  68                 },
  69                 comments_allowdirectives => {
  70                         type => 'boolean',
  71                         example => 0,
  72                         description => 'Interpret directives in comments?',
  73                         safe => 1,
  74                         rebuild => 0,
  75                 },
  76                 comments_allowauthor => {
  77                         type => 'boolean',
  78                         example => 0,
  79                         description => 'Allow anonymous commenters to set an author name?',
  80                         safe => 1,
  81                         rebuild => 0,
  82                 },
  83                 comments_commit => {
  84                         type => 'boolean',
  85                         example => 1,
  86                         description => 'commit comments to the VCS',
  87                         # old uncommitted comments are likely to cause
  88                         # confusion if this is changed
  89                         safe => 0,
  90                         rebuild => 0,
  91                 },
  92 }
  93
  94 sub checkconfig () {
  95         $config{comments_commit} = 1
  96                 unless defined $config{comments_commit};
  97         $config{comments_pagespec} = ''
  98                 unless defined $config{comments_pagespec};
  99         $config{comments_closed_pagespec} = ''
 100                 unless defined $config{comments_closed_pagespec};
 101         $config{comments_pagename} = 'comment_'
 102                 unless defined $config{comments_pagename};
 103 }
 104
 105 sub htmlize {
 106         my %params = @_;
 107         return $params{content};
 108 }
 109
 110 sub htmlize_pending {
 111         my %params = @_;
 112         return sprintf(gettext("this comment needs %s"),
 113                 '<a href="'.
 114                 IkiWiki::cgiurl(do => "commentmoderation").'">'.
 115                 gettext("moderation").'</a>');
 116 }
 117
 118 # FIXME: copied verbatim from meta
 119 sub safeurl ($) {
 120         my $url=shift;
 121         if (exists $IkiWiki::Plugin::htmlscrubber::{safe_url_regexp} &&
 122             defined $IkiWiki::Plugin::htmlscrubber::safe_url_regexp) {
 123                 return $url=~/$IkiWiki::Plugin::htmlscrubber::safe_url_regexp/;
 124         }
 125         else {
 126                 return 1;
 127         }
 128 }
 129
 130 sub preprocess {
 131         my %params = @_;
 132         my $page = $params{page};
 133
 134         my $format = $params{format};
 135         if (defined $format && ! exists $IkiWiki::hooks{htmlize}{$format}) {
 136                 error(sprintf(gettext("unsupported page format %s"), $format));
 137         }
 138
 139         my $content = $params{content};
 140         if (! defined $content) {
 141                 error(gettext("comment must have content"));
 142         }
 143         $content =~ s/\\"/"/g;
 144
 145         $content = IkiWiki::filter($page, $params{destpage}, $content);
 146
 147         if ($config{comments_allowdirectives}) {
 148                 $content = IkiWiki::preprocess($page, $params{destpage},
 149                         $content);
 150         }
 151
 152         # no need to bother with htmlize if it's just HTML
 153         $content = IkiWiki::htmlize($page, $params{destpage}, $format, $content)
 154                 if defined $format;
 155
 156         IkiWiki::run_hooks(sanitize => sub {
 157                 $content = shift->(
 158                         page => $page,
 159                         destpage => $params{destpage},
 160                         content => $content,
 161                 );
 162         });
 163
 164         # set metadata, possibly overriding [[!meta]] directives from the
 165         # comment itself
 166
 167         my $commentuser;
 168         my $commentip;
 169         my $commentauthor;
 170         my $commentauthorurl;
 171         my $commentopenid;
 172         if (defined $params{username}) {
 173                 $commentuser = $params{username};
 174
 175                 my $oiduser = eval { IkiWiki::openiduser($commentuser) };
 176
 177                 if (defined $oiduser) {
 178                         # looks like an OpenID
 179                         $commentauthorurl = $commentuser;
 180                         $commentauthor = $oiduser;
 181                         $commentopenid = $commentuser;
 182                 }
 183                 else {
 184                         $commentauthorurl = IkiWiki::cgiurl(
 185                                 do => 'goto',
 186                                 page => IkiWiki::userpage($commentuser)
 187                         );
 188
 189                         $commentauthor = $commentuser;
 190                 }
 191         }
 192         else {
 193                 if (defined $params{ip}) {
 194                         $commentip = $params{ip};
 195                 }
 196                 $commentauthor = gettext("Anonymous");
 197         }
 198
 199         $commentstate{$page}{commentuser} = $commentuser;
 200         $commentstate{$page}{commentopenid} = $commentopenid;
 201         $commentstate{$page}{commentip} = $commentip;
 202         $commentstate{$page}{commentauthor} = $commentauthor;
 203         $commentstate{$page}{commentauthorurl} = $commentauthorurl;
 204         if (! defined $pagestate{$page}{meta}{author}) {
 205                 $pagestate{$page}{meta}{author} = $commentauthor;
 206         }
 207         if (! defined $pagestate{$page}{meta}{authorurl}) {
 208                 $pagestate{$page}{meta}{authorurl} = $commentauthorurl;
 209         }
 210
 211         if ($config{comments_allowauthor}) {
 212                 if (defined $params{claimedauthor}) {
 213                         $pagestate{$page}{meta}{author} = $params{claimedauthor};
 214                 }
 215
 216                 if (defined $params{url}) {
 217                         my $url=$params{url};
 218
 219                         eval q{use URI::Heuristic};
 220                         if (! $@) {
 221                                 $url=URI::Heuristic::uf_uristr($url);
 222                         }
 223
 224                         if (safeurl($url)) {
 225                                 $pagestate{$page}{meta}{authorurl} = $url;
 226                         }
 227                 }
 228         }
 229         else {
 230                 $pagestate{$page}{meta}{author} = $commentauthor;
 231                 $pagestate{$page}{meta}{authorurl} = $commentauthorurl;
 232         }
 233
 234         if (defined $params{subject}) {
 235                 # decode title the same way meta does
 236                 eval q{use HTML::Entities};
 237                 $pagestate{$page}{meta}{title} = decode_entities($params{subject});
 238         }
 239
 240         if ($params{page} =~ m/\/\Q$config{comments_pagename}\E\d+_/) {
 241                 $pagestate{$page}{meta}{permalink} = urlto(IkiWiki::dirname($params{page}), undef, 1).
 242                         "#".page_to_id($params{page});
 243         }
 244
 245         eval q{use Date::Parse};
 246         if (! $@) {
 247                 my $time = str2time($params{date});
 248                 $IkiWiki::pagectime{$page} = $time if defined $time;
 249         }
 250
 251         return $content;
 252 }
 253
 254 sub sessioncgi ($$) {
 255         my $cgi=shift;
 256         my $session=shift;
 257
 258         my $do = $cgi->param('do');
 259         if ($do eq 'comment') {
 260                 editcomment($cgi, $session);
 261         }
 262         elsif ($do eq 'commentmoderation') {
 263                 commentmoderation($cgi, $session);
 264         }
 265         elsif ($do eq 'commentsignin') {
 266                 IkiWiki::cgi_signin($cgi, $session);
 267                 exit;
 268         }
 269 }
 270
 271 # Mostly cargo-culted from IkiWiki::plugin::editpage
 272 sub editcomment ($$) {
 273         my $cgi=shift;
 274         my $session=shift;
 275
 276         IkiWiki::decode_cgi_utf8($cgi);
 277
 278         eval q{use CGI::FormBuilder};
 279         error($@) if $@;
 280
 281         my @buttons = (POST_COMMENT, PREVIEW, CANCEL);
 282         my $form = CGI::FormBuilder->new(
 283                 fields => [qw{do sid page subject editcontent type author url}],
 284                 charset => 'utf-8',
 285                 method => 'POST',
 286                 required => [qw{editcontent}],
 287                 javascript => 0,
 288                 params => $cgi,
 289                 action => $config{cgiurl},
 290                 header => 0,
 291                 table => 0,
 292                 template => { template('editcomment.tmpl') },
 293         );
 294
 295         IkiWiki::decode_form_utf8($form);
 296         IkiWiki::run_hooks(formbuilder_setup => sub {
 297                         shift->(title => "comment", form => $form, cgi => $cgi,
 298                                 session => $session, buttons => \@buttons);
 299                 });
 300         IkiWiki::decode_form_utf8($form);
 301
 302         my $type = $form->param('type');
 303         if (defined $type && length $type && $IkiWiki::hooks{htmlize}{$type}) {
 304                 $type = IkiWiki::possibly_foolish_untaint($type);
 305         }
 306         else {
 307                 $type = $config{default_pageext};
 308         }
 309
 310
 311         my @page_types;
 312         if (exists $IkiWiki::hooks{htmlize}) {
 313                 foreach my $key (grep { !/^_/ } keys %{$IkiWiki::hooks{htmlize}}) {
 314                         push @page_types, [$key, $IkiWiki::hooks{htmlize}{$key}{longname} || $key];
 315                 }
 316         }
 317         @page_types=sort @page_types;
 318
 319         $form->field(name => 'do', type => 'hidden');
 320         $form->field(name => 'sid', type => 'hidden', value => $session->id,
 321                 force => 1);
 322         $form->field(name => 'page', type => 'hidden');
 323         $form->field(name => 'subject', type => 'text', size => 72);
 324         $form->field(name => 'editcontent', type => 'textarea', rows => 10);
 325         $form->field(name => "type", value => $type, force => 1,
 326                 type => 'select', options => \@page_types);
 327
 328         $form->tmpl_param(username => $session->param('name'));
 329
 330         if ($config{comments_allowauthor} and
 331             ! defined $session->param('name')) {
 332                 $form->tmpl_param(allowauthor => 1);
 333                 $form->field(name => 'author', type => 'text', size => '40');
 334                 $form->field(name => 'url', type => 'text', size => '40');
 335         }
 336         else {
 337                 $form->tmpl_param(allowauthor => 0);
 338                 $form->field(name => 'author', type => 'hidden', value => '',
 339                         force => 1);
 340                 $form->field(name => 'url', type => 'hidden', value => '',
 341                         force => 1);
 342         }
 343
 344         if (! defined $session->param('name')) {
 345                 # Make signinurl work and return here.
 346                 $form->tmpl_param(signinurl => IkiWiki::cgiurl(do => 'commentsignin'));
 347                 $session->param(postsignin => $ENV{QUERY_STRING});
 348                 IkiWiki::cgi_savesession($session);
 349         }
 350
 351         # The untaint is OK (as in editpage) because we're about to pass
 352         # it to file_pruned anyway
 353         my $page = $form->field('page');
 354         $page = IkiWiki::possibly_foolish_untaint($page);
 355         if (! defined $page || ! length $page ||
 356                 IkiWiki::file_pruned($page)) {
 357                 error(gettext("bad page name"));
 358         }
 359
 360         my $baseurl = urlto($page, undef, 1);
 361
 362         $form->title(sprintf(gettext("commenting on %s"),
 363                         IkiWiki::pagetitle($page)));
 364
 365         $form->tmpl_param('helponformattinglink',
 366                 htmllink($page, $page, 'ikiwiki/formatting',
 367                         noimageinline => 1,
 368                         linktext => 'FormattingHelp'),
 369                         allowdirectives => $config{allow_directives});
 370
 371         if ($form->submitted eq CANCEL) {
 372                 # bounce back to the page they wanted to comment on, and exit.
 373                 # CANCEL need not be considered in future
 374                 IkiWiki::redirect($cgi, urlto($page, undef, 1));
 375                 exit;
 376         }
 377
 378         if (not exists $pagesources{$page}) {
 379                 error(sprintf(gettext(
 380                         "page '%s' doesn't exist, so you can't comment"),
 381                         $page));
 382         }
 383
 384         if (pagespec_match($page, $config{comments_closed_pagespec},
 385                 location => $page)) {
 386                 error(sprintf(gettext(
 387                         "comments on page '%s' are closed"),
 388                         $page));
 389         }
 390
 391         # Set a flag to indicate that we're posting a comment,
 392         # so that postcomment() can tell it should match.
 393         $postcomment=1;
 394         IkiWiki::check_canedit($page, $cgi, $session);
 395         $postcomment=0;
 396
 397         my $content = "[[!comment format=$type\n";
 398
 399         # FIXME: handling of double quotes probably wrong?
 400         if (defined $session->param('name')) {
 401                 my $username = $session->param('name');
 402                 $username =~ s/"/&quot;/g;
 403                 $content .= " username=\"$username\"\n";
 404         }
 405         elsif (defined $ENV{REMOTE_ADDR}) {
 406                 my $ip = $ENV{REMOTE_ADDR};
 407                 if ($ip =~ m/^([.0-9]+)$/) {
 408                         $content .= " ip=\"$1\"\n";
 409                 }
 410         }
 411
 412         if ($config{comments_allowauthor}) {
 413                 my $author = $form->field('author');
 414                 if (defined $author && length $author) {
 415                         $author =~ s/"/&quot;/g;
 416                         $content .= " claimedauthor=\"$author\"\n";
 417                 }
 418                 my $url = $form->field('url');
 419                 if (defined $url && length $url) {
 420                         $url =~ s/"/&quot;/g;
 421                         $content .= " url=\"$url\"\n";
 422                 }
 423         }
 424
 425         my $subject = $form->field('subject');
 426         if (defined $subject && length $subject) {
 427                 $subject =~ s/"/&quot;/g;
 428         }
 429         else {
 430                 $subject = "comment ".(num_comments($page, $config{srcdir}) + 1);
 431         }
 432         $content .= " subject=\"$subject\"\n";
 433
 434         $content .= " date=\"" . decode_utf8(strftime('%Y-%m-%dT%H:%M:%SZ', gmtime)) . "\"\n";
 435
 436         my $editcontent = $form->field('editcontent') || '';
 437         $editcontent =~ s/\r\n/\n/g;
 438         $editcontent =~ s/\r/\n/g;
 439         $editcontent =~ s/"/\\"/g;
 440         $content .= " content=\"\"\"\n$editcontent\n\"\"\"]]\n";
 441
 442         my $location=unique_comment_location($page, $content, $config{srcdir});
 443
 444         # This is essentially a simplified version of editpage:
 445         # - the user does not control the page that's created, only the parent
 446         # - it's always a create operation, never an edit
 447         # - this means that conflicts should never happen
 448         # - this means that if they do, rocks fall and everyone dies
 449
 450         if ($form->submitted eq PREVIEW) {
 451                 my $preview=previewcomment($content, $location, $page, time);
 452                 IkiWiki::run_hooks(format => sub {
 453                         $preview = shift->(page => $page,
 454                                 content => $preview);
 455                 });
 456                 $form->tmpl_param(page_preview => $preview);
 457         }
 458         else {
 459                 $form->tmpl_param(page_preview => "");
 460         }
 461
 462         if ($form->submitted eq POST_COMMENT && $form->validate) {
 463                 IkiWiki::checksessionexpiry($cgi, $session);
 464
 465                 $postcomment=1;
 466                 my $ok=IkiWiki::check_content(content => $form->field('editcontent'),
 467                         subject => $form->field('subject'),
 468                         $config{comments_allowauthor} ? (
 469                                 author => $form->field('author'),
 470                                 url => $form->field('url'),
 471                         ) : (),
 472                         page => $location,
 473                         cgi => $cgi,
 474                         session => $session,
 475                         nonfatal => 1,
 476                 );
 477                 $postcomment=0;
 478
 479                 if (! $ok) {
 480                         $location=unique_comment_location($page, $content, $config{srcdir}, "._comment_pending");
 481                         writefile("$location._comment_pending", $config{srcdir}, $content);
 482
 483                         # Refresh so anything that deals with pending
 484                         # comments can be updated.
 485                         require IkiWiki::Render;
 486                         IkiWiki::refresh();
 487                         IkiWiki::saveindex();
 488
 489                         IkiWiki::printheader($session);
 490                         print IkiWiki::misctemplate(gettext(gettext("comment stored for moderation")),
 491                                 "<p>".
 492                                 gettext("Your comment will be posted after moderator review").
 493                                 "</p>");
 494                         exit;
 495                 }
 496
 497                 # FIXME: could probably do some sort of graceful retry
 498                 # on error? Would require significant unwinding though
 499                 my $file = "$location._comment";
 500                 writefile($file, $config{srcdir}, $content);
 501
 502                 my $conflict;
 503
 504                 if ($config{rcs} and $config{comments_commit}) {
 505                         my $message = gettext("Added a comment");
 506                         if (defined $form->field('subject') &&
 507                                 length $form->field('subject')) {
 508                                 $message = sprintf(
 509                                         gettext("Added a comment: %s"),
 510                                         $form->field('subject'));
 511                         }
 512
 513                         IkiWiki::rcs_add($file);
 514                         IkiWiki::disable_commit_hook();
 515                         $conflict = IkiWiki::rcs_commit_staged($message,
 516                                 $session->param('name'), $ENV{REMOTE_ADDR});
 517                         IkiWiki::enable_commit_hook();
 518                         IkiWiki::rcs_update();
 519                 }
 520
 521                 # Now we need a refresh
 522                 require IkiWiki::Render;
 523                 IkiWiki::refresh();
 524                 IkiWiki::saveindex();
 525
 526                 # this should never happen, unless a committer deliberately
 527                 # breaks it or something
 528                 error($conflict) if defined $conflict;
 529
 530                 # Jump to the new comment on the page.
 531                 # The trailing question mark tries to avoid broken
 532                 # caches and get the most recent version of the page.
 533                 IkiWiki::redirect($cgi, urlto($page, undef, 1).
 534                         "?updated#".page_to_id($location));
 535
 536         }
 537         else {
 538                 IkiWiki::showform ($form, \@buttons, $session, $cgi,
 539                         forcebaseurl => $baseurl);
 540         }
 541
 542         exit;
 543 }
 544
 545 sub commentmoderation ($$) {
 546         my $cgi=shift;
 547         my $session=shift;
 548
 549         IkiWiki::needsignin($cgi, $session);
 550         if (! IkiWiki::is_admin($session->param("name"))) {
 551                 error(gettext("you are not logged in as an admin"));
 552         }
 553
 554         IkiWiki::decode_cgi_utf8($cgi);
 555
 556         if (defined $cgi->param('sid')) {
 557                 IkiWiki::checksessionexpiry($cgi, $session);
 558
 559                 my $rejectalldefer=$cgi->param('rejectalldefer');
 560
 561                 my %vars=$cgi->Vars;
 562                 my $added=0;
 563                 foreach my $id (keys %vars) {
 564                         if ($id =~ /(.*)\._comment(?:_pending)?$/) {
 565                                 my $action=$cgi->param($id);
 566                                 next if $action eq 'Defer' && ! $rejectalldefer;
 567
 568                                 # Make sure that the id is of a legal
 569                                 # pending comment.
 570                                 my ($f) = $id =~ /$config{wiki_file_regexp}/;
 571                                 if (! defined $f || ! length $f ||
 572                                     IkiWiki::file_pruned($f)) {
 573                                         error("illegal file");
 574                                 }
 575
 576                                 my $page=IkiWiki::dirname($f);
 577                                 my $file="$config{srcdir}/$f";
 578                                 if (! -e $file) {
 579                                         # old location
 580                                         $file="$config{wikistatedir}/comments_pending/".$f;
 581                                 }
 582
 583                                 if ($action eq 'Accept') {
 584                                         my $content=eval { readfile($file) };
 585                                         next if $@; # file vanished since form was displayed
 586                                         my $dest=unique_comment_location($page, $content, $config{srcdir})."._comment";
 587                                         writefile($dest, $config{srcdir}, $content);
 588                                         if ($config{rcs} and $config{comments_commit}) {
 589                                                 IkiWiki::rcs_add($dest);
 590                                         }
 591                                         $added++;
 592                                 }
 593
 594                                 require IkiWiki::Render;
 595                                 IkiWiki::prune($file);
 596                         }
 597                 }
 598
 599                 if ($added) {
 600                         my $conflict;
 601                         if ($config{rcs} and $config{comments_commit}) {
 602                                 my $message = gettext("Comment moderation");
 603                                 IkiWiki::disable_commit_hook();
 604                                 $conflict=IkiWiki::rcs_commit_staged($message,
 605                                         $session->param('name'), $ENV{REMOTE_ADDR});
 606                                 IkiWiki::enable_commit_hook();
 607                                 IkiWiki::rcs_update();
 608                         }
 609
 610                         # Now we need a refresh
 611                         require IkiWiki::Render;
 612                         IkiWiki::refresh();
 613                         IkiWiki::saveindex();
 614
 615                         error($conflict) if defined $conflict;
 616                 }
 617         }
 618
 619         my @comments=map {
 620                 my ($id, $dir, $ctime)=@{$_};
 621                 my $content=readfile("$dir/$id");
 622                 my $preview=previewcomment($content, $id,
 623                         $id, $ctime);
 624                 {
 625                         id => $id,
 626                         view => $preview,
 627                 }
 628         } sort { $b->[2] <=> $a->[2] } comments_pending();
 629
 630         my $template=template("commentmoderation.tmpl");
 631         $template->param(
 632                 sid => $session->id,
 633                 comments => \@comments,
 634         );
 635         IkiWiki::printheader($session);
 636         my $out=$template->output;
 637         IkiWiki::run_hooks(format => sub {
 638                 $out = shift->(page => "", content => $out);
 639         });
 640         print IkiWiki::misctemplate(gettext("comment moderation"), $out);
 641         exit;
 642 }
 643
 644 sub formbuilder_setup (@) {
 645         my %params=@_;
 646
 647         my $form=$params{form};
 648         if ($form->title eq "preferences" &&
 649             IkiWiki::is_admin($params{session}->param("name"))) {
 650                 push @{$params{buttons}}, "Comment Moderation";
 651                 if ($form->submitted && $form->submitted eq "Comment Moderation") {
 652                         commentmoderation($params{cgi}, $params{session});
 653                 }
 654         }
 655 }
 656
 657 sub comments_pending () {
 658         my @ret;
 659
 660         eval q{use File::Find};
 661         error($@) if $@;
 662
 663         my $find_comments=sub {
 664                 my $dir=shift;
 665                 my $extension=shift;
 666                 return unless -d $dir;
 667                 find({
 668                         no_chdir => 1,
 669                         wanted => sub {
 670                                 my $file=decode_utf8($_);
 671                                 $file=~s/^\Q$dir\E\/?//;
 672                                 return if ! length $file || IkiWiki::file_pruned($file)
 673                                         || -l $_ || -d _ || $file !~ /\Q$extension\E$/;
 674                                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 675                                 if (defined $f) {
 676                                         my $ctime=(stat($_))[10];
 677                                         push @ret, [$f, $dir, $ctime];
 678                                 }
 679                         }
 680                 }, $dir);
 681         };
 682
 683         $find_comments->($config{srcdir}, "._comment_pending");
 684         # old location
 685         $find_comments->("$config{wikistatedir}/comments_pending/",
 686                 "._comment");
 687
 688         return @ret;
 689 }
 690
 691 sub previewcomment ($$$) {
 692         my $content=shift;
 693         my $location=shift;
 694         my $page=shift;
 695         my $time=shift;
 696
 697         my $preview = IkiWiki::htmlize($location, $page, '_comment',
 698                         IkiWiki::linkify($location, $page,
 699                         IkiWiki::preprocess($location, $page,
 700                         IkiWiki::filter($location, $page, $content), 0, 1)));
 701
 702         my $template = template("comment.tmpl");
 703         $template->param(content => $preview);
 704         $template->param(ctime => displaytime($time, undef, 1));
 705         $template->param(html5 => $config{html5});
 706
 707         IkiWiki::run_hooks(pagetemplate => sub {
 708                 shift->(page => $location,
 709                         destpage => $page,
 710                         template => $template);
 711         });
 712
 713         $template->param(have_actions => 0);
 714
 715         return $template->output;
 716 }
 717
 718 sub commentsshown ($) {
 719         my $page=shift;
 720
 721         return ! pagespec_match($page, "comment(*)",
 722                                 location => $page) &&
 723                pagespec_match($page, $config{comments_pagespec},
 724                               location => $page);
 725 }
 726
 727 sub commentsopen ($) {
 728         my $page = shift;
 729
 730         return length $config{cgiurl} > 0 &&
 731                (! length $config{comments_closed_pagespec} ||
 732                 ! pagespec_match($page, $config{comments_closed_pagespec},
 733                                  location => $page));
 734 }
 735
 736 sub pagetemplate (@) {
 737         my %params = @_;
 738
 739         my $page = $params{page};
 740         my $template = $params{template};
 741         my $shown = ($template->query(name => 'commentslink') ||
 742                      $template->query(name => 'commentsurl') ||
 743                      $template->query(name => 'atomcommentsurl') ||
 744                      $template->query(name => 'comments')) &&
 745                     commentsshown($page);
 746
 747         if ($template->query(name => 'comments')) {
 748                 my $comments = undef;
 749                 if ($shown) {
 750                         $comments = IkiWiki::preprocess_inline(
 751                                 pages => "comment($page)",
 752                                 template => 'comment',
 753                                 show => 0,
 754                                 reverse => 'yes',
 755                                 page => $page,
 756                                 destpage => $params{destpage},
 757                                 feedfile => 'comments',
 758                                 emptyfeeds => 'no',
 759                         );
 760                 }
 761
 762                 if (defined $comments && length $comments) {
 763                         $template->param(comments => $comments);
 764                 }
 765
 766                 if ($shown && commentsopen($page)) {
 767                         $template->param(addcommenturl => addcommenturl($page));
 768                 }
 769         }
 770
 771         if ($shown) {
 772                 if ($template->query(name => 'commentsurl')) {
 773                         $template->param(commentsurl =>
 774                                 urlto($page, undef, 1).'#comments');
 775                 }
 776
 777                 if ($template->query(name => 'atomcommentsurl') && $config{usedirs}) {
 778                         # This will 404 until there are some comments, but I
 779                         # think that's probably OK...
 780                         $template->param(atomcommentsurl =>
 781                                 urlto($page, undef, 1).'comments.atom');
 782                 }
 783
 784                 if ($template->query(name => 'commentslink')) {
 785                         my $num=num_comments($page, $config{srcdir});
 786                         my $link;
 787                         if ($num > 0) {
 788                                 $link = htmllink($page, $params{destpage}, $page,
 789                                         linktext => sprintf(ngettext("%i comment", "%i comments", $num), $num),
 790                                         anchor => "comments",
 791                                         noimageinline => 1
 792                                 );
 793                         }
 794                         elsif (commentsopen($page)) {
 795                                 $link = "<a href=\"".addcommenturl($page)."\">".
 796                                         #translators: Here "Comment" is a verb;
 797                                         #translators: the user clicks on it to
 798                                         #translators: post a comment.
 799                                         gettext("Comment").
 800                                         "</a>";
 801                         }
 802                         $template->param(commentslink => $link)
 803                                 if defined $link;
 804                 }
 805         }
 806
 807         # everything below this point is only relevant to the comments
 808         # themselves
 809         if (!exists $commentstate{$page}) {
 810                 return;
 811         }
 812
 813         if ($template->query(name => 'commentid')) {
 814                 $template->param(commentid => page_to_id($page));
 815         }
 816
 817         if ($template->query(name => 'commentuser')) {
 818                 $template->param(commentuser =>
 819                         $commentstate{$page}{commentuser});
 820         }
 821
 822         if ($template->query(name => 'commentopenid')) {
 823                 $template->param(commentopenid =>
 824                         $commentstate{$page}{commentopenid});
 825         }
 826
 827         if ($template->query(name => 'commentip')) {
 828                 $template->param(commentip =>
 829                         $commentstate{$page}{commentip});
 830         }
 831
 832         if ($template->query(name => 'commentauthor')) {
 833                 $template->param(commentauthor =>
 834                         $commentstate{$page}{commentauthor});
 835         }
 836
 837         if ($template->query(name => 'commentauthorurl')) {
 838                 $template->param(commentauthorurl =>
 839                         $commentstate{$page}{commentauthorurl});
 840         }
 841
 842         if ($template->query(name => 'removeurl') &&
 843             IkiWiki::Plugin::remove->can("check_canremove") &&
 844             length $config{cgiurl}) {
 845                 $template->param(removeurl => IkiWiki::cgiurl(do => 'remove',
 846                         page => $page));
 847                 $template->param(have_actions => 1);
 848         }
 849 }
 850
 851 sub addcommenturl ($) {
 852         my $page=shift;
 853
 854         return IkiWiki::cgiurl(do => 'comment', page => $page);
 855 }
 856
 857 sub num_comments ($$) {
 858         my $page=shift;
 859         my $dir=shift;
 860
 861         my @comments=glob("$dir/$page/$config{comments_pagename}*._comment");
 862         return @comments;
 863 }
 864
 865 sub unique_comment_location ($$$$) {
 866         my $page=shift;
 867         eval q{use Digest::MD5 'md5_hex'};
 868         error($@) if $@;
 869         my $content_md5=md5_hex(Encode::encode_utf8(shift));
 870         my $dir=shift;
 871         my $ext=shift || "._comment";
 872
 873         my $location;
 874         my $i = num_comments($page, $dir);
 875         do {
 876                 $i++;
 877                 $location = "$page/$config{comments_pagename}${i}_${content_md5}";
 878         } while (-e "$dir/$location$ext");
 879
 880         return $location;
 881 }
 882
 883 sub page_to_id ($) {
 884         # Converts a comment page name into a unique, legal html id
 885         # attribute value, that can be used as an anchor to link to the
 886         # comment.
 887         my $page=shift;
 888
 889         eval q{use Digest::MD5 'md5_hex'};
 890         error($@) if $@;
 891
 892         return "comment-".md5_hex(Encode::encode_utf8(($page)));
 893 }
 894
 895 package IkiWiki::PageSpec;
 896
 897 sub match_postcomment ($$;@) {
 898         my $page = shift;
 899         my $glob = shift;
 900
 901         if (! $postcomment) {
 902                 return IkiWiki::FailReason->new("not posting a comment");
 903         }
 904         return match_glob($page, $glob, @_);
 905 }
 906
 907 sub match_comment ($$;@) {
 908         my $page = shift;
 909         my $glob = shift;
 910
 911         if (! IkiWiki::isinternal($page)) {
 912                 return IkiWiki::FailReason->new("$page is not a comment");
 913         }
 914         my $type=IkiWiki::pagetype($IkiWiki::pagesources{$page});
 915         if (defined $type && $type ne "_comment") {
 916                 return IkiWiki::FailReason->new("$page is not a comment");
 917         }
 918
 919         return match_glob($page, "$glob/*", internal => 1, @_);
 920 }
 921
 922 sub match_comment_pending ($$;@) {
 923         my $page = shift;
 924         my $glob = shift;
 925
 926         if (! IkiWiki::isinternal($page)) {
 927                 return IkiWiki::FailReason->new("$page is not a pending comment");
 928         }
 929         my $type=IkiWiki::pagetype($IkiWiki::pagesources{$page});
 930         if (defined $type && $type ne "_comment_pending") {
 931                 return IkiWiki::FailReason->new("$page is not a pending comment");
 932         }
 933
 934         return match_glob($page, "$glob/*", internal => 1, @_);
 935 }
 936
 937 1