From 8566646eacc914b49881ddddd0678fdc54139d0c Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Fri, 22 Nov 2019 14:06:26 +0100
Subject: [PATCH] media-libs/phonon: Always build phononsettings

Package-Manager: Portage-2.3.79, Repoman-2.3.17
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 media-libs/phonon/phonon-4.11.1-r1.ebuild | 53 +++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 media-libs/phonon/phonon-4.11.1-r1.ebuild

diff --git a/media-libs/phonon/phonon-4.11.1-r1.ebuild b/media-libs/phonon/phonon-4.11.1-r1.ebuild
new file mode 100644
index 000000000000..56480c9276e1
--- /dev/null
+++ b/media-libs/phonon/phonon-4.11.1-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop ecm kde.org
+
+DESCRIPTION="KDE multimedia abstraction library"
+HOMEPAGE="https://phonon.kde.org/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/phonon/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="|| ( LGPL-2.1 LGPL-3 ) !pulseaudio? ( || ( GPL-2 GPL-3 ) )"
+SLOT="0"
+IUSE="debug designer gstreamer pulseaudio +vlc"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	designer? ( dev-qt/designer:5 )
+	pulseaudio? (
+		dev-libs/glib:2
+		media-sound/pulseaudio[glib]
+	)
+"
+RDEPEND="${DEPEND}"
+PDEPEND="
+	gstreamer? ( >=media-libs/phonon-gstreamer-4.9.60 )
+	vlc? ( >=media-libs/phonon-vlc-0.9.60 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DPHONON_BUILD_DESIGNER_PLUGIN=$(usex designer)
+		-DCMAKE_DISABLE_FIND_PACKAGE_GLIB2=$(usex !pulseaudio)
+		-DCMAKE_DISABLE_FIND_PACKAGE_PulseAudio=$(usex !pulseaudio)
+		-DPHONON_BUILD_SETTINGS=ON
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	make_desktop_entry "${PN}settings" \
+		"Phonon Audio and Video" preferences-desktop-sound
+}
-- 
2.26.2