\begin{problem*}{5.28}
An object of mass $m_1=5.00\U{kg}$ placed on a frictionless,
horizontal table is connected to a string that passes over a pulley
and then is fastened to a hanging object of mass $m_2=9.00\U{kg}$ as
shown in Figure~P5.28.  \Part{a} Draw free-body diagrams of both
objects.  Find \Part{b} the magnitude of that acceleration of the
objects and \Part{c} the tension in the string.
\begin{center}
\begin{asy}
import Mechanics;

real u = 1cm;

real a = u;       // block side length
real pr = a/4;    // pulley radius
real psw = 0.2u;  // pulley support width
real d = 2u;      // rope length

Surface s = Surface((-.7a, 0), (d-2.5pr, 0));
Block m1 = Block((0, a/2), width=a, height=a, "$m_1$");
Block m2 = Block(m1.center + (d,-d), width=a, height=a, "$m_2$");

pair ropecross = extension(m1.center, m1.center+E,
                           m2.center, m2.center+N);
pair pulley = ropecross + (-pr, -pr/Tan(90/2));

// pulley support
draw(pulley -- (pulley + 1.3(s.pTo-pulley)), psw+currentpen);

draw(m1.center -- (pulley.x, m1.center.y));
draw(m2.center -- (m2.center.x, pulley.y));

filldraw(shift(pulley)*scale(pr)*unitcircle, fillpen=white);

s.draw();
m1.draw();
m2.draw();
\end{asy}
\end{center}
\end{problem*}

\begin{solution}
\Part{a}
\begin{center}
\begin{asy}
import Mechanics;

real u = 1cm;
real m1 = 5;
real m2 = 9;
real g = 0.2u;
real t = (m1*m2*g)/(m1 + m2);

Vector T = Force((0,0), mag=t, dir=0, "$T$");
T.draw();
Vector G = Force((0,0), mag=m1*g, dir=-90, "$F_g$");
G.draw();
Vector norm = Force((0,0), mag=m1*g, dir=90, "$N$");
norm.draw();
dot("$m_1$", (0,0), W);
\end{asy}
\hspace{1cm}
\begin{asy}
import Mechanics;

real u = 1cm;
real m1 = 5;
real m2 = 9;
real g = 0.2u;
real t = (m1*m2*g)/(m1 + m2);

Vector T = Force((0,0), mag=t, dir=90, "$T$");
T.draw();
Vector G = Force((0,0), mag=m2*g, dir=-90, "$F_g$");
G.draw();
dot("$m_2$", (0,0), E);
\end{asy}
\end{center}

\Part{b}
Because the rope does not stretch, both objects have the same
magnitude of acceleration.  Using $F=ma$ on both objects, we can solve
for $a$.
\begin{align}
  T &= m_1 a \\
  m_2 g - T &= m_2 a \\
  m_2 g - m_1 a &= m_2 a \\
  m_2 g &= (m_1 + m_2) a \\
  a &= \frac{m_2 g}{m_1 + m_2}
    = \frac{9.00\U{kg}\cdot9.80\U{m/s$^2$}}{5.00\U{kg} + 9.00\U{kg}}
    = \ans{6.30\U{m/s$^2$}}
\end{align}

\Part{c}
Plugging the solution for $a$ back into either of the $F=ma$
equations,
\begin{equation}
  T = m_1 a
    = \frac{m_1 m_2 g}{m_1 + m_2}
    = \frac{5.00\U{kg}\cdot9.00\U{kg}\cdot9.80\U{m/s$^2$}}
           {5.00\U{kg} + 9.00\U{kg}}
    = \ans{32.1\U{N}}
\end{equation}
\end{solution}
