From c909b14c7864ef6554f98c504bd13b7f4c952320 Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Fri, 29 May 2020 08:36:29 +0200
Subject: [PATCH] net-misc/youtube-dl: Version 2020.05.29

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 net-misc/youtube-dl/Manifest                  |  1 +
 .../youtube-dl/youtube-dl-2020.05.29.ebuild   | 74 +++++++++++++++++++
 2 files changed, 75 insertions(+)
 create mode 100644 net-misc/youtube-dl/youtube-dl-2020.05.29.ebuild

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 85df10dd705e..a8463f8d1991 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2020.05.08.tar.gz 3172744 BLAKE2B d3ae7cc18f4156f4fe6fc17b4ef46f8406cd0b01ae18e3317d048bdbc737a9b12c67c9aded22a8e7631ea3b0f90f6b306f4148a5e33a0a597490b35fcf3b5113 SHA512 fbfd6bc42959547c6307b291478d7d86b79847a92d193b795d91f717471927d22c45356c0e2ba03ea1c5bc96d2fa5a949cb2283b0d7ec976bcf3a54d6c928ed1
+DIST youtube-dl-2020.05.29.tar.gz 3174451 BLAKE2B 5ec37038a49c24e27fe6dc1b6286d41a320f694ac9fb21be0444e476029e3f3f0a286f1c5a103b8e6fe97dd8301d6a8d2a5a31088769145fed6de318a15bf609 SHA512 d96a93e1b1dbd27236c827d1d03e8482b6adbd1c85c9c5befe1a8bb998cc6ea81451c0830a57de0f8f03f4da3b57d57b81fbbd4547c1f73c9789d51f9d18f7c3
diff --git a/net-misc/youtube-dl/youtube-dl-2020.05.29.ebuild b/net-misc/youtube-dl/youtube-dl-2020.05.29.ebuild
new file mode 100644
index 000000000000..27edc068096a
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2020.05.29.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python3_{6,7,8})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+RDEPEND="
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+	)
+"
+S=${WORKDIR}/${PN}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake offlinetest
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need ffmpeg (media-video/ffmpeg)."
+	elog "On some sites - most notably YouTube - videos can be retrieved in"
+	elog "a higher quality format without sound. ${PN} will detect whether"
+	elog "ffmpeg is present and automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}
-- 
2.26.2