From 7e86ece96cd3b4d01e1cee9853f0ff1be4474332 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Thu, 12 Dec 2019 18:31:16 +0100
Subject: [PATCH] media-libs/memphis: Port to EAPI 7

Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: David Seifert <soap@gentoo.org>
---
 media-libs/memphis/memphis-0.2.3.ebuild | 45 +++++++++++++------------
 1 file changed, 23 insertions(+), 22 deletions(-)

diff --git a/media-libs/memphis/memphis-0.2.3.ebuild b/media-libs/memphis/memphis-0.2.3.ebuild
index 368aa1b04541..9063f96e9072 100644
--- a/media-libs/memphis/memphis-0.2.3.ebuild
+++ b/media-libs/memphis/memphis-0.2.3.ebuild
@@ -1,14 +1,11 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
+EAPI=7
 
 WANT_AUTOMAKE=1.11
 
-AUTOTOOLS_AUTORECONF=true
-VALA_MIN_API_VERSION=0.12
-
-inherit autotools-utils vala
+inherit autotools vala
 
 DESCRIPTION="A map-rendering application and a library for OpenStreetMap"
 HOMEPAGE="http://trac.openstreetmap.ch/trac/memphis/"
@@ -17,36 +14,40 @@ SRC_URI="http://wenner.ch/files/public/mirror/${PN}/${P}.tar.gz"
 LICENSE="LGPL-2.1"
 SLOT="0.2"
 KEYWORDS="alpha amd64 arm ia64 ppc ppc64 sparc x86"
-IUSE="debug doc +introspection vala static-libs"
+IUSE="debug doc +introspection vala"
 
 RDEPEND="
-	dev-libs/expat
+	dev-libs/expat:=
 	dev-libs/glib:2
-	x11-libs/cairo
+	x11-libs/cairo:=
 	introspection? ( dev-libs/gobject-introspection )"
-DEPEND="${RDEPEND}
+DEPEND="${RDEPEND}"
+BDEPEND="
 	doc? ( dev-util/gtk-doc )
 	vala? ( $(vala_depend) )"
 
-AUTOTOOLS_IN_SOURCE_BUILD=1
-
-DOCS=( AUTHORS ChangeLog NEWS README )
-
 PATCHES=( "${FILESDIR}"/${P}-link_gobject.patch )
 
 src_prepare() {
+	default
+	eautoreconf
+
 	unset VALAC
 	use vala && vala_src_prepare
-	autotools-utils_src_prepare
 }
 
 src_configure() {
-	local myeconfargs=(
-		$(use_enable debug)
-		$(use_enable doc gtk-doc)
-		$(use_enable introspection)
+	econf \
+		--disable-static \
+		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
+		$(use_enable introspection) \
 		$(use_enable vala)
-	)
-	CFLAGS="${CFLAGS}" \
-		autotools-utils_src_configure
+}
+
+src_install() {
+	default
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
 }
-- 
2.26.2