From a7626838bc7681c06e15a643db2cbdec7b74f058 Mon Sep 17 00:00:00 2001
From: Matthew Thode <prometheanfire@gentoo.org>
Date: Mon, 8 Apr 2019 22:28:40 -0500
Subject: [PATCH] dev-python/pyjwt: 1.7.1 bump

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>
---
 dev-python/pyjwt/Manifest           |  1 +
 dev-python/pyjwt/pyjwt-1.7.1.ebuild | 51 +++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+)
 create mode 100644 dev-python/pyjwt/pyjwt-1.7.1.ebuild

diff --git a/dev-python/pyjwt/Manifest b/dev-python/pyjwt/Manifest
index 9790ed399a7d..efcfa057cb80 100644
--- a/dev-python/pyjwt/Manifest
+++ b/dev-python/pyjwt/Manifest
@@ -1 +1,2 @@
 DIST PyJWT-1.5.3.tar.gz 73044 BLAKE2B ae2e3caec52ddd768d573e0398bbc355c6eedca238db9b1808ff1d723b9fdee0845cf119d78e561833fe770e5ec39000905cec43a5e96102865f60e204c72c22 SHA512 b25a9f6a04bd072020fcf00bb559b7560902adb79746fb880432c01fa356748238432f53f6b9a21db50ece3e59ed4c45ca3f48ecec0ca3c4095e6a739a5c150c
+DIST PyJWT-1.7.1.tar.gz 41979 BLAKE2B 5604b309838b2dfb2f95e18e291c43703954664aa8acb7439072f002c1c8a1e49ff2c21d907be77a4d2f86e695ec71970d550aad2541252ac85bd7133e300b28 SHA512 70cd38127b6848933992c8b88303725ef71bfb430ad42eb63247e549b0bdab2a194137349d43ab02a1c97212dbc89f447ee3f0c5403dd14632b8b4b6b9235fc4
diff --git a/dev-python/pyjwt/pyjwt-1.7.1.ebuild b/dev-python/pyjwt/pyjwt-1.7.1.ebuild
new file mode 100644
index 000000000000..d66b9c45e9f4
--- /dev/null
+++ b/dev-python/pyjwt/pyjwt-1.7.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} pypy )
+
+inherit distutils-r1 eutils
+
+MY_PN="PyJWT"
+
+DESCRIPTION="JSON Web Token implementation in Python"
+HOMEPAGE="https://github.com/progrium/pyjwt https://pypi.org/project/PyJWT/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test"
+
+RDEPEND=""
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/cryptography-1.4.0[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}"/${MY_PN}-${PV}
+
+python_prepare_all() {
+	find . -name '__pycache__' -prune -exec rm -rf {} \; || die "Cleaning __pycache__ failed"
+	find . -name '*.pyc' -exec rm -f {} \; || die "Cleaing *.pyc failed"
+
+	# enables coverage, we don't need that
+	rm setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	elog "Available optional features:"
+	optfeature "cryptography" dev-python/cryptography
+	optfeature "flake8" dev-python/flake8
+
+	ewarn "flake8 feature requires 'flake8-import-order' and 'pep8-naming', which are not in portage yet"
+}
-- 
2.26.2