From c5d0556fe8ce7b466a71707cb8443fa2ab5ddedd Mon Sep 17 00:00:00 2001
From: Patrick McLean <patrick.mclean@sony.com>
Date: Thu, 21 Nov 2019 15:54:46 -0800
Subject: [PATCH] dev-python/tempora: Revbump to 1.14.1-r1, add py38

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
---
 dev-python/tempora/tempora-1.12.ebuild      |  2 +-
 dev-python/tempora/tempora-1.14.1-r1.ebuild | 69 +++++++++++++++++++++
 2 files changed, 70 insertions(+), 1 deletion(-)
 create mode 100644 dev-python/tempora/tempora-1.14.1-r1.ebuild

diff --git a/dev-python/tempora/tempora-1.12.ebuild b/dev-python/tempora/tempora-1.12.ebuild
index da787d21de2c..a44c68177598 100644
--- a/dev-python/tempora/tempora-1.12.ebuild
+++ b/dev-python/tempora/tempora-1.12.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~x86"
 IUSE="doc test"
 
 RDEPEND="
diff --git a/dev-python/tempora/tempora-1.14.1-r1.ebuild b/dev-python/tempora/tempora-1.14.1-r1.ebuild
new file mode 100644
index 000000000000..411f243370da
--- /dev/null
+++ b/dev-python/tempora/tempora-1.14.1-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python{2_7,3_{5,6,7,8}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Objects and routines pertaining to date and time"
+HOMEPAGE="https://github.com/jaraco/tempora"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/jaraco-functools-1.20[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( $(python_gen_any_dep '
+			>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+			>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+		')
+	)
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+	)
+"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_check_deps() {
+	use doc || return 0
+	has_version ">=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]" && \
+		has_version ">=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]" && \
+		has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+python_prepare_all() {
+	# avoid a setuptools_scm dependency
+	sed -i "s:use_scm_version=True:version='${PV}':" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	PYTHONPATH=. pytest -vv --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
-- 
2.26.2