From 982b2532f76511911deb63fc4da117f2372bcfaa Mon Sep 17 00:00:00 2001
From: Tupone Alfredo <tupone@gentoo.org>
Date: Tue, 22 Oct 2019 08:30:42 +0200
Subject: [PATCH] dev-libs/antlr-c: EAPI 7

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>
---
 dev-libs/antlr-c/antlr-c-3.5.2-r1.ebuild | 63 ++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 dev-libs/antlr-c/antlr-c-3.5.2-r1.ebuild

diff --git a/dev-libs/antlr-c/antlr-c-3.5.2-r1.ebuild b/dev-libs/antlr-c/antlr-c-3.5.2-r1.ebuild
new file mode 100644
index 000000000000..743a7d4e90ab
--- /dev/null
+++ b/dev-libs/antlr-c/antlr-c-3.5.2-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit eutils autotools multilib-minimal
+
+MY_PN="${PN%-c}"
+DESCRIPTION="The ANTLR3 C Runtime"
+HOMEPAGE="http://www.antlr3.org/"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}3/archive/${PV}.tar.gz -> ${MY_PN}-${PV}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug debugger doc static-libs"
+
+DEPEND="doc? ( app-doc/doxygen[dot] )"
+RDEPEND=""
+
+S="${WORKDIR}/${MY_PN}3-${PV}/runtime/C"
+PATCHES=( "${FILESDIR}/3.5-cflags.patch" )
+MULTILIB_WRAPPED_HEADERS=( /usr/include/antlr3config.h )
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	default
+	sed -i '/^QUIET/s/NO/YES/' doxyfile || die
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local econfargs=(
+		--enable-shared
+		$(use_enable debug debuginfo)
+		$(use_enable debugger antlrdebug)
+		$(use_enable static-libs static)
+	)
+
+	case "${ABI}" in
+		*64*) econfargs+=( --enable-64bit ) ;;
+		*) econfargs+=( --disable-64bit ) ;;
+	esac
+
+	econf "${econfargs[@]}"
+}
+
+src_compile() {
+	multilib-minimal_src_compile
+
+	if use doc; then
+		einfo "Generating API documentation ..."
+		cd "${S}" || die
+		doxygen -u doxyfile || die
+		doxygen doxyfile || die
+	fi
+}
+
+src_install() {
+	use doc && HTML_DOCS=( "${S}/api/" )
+	multilib-minimal_src_install
+	find "${D}" -name '*.la' -delete || die
+}
-- 
2.26.2