From 9b978eedab0fcb5f8ee8e4abbe1824126c9e50a1 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Fri, 18 Oct 2019 14:18:34 +0200
Subject: [PATCH] net-misc/vconfig: Port to EAPI 7

Closes: https://bugs.gentoo.org/697222
Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: David Seifert <soap@gentoo.org>
---
 net-misc/vconfig/vconfig-1.9.ebuild | 38 ++++++++++++++++++++---------
 1 file changed, 26 insertions(+), 12 deletions(-)

diff --git a/net-misc/vconfig/vconfig-1.9.ebuild b/net-misc/vconfig/vconfig-1.9.ebuild
index 4671806983be..68ad081deeef 100644
--- a/net-misc/vconfig/vconfig-1.9.ebuild
+++ b/net-misc/vconfig/vconfig-1.9.ebuild
@@ -1,37 +1,51 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=0
+EAPI=7
 
-inherit eutils flag-o-matic toolchain-funcs
+inherit flag-o-matic toolchain-funcs
 
 MY_PN="vlan"
-S=${WORKDIR}/${MY_PN}
 
 DESCRIPTION="802.1Q vlan control utility"
 HOMEPAGE="http://www.candelatech.com/~greear/vlan.html"
 SRC_URI="http://www.candelatech.com/~greear/vlan/${MY_PN}.${PV}.tar.gz"
+
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~alpha amd64 ~arm hppa ~ppc ~ppc64 sparc x86"
 IUSE="static"
 
+S="${WORKDIR}/${MY_PN}"
+
+src_prepare() {
+	default
+	sed -e "s:/usr/local/bin/vconfig:/sbin/vconfig:g" -i vlan_test.pl || die
+	sed -e "s:/usr/local/bin/vconfig:/sbin/vconfig:g" -i vlan_test2.pl || die
+}
+
+src_configure() {
+	use static && append-ldflags -static
+}
+
 src_compile() {
-	use static && appened-ldflags -static
 	emake purge
-	emake CC="$(tc-getCC)" CCFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" STRIP="true" vconfig || die
+	emake \
+		CC="$(tc-getCC)" \
+		CCFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		STRIP="true" vconfig
 }
 
 src_install() {
 	into /
-	dosbin vconfig || die "dosbin error"
+	dosbin vconfig
 
-	sed -e "s:/usr/local/bin/vconfig:/sbin/vconfig:g" -i vlan_test.pl
-	sed -e "s:/usr/local/bin/vconfig:/sbin/vconfig:g" -i vlan_test2.pl
+	local HTML_DOCS=( {howto,vlan}.html )
+	einstalldocs
+	dodoc vlan_test*.pl
 
-	doman vconfig.8 || die "doman error"
-	dohtml howto.html vlan.html || die "dohtml error"
-	dodoc CHANGELOG README vlan_test*.pl || die "dodoc error"
+	doman vconfig.8
 }
 
 pkg_postinst() {
-- 
2.26.2