From c658f1153f43ad8d07f46fe2204b5d1e91a9a241 Mon Sep 17 00:00:00 2001
From: "Anthony G. Basile" <blueness@gentoo.org>
Date: Tue, 10 Mar 2020 21:50:22 -0400
Subject: [PATCH] app-backup/borgbackup: version bump to 1.1.11

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Anthony G. Basile <blueness@gentoo.org>
---
 app-backup/borgbackup/Manifest                |  1 +
 .../borgbackup/borgbackup-1.1.11.ebuild       | 52 +++++++++++++++++++
 2 files changed, 53 insertions(+)
 create mode 100644 app-backup/borgbackup/borgbackup-1.1.11.ebuild

diff --git a/app-backup/borgbackup/Manifest b/app-backup/borgbackup/Manifest
index e7366684d6e9..d7ee489ce9f6 100644
--- a/app-backup/borgbackup/Manifest
+++ b/app-backup/borgbackup/Manifest
@@ -1 +1,2 @@
 DIST borgbackup-1.1.10.tar.gz 3610011 BLAKE2B 9c13d89a0441b5403019ed24b2f36fd55f4d133219b68802b79c76f5086324f4a249124a89c67049fecbadb78d5dae64b007ed6c53a579c115ce248db3e83054 SHA512 9315335208f10427e3105e10819817d15fd05171479252903bd51eaacb016bc3ff792d505b9203ce0b9b41ec350472bdb9a23b0128e7fe156aaa47c1608451c0
+DIST borgbackup-1.1.11.tar.gz 3718055 BLAKE2B ea03d538bd7936cc12705f73c3f8e63dc28167f1930e84bdd04fc13bcc34c2b9f35e7e6ed945ba20b647dbdefe12c66c04645414c7efc974e53a312e3dff6991 SHA512 cf629f31d38d27ce6350670ff27b4937f2f30eddf9e0cd9209cd9d57a4ffa653f5a291ea1e1c79614dd2c08bcf5c50bc3e4e0f222e0d3cd1bbfb2d756b4a4573
diff --git a/app-backup/borgbackup/borgbackup-1.1.11.ebuild b/app-backup/borgbackup/borgbackup-1.1.11.ebuild
new file mode 100644
index 000000000000..644e3a093322
--- /dev/null
+++ b/app-backup/borgbackup/borgbackup-1.1.11.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/borg.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Deduplicating backup program with compression and authenticated encryption"
+HOMEPAGE="https://borgbackup.readthedocs.io/"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="libressl"
+
+# Unfortunately we have a file conflict with app-office/borg, bug #580402
+RDEPEND="
+	!!app-office/borg
+	app-arch/lz4
+	virtual/acl
+	dev-python/llfuse[${PYTHON_USEDEP}]
+	~dev-python/msgpack-0.5.6[${PYTHON_USEDEP}]
+	dev-python/pyzmq[${PYTHON_USEDEP}]
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+"
+
+DEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	${RDEPEND}
+"
+
+python_prepare_all() {
+	# allow use of new (renamed) msgpack
+	sed -i "s|'msgpack-python.*',||g" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+src_install() {
+	distutils-r1_src_install
+	doman docs/man/*
+}
-- 
2.26.2