From 8e8cc0754b0d67845c770ebf03a23027850f42d6 Mon Sep 17 00:00:00 2001
From: Julian Ospald <hasufell@gentoo.org>
Date: Sat, 3 Oct 2015 15:51:47 +0200
Subject: [PATCH] dev-libs/libevent: add libressl support

---
 dev-libs/libevent/libevent-2.1.5-r1.ebuild | 67 ++++++++++++++++++++++
 dev-libs/libevent/libevent-9999.ebuild     | 10 +++-
 2 files changed, 74 insertions(+), 3 deletions(-)
 create mode 100644 dev-libs/libevent/libevent-2.1.5-r1.ebuild

diff --git a/dev-libs/libevent/libevent-2.1.5-r1.ebuild b/dev-libs/libevent/libevent-2.1.5-r1.ebuild
new file mode 100644
index 000000000000..9602758bdcbd
--- /dev/null
+++ b/dev-libs/libevent/libevent-2.1.5-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils libtool multilib-minimal
+
+MY_P="${P}-beta"
+
+DESCRIPTION="A library to execute a function when a specific event occurs on a file descriptor"
+HOMEPAGE="http://libevent.org/"
+SRC_URI="mirror://sourceforge/levent/files/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug libressl +ssl static-libs test +threads"
+
+DEPEND="
+	ssl? (
+		!libressl? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
+		libressl? ( dev-libs/libressl[${MULTILIB_USEDEP}] )
+	)"
+RDEPEND="
+	${DEPEND}
+	!<=dev-libs/9libs-1.0
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/event2/event-config.h
+)
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	elibtoolize
+	# don't waste time building tests
+	# https://github.com/libevent/libevent/pull/144
+	sed -i -e '/^all:/s|tests||g' Makefile.nmake || die
+}
+
+multilib_src_configure() {
+	# fix out-of-source builds
+	mkdir -p test || die
+
+	ECONF_SOURCE="${S}" \
+	econf \
+		$(use_enable debug debug-mode) \
+		$(use_enable debug malloc-replacement) \
+		$(use_enable ssl openssl) \
+		$(use_enable static-libs static) \
+		$(use_enable threads thread-support)
+}
+
+src_test() {
+	# The test suite doesn't quite work (see bug #406801 for the latest
+	# installment in a riveting series of reports).
+	:
+	# emake -C test check | tee "${T}"/tests
+}
+
+DOCS=( ChangeLog{,-1.4,-2.0} )
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}
diff --git a/dev-libs/libevent/libevent-9999.ebuild b/dev-libs/libevent/libevent-9999.ebuild
index fc1817a6300c..179af26b421f 100644
--- a/dev-libs/libevent/libevent-9999.ebuild
+++ b/dev-libs/libevent/libevent-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -12,9 +12,13 @@ EGIT_REPO_URI="https://github.com/libevent/libevent"
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS=""
-IUSE="debug +ssl static-libs test +threads"
+IUSE="debug libressl +ssl static-libs test +threads"
 
-DEPEND="ssl? ( >=dev-libs/openssl-1.0.1h-r2[${MULTILIB_USEDEP}] )"
+DEPEND="
+	ssl? (
+		!libressl? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
+		libressl? ( dev-libs/libressl[${MULTILIB_USEDEP}] )
+	)"
 RDEPEND="
 	${DEPEND}
 	!<=dev-libs/9libs-1.0
-- 
2.26.2