From c34df49a9e01c6928d712a9f3976d96d0da283c0 Mon Sep 17 00:00:00 2001
From: =?utf8?q?Manuel=20R=C3=BCger?= <mrueg@gentoo.org>
Date: Thu, 4 Jul 2019 17:41:02 +0200
Subject: [PATCH] app-emulation/containerd: Version bump to 1.2.7
MIME-Version: 1.0
Content-Type: text/plain; charset=utf8
Content-Transfer-Encoding: 8bit

Package-Manager: Portage-2.3.68, Repoman-2.3.16
Signed-off-by: Manuel Rüger <mrueg@gentoo.org>
---
 app-emulation/containerd/Manifest             |  1 +
 .../containerd/containerd-1.2.7.ebuild        | 56 +++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 app-emulation/containerd/containerd-1.2.7.ebuild

diff --git a/app-emulation/containerd/Manifest b/app-emulation/containerd/Manifest
index 989fa6368005..a18502cdd4d0 100644
--- a/app-emulation/containerd/Manifest
+++ b/app-emulation/containerd/Manifest
@@ -1 +1,2 @@
 DIST containerd-1.2.6.tar.gz 4874159 BLAKE2B 202e19cffbe2b5335558dc1db28ea28a05dcc9e9b3aad864e090d86f7590df9e67ae685c9fc6ab2b8abdd1762d001fa9b298b1d311c080449bc86087b6af8c36 SHA512 287b064cb3e57369e34f6debb434526d6bd4857e337e489c56e4ca484c66e161bbda911b4fc29cb49808a756f6ec7af5629e46d693644500e3bf2d9e45e87e73
+DIST containerd-1.2.7.tar.gz 4877757 BLAKE2B 6cf98e370547d3ca5158f546e72e3ff5fdccc08c2e9f390988d080222195f95512dbf6f7dc042b7a966283a040000b7b8777b3fbeb4c5b861caae4f6209c59c5 SHA512 b96ca236d28933c1bf309fc7204af7d2c356e19af394d5c2274a178c8f15298faf6ca9bb8e7d04acb7c3c9c41035446643a8df0103017f7ed0320bfc37cb8ca9
diff --git a/app-emulation/containerd/containerd-1.2.7.ebuild b/app-emulation/containerd/containerd-1.2.7.ebuild
new file mode 100644
index 000000000000..21f2f7301c8d
--- /dev/null
+++ b/app-emulation/containerd/containerd-1.2.7.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+EGO_PN="github.com/containerd/${PN}"
+
+inherit toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	inherit golang-vcs
+else
+	MY_PV="${PV/_rc/-rc.}"
+	EGIT_COMMIT="v${MY_PV}"
+	CONTAINERD_COMMIT="85f6aa58b8a3170aec9824568f7a31832878b603"
+	SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64"
+	inherit golang-vcs-snapshot
+fi
+
+DESCRIPTION="A daemon to control runC"
+HOMEPAGE="https://containerd.tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="apparmor +btrfs +cri hardened +seccomp"
+
+DEPEND="btrfs? ( sys-fs/btrfs-progs )
+	seccomp? ( sys-libs/libseccomp )"
+RDEPEND=">=app-emulation/runc-1.0.0_rc8
+	seccomp? ( sys-libs/libseccomp )"
+
+S=${WORKDIR}/${P}/src/${EGO_PN}
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	if [[ ${PV} != *9999* ]]; then
+		sed -i -e "s/git describe --match.*$/echo ${PV})/"\
+			-e "s/git rev-parse HEAD.*$/echo $CONTAINERD_COMMIT)/"\
+			-e "s/-s -w//" \
+			Makefile || die
+	fi
+}
+
+src_compile() {
+	local options=( $(usex btrfs "" "no_btrfs") $(usex cri "" "no_cri") $(usex seccomp "seccomp" "") $(usex apparmor "apparmor" "") )
+	export GOPATH="${WORKDIR}/${P}" # ${PWD}/vendor
+	LDFLAGS=$(usex hardened '-extldflags -fno-PIC' '') BUILDTAGS="${options[@]}" emake
+}
+
+src_install() {
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	keepdir /var/lib/containerd
+	dobin bin/*
+}
-- 
2.26.2