From 82212b57163eedf88c588ec05e5981f4e7d6ac0f Mon Sep 17 00:00:00 2001
From: Daniel Pielmeier <billie@gentoo.org>
Date: Sun, 7 Oct 2018 17:18:25 +0200
Subject: [PATCH] app-portage/pfl: Revision bump to 3.0-r2. Switch to EAPI 7.

Signed-off-by: Daniel Pielmeier <billie@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11
---
 app-portage/pfl/pfl-3.0-r2.ebuild | 47 +++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 app-portage/pfl/pfl-3.0-r2.ebuild

diff --git a/app-portage/pfl/pfl-3.0-r2.ebuild b/app-portage/pfl/pfl-3.0-r2.ebuild
new file mode 100644
index 000000000000..c285466a6032
--- /dev/null
+++ b/app-portage/pfl/pfl-3.0-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_REQ_USE="xml"
+
+inherit distutils-r1
+
+DESCRIPTION="Searchable online file/package database for Gentoo"
+HOMEPAGE="http://www.portagefilelist.de"
+SRC_URI="http://files.portagefilelist.de/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="+network-cron"
+
+DEPEND=""
+RDEPEND="
+	${DEPEND}
+	net-misc/curl
+	|| (
+		sys-apps/portage[${PYTHON_USEDEP}]
+		sys-apps/portage-mgorny[${PYTHON_USEDEP}]
+	)
+	>=dev-python/ssl-fetch-0.4[${PYTHON_USEDEP}]
+"
+
+python_install_all() {
+	if use network-cron ; then
+		exeinto /etc/cron.weekly
+		doexe cron/pfl
+	fi
+
+	keepdir /var/lib/${PN}
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if [[ ! -e "${EROOT}/var/lib/${PN}/pfl.info" ]]; then
+		touch "${EROOT}/var/lib/${PN}/pfl.info" || die
+		chown -R 0:portage "${EROOT}/var/lib/${PN}" || die
+		chmod 775 "${EROOT}/var/lib/${PN}" || die
+	fi
+}
-- 
2.26.2