From eab936c6d9c2a2a5096b29acce7a435ba70f240f Mon Sep 17 00:00:00 2001
From: Patrick McLean <patrick.mclean@sony.com>
Date: Wed, 4 Dec 2019 14:11:09 -0800
Subject: [PATCH] dev-python/tqdm: bump to 4.40.0, add py38, sync 9999

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.80, Repoman-2.3.19
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
---
 dev-python/tqdm/Manifest           |  1 +
 dev-python/tqdm/tqdm-4.40.0.ebuild | 60 ++++++++++++++++++++++++++++++
 dev-python/tqdm/tqdm-9999.ebuild   | 26 ++++++++-----
 3 files changed, 78 insertions(+), 9 deletions(-)
 create mode 100644 dev-python/tqdm/tqdm-4.40.0.ebuild

diff --git a/dev-python/tqdm/Manifest b/dev-python/tqdm/Manifest
index 4026ad4374c5..2aa18f1ff3f1 100644
--- a/dev-python/tqdm/Manifest
+++ b/dev-python/tqdm/Manifest
@@ -1,2 +1,3 @@
 DIST tqdm-4.23.3.tar.gz 75941 BLAKE2B 9e5810765e8f7ea4f54b0f93f453d278d5ad4b1710f1476a6f00ff2e513789585e97dcd5a8331fe69d3593b18affd50bf9bf51cbaed29ecd68d4efad9318aa31 SHA512 40c853b7cf7611ba2ef7652417c0d42ea4392f5ea9cbe319dbb9e3dd063594e5c637fb5d13f77935fb9a034d395b28fa9480fec1c6cca1852644add4ac18cce8
 DIST tqdm-4.33.0.tar.gz 121571 BLAKE2B f4ee73cfa710462e148f6034ac69144d845d216bd97e16a78bc1f1ed5d658b6cd695d07aa1ea6ec93e2e747ab8fc52263a580c01516d1f111dcb5766b019925d SHA512 de86a2dc2c5f887b9671ee01e7c05820375b0ef83dec92f17da4d944dd02cbf96a133fd9d349ba5f9c75af70e7b87110a9a7ad3293c7eb81e49ed6ea288ba73c
+DIST tqdm-4.40.0.tar.gz 129225 BLAKE2B 85030c11bdba6c1d6da461e3c648bae6ae173577fb18986e3153badd73a28352f807782759aa52ed082d7ee0c13dc5f850c1da563ee5892f6bf5e8f49c48c7ee SHA512 1c326d98130c79f614cea502723e4202baa57b7b4639e208133cb464785e4a8d4eaa9d262ea484246d45e5eb8f21994e7ecf3fd6ef0f4966f9049fc8013d7442
diff --git a/dev-python/tqdm/tqdm-4.40.0.ebuild b/dev-python/tqdm/tqdm-4.40.0.ebuild
new file mode 100644
index 000000000000..78874a4508fc
--- /dev/null
+++ b/dev-python/tqdm/tqdm-4.40.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7,8}} )
+
+inherit distutils-r1
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/tqdm/tqdm"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~sparc ~x86"
+fi
+
+DESCRIPTION="Add a progress meter to your loops in a second"
+HOMEPAGE="https://github.com/tqdm/tqdm"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="examples"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+BDEPEND="${RDEPEND}"
+
+distutils_enable_tests nose
+
+python_prepare_all() {
+	sed -r \
+		-e "s:'nose'(,[[:space:]]*|)::" \
+		-e "s:'flake8'(,[[:space:]]*|)::" \
+		-e "s:'coverage'(,[[:space:]]*|)::" \
+		-i setup.py
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# tests_main.py requires the package to be installed
+	distutils_install_for_testing
+	# Skip unpredictable performance tests
+	nosetests tqdm -v --ignore 'tests_perf.py' \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	doman "${BUILD_DIR}"/lib/tqdm/tqdm.1
+	rm "${BUILD_DIR}"/lib/tqdm/tqdm.1 || die
+	distutils-r1_python_install --skip-build
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/tqdm/tqdm-9999.ebuild b/dev-python/tqdm/tqdm-9999.ebuild
index 9a0b9b8ea059..78874a4508fc 100644
--- a/dev-python/tqdm/tqdm-9999.ebuild
+++ b/dev-python/tqdm/tqdm-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7,8}} )
 
 inherit distutils-r1
 
@@ -12,7 +12,7 @@ if [[ ${PV} == 9999 ]]; then
 	EGIT_REPO_URI="https://github.com/tqdm/tqdm"
 else
 	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86"
+	KEYWORDS="~amd64 ~sparc ~x86"
 fi
 
 DESCRIPTION="Add a progress meter to your loops in a second"
@@ -20,20 +20,28 @@ HOMEPAGE="https://github.com/tqdm/tqdm"
 
 LICENSE="MIT"
 SLOT="0"
-IUSE="examples test"
+IUSE="examples"
 
-# Uses pkg_resources
 RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
-BDEPEND="
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	test? ( dev-python/nose[${PYTHON_USEDEP}] )
-"
+BDEPEND="${RDEPEND}"
+
+distutils_enable_tests nose
+
+python_prepare_all() {
+	sed -r \
+		-e "s:'nose'(,[[:space:]]*|)::" \
+		-e "s:'flake8'(,[[:space:]]*|)::" \
+		-e "s:'coverage'(,[[:space:]]*|)::" \
+		-i setup.py
+
+	distutils-r1_python_prepare_all
+}
 
 python_test() {
 	# tests_main.py requires the package to be installed
 	distutils_install_for_testing
 	# Skip unpredictable performance tests
-	nosetests tqdm -v -I 'tests_perf.py' \
+	nosetests tqdm -v --ignore 'tests_perf.py' \
 		|| die "tests failed with ${EPYTHON}"
 }
 
-- 
2.26.2