From aec1e3e0ed417d2579ed24c51382efcd5e31bfc0 Mon Sep 17 00:00:00 2001
From: Mike Gilbert <floppym@gentoo.org>
Date: Wed, 29 Nov 2017 11:30:00 -0500
Subject: [PATCH] dev-python/wcsaxes: drop python3_6 from stable ebuild

---
 dev-python/wcsaxes/wcsaxes-0.9-r1.ebuild | 59 ++++++++++++++++++++++++
 dev-python/wcsaxes/wcsaxes-0.9.ebuild    |  2 +-
 2 files changed, 60 insertions(+), 1 deletion(-)
 create mode 100644 dev-python/wcsaxes/wcsaxes-0.9-r1.ebuild

diff --git a/dev-python/wcsaxes/wcsaxes-0.9-r1.ebuild b/dev-python/wcsaxes/wcsaxes-0.9-r1.ebuild
new file mode 100644
index 000000000000..73dbb6fafe0b
--- /dev/null
+++ b/dev-python/wcsaxes/wcsaxes-0.9-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Framework for plotting astronomical and geospatial data"
+HOMEPAGE="http://wcsaxes.readthedocs.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+	  dev-python/sphinx[${PYTHON_USEDEP}]
+	  dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.8-disable_mpltest.patch"
+)
+
+python_prepare_all() {
+	# use system astropy-helpers instead of bundled one
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	echo "backend: Agg" > "${WORKDIR}"/matplotlibrc || die
+	export MATPLOTLIBRC="${WORKDIR}"
+	xdg_environment_reset
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx --no-intersphinx
+	fi
+}
+
+python_test() {
+	virtx esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/wcsaxes/wcsaxes-0.9.ebuild b/dev-python/wcsaxes/wcsaxes-0.9.ebuild
index 898e26934a0d..8a811819eac3 100644
--- a/dev-python/wcsaxes/wcsaxes-0.9.ebuild
+++ b/dev-python/wcsaxes/wcsaxes-0.9.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
-PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
 
 inherit distutils-r1 virtualx xdg-utils
 
-- 
2.26.2