From b9e4b6ccb7e424d708f67be1512cdb3df88ebccf Mon Sep 17 00:00:00 2001
From: Michael Palimaka <kensington@gentoo.org>
Date: Sat, 6 Oct 2018 20:52:53 +1000
Subject: [PATCH] net-analyzer/testssl: use bundled openssl by default when
 enabled

Closes: https://bugs.gentoo.org/664084
Signed-off-by: Michael Palimaka <kensington@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11
---
 .../testssl/testssl-2.9.5_p5-r1.ebuild        | 60 +++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 net-analyzer/testssl/testssl-2.9.5_p5-r1.ebuild

diff --git a/net-analyzer/testssl/testssl-2.9.5_p5-r1.ebuild b/net-analyzer/testssl/testssl-2.9.5_p5-r1.ebuild
new file mode 100644
index 000000000000..41bdd598f1b3
--- /dev/null
+++ b/net-analyzer/testssl/testssl-2.9.5_p5-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="${PN}.sh"
+MY_PV="${PV/_p/-}"
+
+DESCRIPTION="Tool to check TLS/SSL cipher support"
+HOMEPAGE="https://testssl.sh/"
+SRC_URI="https://github.com/drwetter/${MY_PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 bundled-openssl? ( openssl )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bundled-openssl"
+
+RDEPEND="
+	app-shells/bash[net]
+	net-dns/bind-tools
+	sys-apps/util-linux
+	sys-libs/ncurses:0
+	sys-process/procps
+	!bundled-openssl? ( dev-libs/openssl:0 )
+"
+
+S=${WORKDIR}/${MY_PN}-${MY_PV}
+
+QA_PREBUILT="opt/${PN}/*"
+
+pkg_setup() {
+	use amd64 && BUNDLED_OPENSSL="openssl.Linux.x86_64"
+}
+
+src_prepare() {
+	default
+	sed -i ${PN}.sh \
+		-e 's|TESTSSL_INSTALL_DIR="${TESTSSL_INSTALL_DIR:-""}"|TESTSSL_INSTALL_DIR="/"|' \
+		-e 's|$TESTSSL_INSTALL_DIR/etc/|&testssl/|g' || die
+
+	if use bundled-openssl; then
+		sed -i ${PN}.sh \
+			-e "/find_openssl_binary()/a OPENSSL=\"/opt/${PN}/${BUNDLED_OPENSSL}\"" || die
+	fi
+}
+
+src_install() {
+	dodoc CHANGELOG.stable-releases.txt CREDITS.md Readme.md
+	dodoc openssl-rfc.mappping.html
+
+	dobin ${PN}.sh
+
+	insinto /etc/${PN}
+	doins etc/*
+
+	if use bundled-openssl; then
+		exeinto /opt/${PN}
+		use amd64 && doexe bin/${BUNDLED_OPENSSL}
+	fi
+}
-- 
2.26.2