From c599de1c9cfeb6a50d7e99205962876d03f61fa6 Mon Sep 17 00:00:00 2001
From: Yixun Lan <dlan@gentoo.org>
Date: Tue, 1 Sep 2015 00:09:41 +0800
Subject: [PATCH] app-backup/snapper: version bump 0.2.8

Package-Manager: portage-2.2.20.1
---
 app-backup/snapper/Manifest             |  1 +
 app-backup/snapper/snapper-0.2.8.ebuild | 71 +++++++++++++++++++++++++
 app-backup/snapper/snapper-9999.ebuild  |  1 +
 3 files changed, 73 insertions(+)
 create mode 100644 app-backup/snapper/snapper-0.2.8.ebuild

diff --git a/app-backup/snapper/Manifest b/app-backup/snapper/Manifest
index 80ceeb6a95c4..54e158ee7a55 100644
--- a/app-backup/snapper/Manifest
+++ b/app-backup/snapper/Manifest
@@ -1,3 +1,4 @@
 DIST snapper-0.2.3.tar.bz2 451916 SHA256 6c78fc57ac018f7536a03971927f2b17f1f048f87e26689609028f51500c9c6a SHA512 a8b847e3bc0759a717f4256ed3c9e7ed675f040a56e80ea7ca2d7f12906198ecd141638f00acce02195b094a9db7fbdd5cb233012e3ba8be7a3502cba1bbd968 WHIRLPOOL cb4a0cd1f4c01ccbf213395f9b8c0eff325f5453fa0e05e37b4b525e6c0b276b3767194a06b2ea50b877883a6061f86817d773775842e161f3298e45573f6789
 DIST snapper-0.2.4.tar.bz2 458409 SHA256 8fc70b8e7a39dc3249ce9141e2c5f0623bb80f8e4150a543d8ed04d2ad27f399 SHA512 e986ebb482a7e30e4e97edc2882653a041c49c9291310469860fd9a0e93c46747ec31723f771a710a6fcce2f4863fdf672c623453ae27b4fb7cd911b8d4b35ed WHIRLPOOL 1627664909ea3a5959c6ff6a66c1dcbacbe835bce2f1f20cc4c380e8613545e8a0e3f7569c32f774a5534636b8321af71d78c21368e8b7a2104e05d241f5d8cd
 DIST snapper-0.2.6.tar.bz2 473015 SHA256 3390650be0e4709595d28df287a0e5902fb570e9fcb5ba992f435326bc53b75e SHA512 d49eef086d84f02106691872db6369b10cb55a6afe6f2cfb6c790330321397d66dc1aa0229d31d9e3c7b1efb6bd6c0fd9242dbb69a44fe3433233717df98a334 WHIRLPOOL 84a24153651dd9bd47e4f25012d87527b35b5dfd3b3a1da86fe0bdecbca032f5fe3c58ab1197a759058301b029961a2b5965dfb245a80cd50621af971d49a722
+DIST snapper-0.2.8.tar.bz2 475053 SHA256 a44608648ed21a1346f8ae9345044901c39ad01abb501806a22c9d4a771eadc5 SHA512 ce1529062943c34b9de2eafb62c6e28b39bda6f4afc23ec5df5ddd42f213cbaf0d77d94d11d982285114ceecd27bd48206436119af84b2769ed4792aab01c75d WHIRLPOOL 3463cf8beb7adb1f3869645b20928dc21fc9cb72f8ed5275688e0b53c97b8103d0536e3246f12fcdc90c1889d221d13ce131b1920c7298232212c003ea9abb6d
diff --git a/app-backup/snapper/snapper-0.2.8.ebuild b/app-backup/snapper/snapper-0.2.8.ebuild
new file mode 100644
index 000000000000..6674766e1ca9
--- /dev/null
+++ b/app-backup/snapper/snapper-0.2.8.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="Command-line program for btrfs and ext4 snapshot management"
+HOMEPAGE="http://snapper.io/"
+SRC_URI="ftp://ftp.suse.com/pub/projects/snapper/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+btrfs ext4 lvm pam xattr"
+
+RDEPEND="dev-libs/boost[threads]
+	dev-libs/libxml2
+	dev-libs/icu:=
+	sys-apps/acl
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/zlib
+	virtual/libintl
+	btrfs? ( >=sys-fs/btrfs-progs-3.17.1 )
+	ext4? ( sys-fs/e2fsprogs )
+	lvm? ( sys-fs/lvm2 )
+	pam? ( sys-libs/pam )
+	xattr? ( sys-apps/attr )"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS README )
+
+src_prepare() {
+	epatch "${FILESDIR}"/cron-confd.patch
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-conf="/etc/conf.d"
+		--docdir="/usr/share/doc/${PF}"
+		--disable-zypp
+		--enable-rollback
+		$(use_enable btrfs)
+		$(use_enable ext4)
+		$(use_enable lvm)
+		$(use_enable pam)
+		$(use_enable xattr xattrs)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	# Existing configuration file required to function
+	newconfd data/sysconfig.snapper snapper
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	elog "In order to use Snapper, you need to set up"
+	elog "at least one config first. To do this, run:"
+	elog "snapper create-config <subvolume>"
+	elog "For more information, see man (8) snapper or"
+	elog "http://snapper.io/documentation.html"
+}
diff --git a/app-backup/snapper/snapper-9999.ebuild b/app-backup/snapper/snapper-9999.ebuild
index b0191f41ff13..3668a406e386 100644
--- a/app-backup/snapper/snapper-9999.ebuild
+++ b/app-backup/snapper/snapper-9999.ebuild
@@ -45,6 +45,7 @@ src_configure() {
 		--with-conf="/etc/conf.d"
 		--docdir="/usr/share/doc/${PF}"
 		--disable-zypp
+		--enable-rollback
 		$(use_enable btrfs)
 		$(use_enable ext4)
 		$(use_enable lvm)
-- 
2.26.2