IkiWiki/Plugin/autoindex.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::autoindex;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use Encode;
   8
   9 sub import {
  10         hook(type => "getsetup", id => "autoindex", call => \&getsetup);
  11         hook(type => "refresh", id => "autoindex", call => \&refresh);
  12 }
  13
  14 sub getsetup () {
  15         return
  16                 plugin => {
  17                         safe => 1,
  18                         rebuild => 0,
  19                 },
  20 }
  21
  22 sub genindex ($) {
  23         my $page=shift;
  24         my $file=newpagefile($page, $config{default_pageext});
  25         my $template=template("autoindex.tmpl");
  26         $template->param(page => $page);
  27         writefile($file, $config{srcdir}, $template->output);
  28         if ($config{rcs}) {
  29                 IkiWiki::rcs_add($file);
  30         }
  31 }
  32
  33 sub refresh () {
  34         eval q{use File::Find};
  35         error($@) if $@;
  36
  37         my (%pages, %dirs);
  38         foreach my $dir ($config{srcdir}, @{$config{underlaydirs}}, $config{underlaydir}) {
  39                 find({
  40                         no_chdir => 1,
  41                         wanted => sub {
  42                                 $_=decode_utf8($_);
  43                                 if (IkiWiki::file_pruned($_, $dir)) {
  44                                         $File::Find::prune=1;
  45                                 }
  46                                 elsif (! -l $_) {
  47                                         my ($f)=/$config{wiki_file_regexp}/; # untaint
  48                                         return unless defined $f;
  49                                         $f=~s/^\Q$dir\E\/?//;
  50                                         return unless length $f;
  51                                         return if $f =~ /\._([^.]+)$/; # skip internal page
  52                                         if (! -d _) {
  53                                                 $pages{pagename($f)}=1;
  54                                         }
  55                                         elsif ($dir eq $config{srcdir}) {
  56                                                 $dirs{$f}=1;
  57                                         }
  58                                 }
  59                         }
  60                 }, $dir);
  61         }
  62
  63         my %deleted;
  64         if (ref $wikistate{autoindex}{deleted}) {
  65                 %deleted=%{$wikistate{autoindex}{deleted}};
  66         }
  67         elsif (ref $pagestate{index}{autoindex}{deleted}) {
  68                 # compatability code
  69                 %deleted=%{$pagestate{index}{autoindex}{deleted}};
  70                 delete $pagestate{index}{autoindex};
  71         }
  72
  73         if (keys %deleted) {
  74                 foreach my $dir (keys %deleted) {
  75                         # remove deleted page state if the deleted page is re-added,
  76                         # or if all its subpages are deleted
  77                         if ($deleted{$dir} && (exists $pages{$dir} ||
  78                                                ! grep /^$dir\/.*/, keys %pages)) {
  79                                 delete $deleted{$dir};
  80                         }
  81                 }
  82                 $wikistate{autoindex}{deleted}=\%deleted;
  83         }
  84
  85         my @needed;
  86         foreach my $dir (keys %dirs) {
  87                 if (! exists $pages{$dir} && ! $deleted{$dir} &&
  88                     grep /^$dir\/.*/, keys %pages) {
  89                         if (exists $IkiWiki::pagemtime{$dir}) {
  90                                 # This page must have just been deleted, so
  91                                 # don't re-add it. And remember it was
  92                                 # deleted.
  93                                 if (! ref $wikistate{autoindex}{deleted}) {
  94                                         $wikistate{autoindex}{deleted}={};
  95                                 }
  96                                 ${$wikistate{autoindex}{deleted}}{$dir}=1;
  97                         }
  98                         else {
  99                                 push @needed, $dir;
 100                         }
 101                 }
 102         }
 103
 104         if (@needed) {
 105                 if ($config{rcs}) {
 106                         IkiWiki::disable_commit_hook();
 107                 }
 108                 foreach my $page (@needed) {
 109                         genindex($page);
 110                 }
 111                 if ($config{rcs}) {
 112                         IkiWiki::rcs_commit_staged(
 113                                 gettext("automatic index generation"),
 114                                 undef, undef);
 115                         IkiWiki::enable_commit_hook();
 116                 }
 117         }
 118 }
 119
 120 1