From bd356a9df39912c0399e2929397155cc845aea54 Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Sat, 5 Sep 2015 13:50:58 +0200
Subject: [PATCH] app-editors/gedit: Version bump

Package-Manager: portage-2.2.20.1
---
 app-editors/gedit/Manifest            |   1 +
 app-editors/gedit/gedit-3.16.3.ebuild | 107 ++++++++++++++++++++++++++
 2 files changed, 108 insertions(+)
 create mode 100644 app-editors/gedit/gedit-3.16.3.ebuild

diff --git a/app-editors/gedit/Manifest b/app-editors/gedit/Manifest
index e1dd10a66ca5..db688455e48e 100644
--- a/app-editors/gedit/Manifest
+++ b/app-editors/gedit/Manifest
@@ -1,2 +1,3 @@
 DIST gedit-3.14.3.tar.xz 2875192 SHA256 cd6c9f556ec12001e4b250091a1d7405cd807cce7fe767bc89ed2c25aa96a319 SHA512 2237ad697161cff5755336775cf128136d7cefdece0d335246735b3ae1b9d2cadb29ae36be2000cd7fb02d6a4187aac1d2ff7935bec5c64b5b880fe84f330b01 WHIRLPOOL 39ffa7ece00f712f052c78107b3f95cd0e3a744932d22f5e946141b3bc8954643ae091f75508d9761761fb041a18b43e50b23ed1c0ff3d7ac0bdce9464cc71cd
 DIST gedit-3.16.2.tar.xz 2905916 SHA256 db60a9408711b00f3780f5f5b657e9f44722c88c683ba6e9f2b4885631f429aa SHA512 511d70099eeb857a3e25d789c44302756d108ff84634c4c7386e1e1de8dd08834cf57991311c69aa81da23510027523bc7cde313b689feb1a8e08eb01b017648 WHIRLPOOL ce51f82265664839d686ea91388f8dc906c5dcf666032f4073792832aabfa9a04dbd99e4aeef5cfd733a753eaf63daaa5b55dce3c67bb0cdb01d96595d36b4f9
+DIST gedit-3.16.3.tar.xz 2924392 SHA256 c28df44a29ee5707441f89e94b513079d709111afec4bd4b079a1dff0242cdb2 SHA512 479370c25be4b8c6f2fc77628e835b763194fdc9ce1858bb8fe4641964e6911db573b28300d8cc5519a5e4ddef980d28c224a315c3879770265be9328b70e925 WHIRLPOOL 604690b148f2af10358c1d567521e49a406594c390d8b67a22a4879ce1d70398d0de43865cc3874d29b51d9c86103fa765b5cde181008172e5617333b1ab3b9e
diff --git a/app-editors/gedit/gedit-3.16.3.ebuild b/app-editors/gedit/gedit-3.16.3.ebuild
new file mode 100644
index 000000000000..aa096cc7be8b
--- /dev/null
+++ b/app-editors/gedit/gedit-3.16.3.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes" # plugins are dlopened
+PYTHON_COMPAT=( python3_{3,4} )
+VALA_MIN_API_VERSION="0.26"
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils gnome2 multilib python-r1 vala virtualx
+
+DESCRIPTION="A text editor for the GNOME desktop"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gedit"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+SLOT="0"
+
+IUSE="+introspection +python spell vala"
+# python-single-r1 would request disabling PYTHON_TARGETS on libpeas
+# we need to fix that
+REQUIRED_USE="
+	python? ( introspection )
+	python? ( ^^ ( $(python_gen_useflags '*') ) )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"
+
+# X libs are not needed for OSX (aqua)
+COMMON_DEPEND="
+	>=dev-libs/libxml2-2.5.0:2
+	>=dev-libs/glib-2.40:2[dbus]
+	>=x11-libs/gtk+-3.16:3[introspection?]
+	>=x11-libs/gtksourceview-3.16:3.0[introspection?]
+	>=dev-libs/libpeas-1.7.0[gtk]
+
+	gnome-base/gsettings-desktop-schemas
+	gnome-base/gvfs
+
+	x11-libs/libX11
+
+	net-libs/libsoup:2.4
+
+	introspection? ( >=dev-libs/gobject-introspection-0.9.3:= )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		>=dev-python/pygobject-3:3[cairo,${PYTHON_USEDEP}]
+		dev-libs/libpeas[${PYTHON_USEDEP}] )
+	spell? (
+		>=app-text/enchant-1.2:=
+		>=app-text/iso-codes-0.35 )
+"
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/gnome-icon-theme-symbolic
+"
+DEPEND="${COMMON_DEPEND}
+	${vala_depend}
+	app-text/docbook-xml-dtd:4.1.2
+	>=app-text/scrollkeeper-0.3.11
+	dev-libs/libxml2:2
+	>=dev-util/gtk-doc-am-1
+	>=dev-util/intltool-0.50.1
+	dev-util/itstool
+	>=sys-devel/gettext-0.18
+	virtual/pkgconfig
+"
+# yelp-tools, gnome-common needed to eautoreconf
+
+pkg_setup() {
+	use python && [[ ${MERGE_TYPE} != binary ]] && python_setup
+}
+
+src_prepare() {
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS BUGS ChangeLog MAINTAINERS NEWS README"
+
+	gnome2_src_configure \
+		--disable-deprecations \
+		--enable-updater \
+		--enable-gvfs-metadata \
+		$(use_enable introspection) \
+		$(use_enable spell) \
+		$(use_enable python) \
+		$(use_enable vala)
+}
+
+src_test() {
+	# FIXME: this should be handled at eclass level
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+
+	unset DBUS_SESSION_BUS_ADDRESS
+	GSETTINGS_SCHEMA_DIR="${S}/data" Xemake check
+}
+
+src_install() {
+	local args=()
+	# manually set pyoverridesdir due to bug #524018 and AM_PATH_PYTHON limitations
+	use python && args+=( pyoverridesdir="$(python_get_sitedir)/gi/overrides" )
+
+	gnome2_src_install "${args[@]}"
+}
-- 
2.26.2