From ef5a789c10a044f0126b77742a77549f1492a782 Mon Sep 17 00:00:00 2001
From: Louis Sautier <sbraz@gentoo.org>
Date: Sat, 13 Jul 2019 03:02:05 +0200
Subject: [PATCH] dev-python/importlib_metadata: new package, v0.18

Required by dev-python/irc-17.1

Package-Manager: Portage-2.3.67, Repoman-2.3.16
Signed-off-by: Louis Sautier <sbraz@gentoo.org>
---
 dev-python/importlib_metadata/Manifest        |  1 +
 .../importlib_metadata-0.18.ebuild            | 51 +++++++++++++++++++
 dev-python/importlib_metadata/metadata.xml    | 17 +++++++
 3 files changed, 69 insertions(+)
 create mode 100644 dev-python/importlib_metadata/Manifest
 create mode 100644 dev-python/importlib_metadata/importlib_metadata-0.18.ebuild
 create mode 100644 dev-python/importlib_metadata/metadata.xml

diff --git a/dev-python/importlib_metadata/Manifest b/dev-python/importlib_metadata/Manifest
new file mode 100644
index 000000000000..b3cd34cc3f9e
--- /dev/null
+++ b/dev-python/importlib_metadata/Manifest
@@ -0,0 +1 @@
+DIST importlib_metadata-0.18.tar.gz 23341 BLAKE2B e1c43a760b141b0589973672ad1cd6c47e077293353f67ebe2c2b3631265712dcecc8e14a57803539d2276d5d908fae3c4ac07165ddd5937cf53955ff896001e SHA512 2f39789725548bcb37061b0b99f90802a2919339db6b29f95b38811b35f4cafc7acfb4cca1167e28a4738ba195af31344f59ab457d87710764d1ba8f06034b18
diff --git a/dev-python/importlib_metadata/importlib_metadata-0.18.ebuild b/dev-python/importlib_metadata/importlib_metadata-0.18.ebuild
new file mode 100644
index 000000000000..dcfb1283d7ba
--- /dev/null
+++ b/dev-python/importlib_metadata/importlib_metadata-0.18.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Read metadata from Python packages"
+HOMEPAGE="https://importlib-metadata.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/zipp[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/configparser-3.5[${PYTHON_USEDEP}]' -2)
+	$(python_gen_cond_dep 'dev-python/contextlib2[${PYTHON_USEDEP}]' -2)
+	$(python_gen_cond_dep 'dev-python/pathlib2[${PYTHON_USEDEP}]' -2)
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep 'dev-python/importlib_resources[${PYTHON_USEDEP}]' pypy pypy3 python2_7 python3_5 python3_6)
+	)
+	doc? (
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+"
+python_prepare_all() {
+	sed -i "/'sphinx.ext.intersphinx'/d" ${PN}/docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build ${PN}/docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/importlib_metadata/metadata.xml b/dev-python/importlib_metadata/metadata.xml
new file mode 100644
index 000000000000..232d18f4ff02
--- /dev/null
+++ b/dev-python/importlib_metadata/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sbraz@gentoo.org</email>
+		<name>Louis Sautier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">importlib-metadata</remote-id>
+		<remote-id type="gitlab">python-devs/importlib_metadata</remote-id>
+		<bugs-to>https://gitlab.com/python-devs/importlib_metadata/issues</bugs-to>
+	</upstream>
+</pkgmetadata>
-- 
2.26.2