From 8dc4fe90b31065dbf6ec7f4162f1f51125964a71 Mon Sep 17 00:00:00 2001
From: Brian Dolbec <dolsen@gentoo.org>
Date: Tue, 28 Apr 2020 11:35:54 -0700
Subject: [PATCH] dev-python/autobahn: Version bump, adds python 3.7, 3.8

metadata.xml: take maintainership

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Brian Dolbec <dolsen@gentoo.org>
---
 dev-python/autobahn/Manifest               |  1 +
 dev-python/autobahn/autobahn-20.4.3.ebuild | 84 ++++++++++++++++++++++
 dev-python/autobahn/metadata.xml           |  6 +-
 3 files changed, 90 insertions(+), 1 deletion(-)
 create mode 100644 dev-python/autobahn/autobahn-20.4.3.ebuild

diff --git a/dev-python/autobahn/Manifest b/dev-python/autobahn/Manifest
index 91e225aae218..a8a3e1c69b92 100644
--- a/dev-python/autobahn/Manifest
+++ b/dev-python/autobahn/Manifest
@@ -1,2 +1,3 @@
 DIST autobahn-17.5.1.tar.gz 205144 BLAKE2B a026381330d062059f23bd0fe20de12bf227fec45c816ce41a05d81951a2cb263e70ec3a5cee265ea3cc1f6910975903b493a767dce64c5bbb13be077561cabd SHA512 904f8f4c527a6c1c7840ea8634d0c0a47141458500c6d29f4aa1f05ff51f91c65a451b7c447201cbdf5e255c4c2d07509efa106790217b09398e7d50c1d85382
 DIST autobahn-18.3.1.tar.gz 213042 BLAKE2B 2f5eb92212f57d2301dbac1108a81cbbd339da4cb5527e3eb55f1ae7dcb951fed3cb7c643e76beaa0a83d623fe96f9eebcf7945e10efb0773e102d0234ebc479 SHA512 3d122cfb54eff0697cf60cd155a07699c6f6b39e573616c247ea79e65e6fa0a86d505ea8bc4f4755dbf266fb8bc7fadabb4338aeb1b9e6a2f0503e1b4d25e2e6
+DIST autobahn-20.4.3.tar.gz 938992 BLAKE2B 259d18f4aa46f7eaeac75811c1c193f3046aca5c5e37627d9ac62eeaa3dc944d05a8d87a558e241bdef56c799be4d89f65d4c8ee7c1a2be20f892896227eb5f9 SHA512 c34f29951b8f9ff5161851cf3a7e964de136f6091b0231a8e78e7fe74cb085077be5078cee352b2c27412d9aa4303de1eb85aa1890b4fb583575638a9c47c6fb
diff --git a/dev-python/autobahn/autobahn-20.4.3.ebuild b/dev-python/autobahn/autobahn-20.4.3.ebuild
new file mode 100644
index 000000000000..b9380e38dc98
--- /dev/null
+++ b/dev-python/autobahn/autobahn-20.4.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+MY_P=${PN}-$(ver_rs 3 -)
+
+DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
+HOMEPAGE="https://pypi.org/project/autobahn/
+	https://crossbar.io/autobahn/
+	https://github.com/crossbario/autobahn-python"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+IUSE="crypt test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/cbor-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/cbor2-5.1.0[${PYTHON_USEDEP}]
+	>=dev-python/flatbuffers-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/lz4-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/py-ubjson-0.8.4[${PYTHON_USEDEP}]
+	>=dev-python/snappy-0.5[${PYTHON_USEDEP}]
+	>=dev-python/twisted-20.3.0[${PYTHON_USEDEP}]
+	>=dev-python/txaio-20.3.1[${PYTHON_USEDEP}]
+	>=dev-python/ujson-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/wsaccel-0.6.2[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-3.6[${PYTHON_USEDEP}]
+	crypt? (
+		>=dev-python/pyopenssl-16.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+		>=dev-python/service_identity-18.1.0
+	)
+	"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}"/${MY_P}
+
+python_test() {
+	echo "Testing all, cryptosign using twisted"
+	export USE_TWISTED=true
+	cd "${BUILD_DIR}"/lib || die
+	"${EPYTHON}" -m twisted.trial autobahn || die
+	unset USE_TWISTED
+	echo "RE-testing cryptosign and component_aio using asyncio"
+	export USE_ASYNCIO=true
+	py.test -v autobahn/wamp/test/test_cryptosign.py || die
+	py.test -v autobahn/wamp/test/test_component_aio.py || die
+	unset USE_ASYNCIO
+	rm -r .pytest_cache || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# delete the dropin.cache so we don't have collisions
+	rm "${D}"/usr/lib*/python*/site-packages/twisted/plugins//dropin.cache || die
+}
+
+pkg_postinst() {
+	python_foreach_impl twisted-regen-cache || die
+}
+
+pkg_postrm() {
+	python_foreach_impl twisted-regen-cache || die
+}
diff --git a/dev-python/autobahn/metadata.xml b/dev-python/autobahn/metadata.xml
index e6c5346fc56b..6ea7ef02739b 100644
--- a/dev-python/autobahn/metadata.xml
+++ b/dev-python/autobahn/metadata.xml
@@ -1,8 +1,12 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-  <!-- maintainer-needed -->
+    <maintainer type="person">
+        <email>dolsen@gentoo.org</email>
+        <name>Brian Dolbec</name>
+    </maintainer>
   <upstream>
     <remote-id type="pypi">autobahn</remote-id>
+    <remote-id type="github">crossbar/autobahn</remote-id>
   </upstream>
 </pkgmetadata>
-- 
2.26.2