From ea6a2e86fb09d15f9c6e4a5596c27d03626205b2 Mon Sep 17 00:00:00 2001
From: Joonas Niilola <juippis@gmail.com>
Date: Tue, 15 Jan 2019 09:50:21 +0200
Subject: [PATCH] media-gfx/ahoviewer: version bump to 1.6.5.

Package-Manager: Portage[mgorny]-2.3.51.1
Signed-off-by: Joonas Niilola <juippis@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/10837
Signed-off-by: Patrice Clement <monsieurp@gentoo.org>
---
 media-gfx/ahoviewer/Manifest               |  1 +
 media-gfx/ahoviewer/ahoviewer-1.6.5.ebuild | 90 ++++++++++++++++++++++
 2 files changed, 91 insertions(+)
 create mode 100644 media-gfx/ahoviewer/ahoviewer-1.6.5.ebuild

diff --git a/media-gfx/ahoviewer/Manifest b/media-gfx/ahoviewer/Manifest
index 986a94ef7b1b..540dbe8650a7 100644
--- a/media-gfx/ahoviewer/Manifest
+++ b/media-gfx/ahoviewer/Manifest
@@ -1 +1,2 @@
 DIST ahoviewer-1.6.4.tar.gz 227225 BLAKE2B c00c89bf80865ddf60a478a8ad030aa136fbc2735598de2b237ea97bc247337d9a12a1423e402c2e95c77df4e70ad68242ed31d5f8d896c1ae835acd860e7a5f SHA512 5e00f086685b7fd6601758e5ae0e6e7d1d24b56c1bd7c81de0be5c3613404fcfc585b8bf035a72a51171a40c8a25c7ad084fc3a9f7ba038e121fb2b7874b4ebd
+DIST ahoviewer-1.6.5.tar.gz 227653 BLAKE2B 691a9eaa62b55d91b2d215d41ce402c39ca7490a44506a489061aaadd97fac2ac84aa1b28a7d1b4c097d69153ffe146fac105e9b086adc6b66b9f459e6b98eb5 SHA512 30309cff22008d444eec113bd5d79bdc0e9ff1bbc1b117bd3ecefabfdef79773fd17347766115bb0a192db76dbb24f30c853b27123f0a333c8625b94dc2a8775
diff --git a/media-gfx/ahoviewer/ahoviewer-1.6.5.ebuild b/media-gfx/ahoviewer/ahoviewer-1.6.5.ebuild
new file mode 100644
index 000000000000..9bf5639b9434
--- /dev/null
+++ b/media-gfx/ahoviewer/ahoviewer-1.6.5.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools gnome2-utils xdg-utils
+
+DESCRIPTION="A GTK2 image viewer, manga reader, and booru browser"
+HOMEPAGE="https://github.com/ahodesuka/ahoviewer"
+SRC_URI="https://github.com/ahodesuka/ahoviewer/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnutls +gstreamer libsecret +rar +ssl +zip"
+
+DEPEND="
+	dev-cpp/glibmm:2
+	dev-cpp/gtkmm:2.4
+	dev-libs/libconfig[cxx]
+	dev-libs/libxml2:2
+	dev-libs/libsigc++:2
+	net-misc/curl
+	gstreamer? (
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gstreamer:1.0
+	)
+	libsecret? ( app-crypt/libsecret )
+	rar? ( app-arch/unrar )
+	ssl? (
+		gnutls? (
+			net-libs/gnutls:=
+			net-misc/curl[curl_ssl_gnutls]
+		)
+		!gnutls? (
+			>=dev-libs/openssl-1.0.0:0=
+			net-misc/curl[curl_ssl_openssl]
+		)
+	)
+	zip? ( dev-libs/libzip )
+"
+RDEPEND="
+	${DEPEND}
+	gstreamer? (
+		media-libs/gst-plugins-base:1.0[X]
+		media-libs/gst-plugins-good:1.0
+		|| (
+			media-plugins/gst-plugins-vpx
+			media-plugins/gst-plugins-libav
+		)
+	)
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable gstreamer gst)
+		$(use_enable libsecret)
+		$(use_enable rar)
+		$(use_enable zip)
+	)
+
+	if use ssl && use gnutls ; then
+		myconf+=( --disable-ssl --enable-gnutls )
+	elif use ssl && ! use gnutls ; then
+		myconf+=( --enable-ssl --disable-gnutls )
+	else
+		myconf+=( --disable-ssl --disable-gnutls )
+	fi
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
-- 
2.26.2