From c3acd0c7a868023cf1732e7e6062e95749cab959 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Sun, 19 Apr 2020 23:13:45 +0300
Subject: [PATCH] net-vpn/networkmanager-pptp: disable legacy libnm-glib compat

Disable libnm-glib, libnm-glib-vpn and libnm-util usage, as they are
all gone with newer NetworkManager.
This also disables libnm-gtk usage, which requires libnm-glib in turn
as well, and is also gone with newer nm-applet.
Depend on new libnma package instead of nm-applet, as this is what
is needed here.

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 .../networkmanager-pptp-1.2.8-r2.ebuild       | 53 +++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 net-vpn/networkmanager-pptp/networkmanager-pptp-1.2.8-r2.ebuild

diff --git a/net-vpn/networkmanager-pptp/networkmanager-pptp-1.2.8-r2.ebuild b/net-vpn/networkmanager-pptp/networkmanager-pptp-1.2.8-r2.ebuild
new file mode 100644
index 000000000000..76465cd0e875
--- /dev/null
+++ b/net-vpn/networkmanager-pptp/networkmanager-pptp-1.2.8-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit gnome2
+
+DESCRIPTION="NetworkManager PPTP VPN plugin"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager/VPN"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="gtk"
+
+RDEPEND="
+	>=net-misc/networkmanager-1.2.0:=
+	>=dev-libs/dbus-glib-0.74
+	>=dev-libs/glib-2.32:2
+	net-dialup/ppp:=
+	net-dialup/pptpclient
+	gtk? (
+		>=net-libs/libnma-1.2.0
+		>=app-crypt/libsecret-0.18
+		>=x11-libs/gtk+-3.4:3
+	)
+"
+# libxml2 required for glib-compile-resources
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/intltool
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf
+	# Same hack as net-dialup/pptpd to get proper plugin dir for ppp, bug #519986
+	local PPPD_VER=`best_version net-dialup/ppp`
+	PPPD_VER=${PPPD_VER#*/*-} #reduce it to ${PV}-${PR}
+	PPPD_VER=${PPPD_VER%%[_-]*} # main version without beta/pre/patch/revision
+	myconf="${myconf} --with-pppd-plugin-dir=/usr/$(get_libdir)/pppd/${PPPD_VER}"
+
+	gnome2_src_configure \
+		--disable-more-warnings \
+		--disable-static \
+		--with-dist-version=Gentoo \
+		$(use_with gtk gnome) \
+		--without-libnm-glib \
+		${myconf}
+}
-- 
2.26.2