\begin{problem*}{5.25}
A bag of cement whose weight is $F_g$ hangs in equilibrium from three
wires shown in Figure~P5.24.  Two of the wires make angles
$\theta_1=60.0\dg$ and $\theta_2=40.0\dg$ with the horizontal.
Assuming the system is in equilibrium, show that the tension in the
left-hand wire is
\begin{equation}
  T_1 = \frac{F_g \cos\theta_2}{\sin(\theta_1+\theta_2)}
\end{equation}
\begin{center}
\begin{asy}
import Mechanics;

real u = 1cm;

real theta1 = 60;
real theta2 = 40;
real d = 3u;      // contact point seperation
real a = u;       // block side length

pair c1 = (0,0);       // left contact point
pair c2 = c1 + (d,0);  // right contact point
pair c3 = extension(c1, c1+dir(-theta1),
                    c2, c2+dir(180+theta2));

Surface s = Surface(c2+(0.2d,0), c1-(0.2d,0));
Angle a1 = Angle(c2, c1, c3, "$\theta_1$");
Angle a2 = Angle(c1, c2, c3, "$\theta_2$");
Block cement = Block(c3-(0, a), width=a, height=a, "$F_g$");

a1.draw();
a2.draw();
draw(c1 -- c3 -- c2);
draw(c3 -- cement.center);
s.draw();
cement.draw();

label("$T_1$", (c1+c3)/2, SW);
label("$T_2$", (c2+c3)/2, SE);
label("$T_3$", c3-(0,a/4), E);
\end{asy}
\end{center}
\end{problem*}

\begin{solution}
Balancing forces on the cement bag, $T_3=F_g$.

Balancing forces on the wire joint is a bit mor complicated and
deserves a free body diagram.
\begin{center}
\begin{asy}
import Mechanics;

real u = 1cm;

real theta1 = 60;
real theta2 = 40;
real T3 = 2u;
real T1 = T3 * Cos(theta2)/Sin(theta1+theta2);
real T2 = T3 * Cos(theta1)/Sin(theta1+theta2);

Angle a1 = Angle(dir(180-theta1), (0,0), (-1,0), "$\theta_1$");
Angle a2 = Angle(dir(theta2), (0,0), (1,0), "$\theta_2$");
Angle A1 = Angle(dir(180-theta1), (0,0), dir(180+theta2), radius=10mm,
    "$\theta_1+\theta_2$");
Angle A3 = Angle((0,-1), (0,0), dir(-90+theta2), "$\theta_2$");

Vector F1 = Force((0,0), mag=T1, dir=180-theta1, "$\vect{F}_1$");
Vector F2 = Force((0,0), mag=T2, dir=theta2,
    L=Label("$\vect{F}_2$", position=EndPoint, align=N));
Vector F3 = Force((0,0), mag=T3, dir=-90, "$\vect{F}_3$");

a1.draw();
a2.draw();
A1.draw();
A3.draw();
draw((-7mm,0)--(7mm,0));
draw((12mm*dir(-90+theta2))--(0,0)--(12mm*dir(180+theta2)));
F1.draw();
F2.draw();
F3.draw();
dot((0,0));

draw_ijhat((1.5u,-.5u), theta2);
\end{asy}
\end{center}
Where we've chosen a coordinate system such that $\vect{F}_2$ has no
$y$ component.

Balancing forces in the $y$ direction,
\begin{align}
  0 &= T_1 \sin(\theta_1+\theta_2) - T_3\cos(\theta_2) \\
  T_1 &= T_3\frac{\cos(\theta_2)}{\sin(\theta_1+\theta_2)}
    = F_g\frac{\cos(\theta_2)}{\sin(\theta_1+\theta_2)} \;,
\end{align}
which is what we set out to show.
\end{solution}
