From 6ab5913d784750e9eeb2fe235f47d6bccf0b4667 Mon Sep 17 00:00:00 2001
From: Matthias Maier <tamiko@gentoo.org>
Date: Tue, 9 Jul 2019 15:35:36 -0500
Subject: [PATCH] media-sound/loudness-scanner: add version 0.5.1_p20190709

Package-Manager: Portage-2.3.68, Repoman-2.3.16
Signed-off-by: Matthias Maier <tamiko@gentoo.org>
---
 media-sound/loudness-scanner/Manifest         |  1 +
 .../loudness-scanner-0.5.1_p20190709.ebuild   | 74 +++++++++++++++++++
 2 files changed, 75 insertions(+)
 create mode 100644 media-sound/loudness-scanner/Manifest
 create mode 100644 media-sound/loudness-scanner/loudness-scanner-0.5.1_p20190709.ebuild

diff --git a/media-sound/loudness-scanner/Manifest b/media-sound/loudness-scanner/Manifest
new file mode 100644
index 000000000000..81baaa84e354
--- /dev/null
+++ b/media-sound/loudness-scanner/Manifest
@@ -0,0 +1 @@
+DIST loudness-scanner-0.5.1_p20190709.tar.xz 65360 BLAKE2B 122a14b1700e0b971d423bb3c6395eddd49663d8980ecc57dec85cbf45b67ef72b68203b15ac21b040af824b71641635bd72c67b40b0ba757ed536e121c7e3ae SHA512 2160a1dcba92efeb308f65e2dbd32405ad6c9b72355a4161f12579d767757e709c0ffe17df988105210cbb8f05f727f6b143cbe0540edeb8c7c6585b14998fe1
diff --git a/media-sound/loudness-scanner/loudness-scanner-0.5.1_p20190709.ebuild b/media-sound/loudness-scanner/loudness-scanner-0.5.1_p20190709.ebuild
new file mode 100644
index 000000000000..6570f3d70fc1
--- /dev/null
+++ b/media-sound/loudness-scanner/loudness-scanner-0.5.1_p20190709.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="Scans your music files and tags them with loudness information"
+HOMEPAGE="https://github.com/jiixyj/loudness-scanner/"
+SRC_URI="https://dev.gentoo.org/~tamiko/distfiles/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ffmpeg gtk mpg123 musepack qt5 sndfile"
+REQUIRED_USE="|| ( sndfile ffmpeg mpg123 musepack )"
+
+DEPEND="
+	dev-libs/glib
+	media-libs/libebur128
+	media-libs/taglib
+	ffmpeg? ( media-video/ffmpeg )
+	mpg123? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	sndfile? ( media-libs/libsndfile )
+	gtk? (
+		gnome-base/librsvg:2
+		x11-libs/cairo
+		x11-libs/gtk+:2
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+	)
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	cmake-utils_src_prepare
+	sed -i -e 's|".",|"'${EROOT}'/usr/'$(get_libdir)'/loudness-scanner",|g' \
+		"${S}"/scanner/inputaudio/input.c
+}
+
+src_configure() {
+	local -a mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_SHARED_LIBS:BOOL=OFF # use static internal libraries
+		-DDISABLE_FFMPEG:BOOL=$(usex ffmpeg no yes)
+		-DDISABLE_GSTREAMER:BOOL=ON # depends on obsolete gstreamer-0.10
+		-DDISABLE_GTK2:BOOL=$(usex gtk no yes)
+		-DDISABLE_MPCDEC:BOOL=$(usex musepack no yes)
+		-DDISABLE_MPG123:BOOL=$(usex mpg123 no yes)
+		-DDISABLE_QT4:BOOL=ON
+		-DDISABLE_QT5:BOOL=$(usex qt5 no yes)
+		-DDISABLE_RSVG2:BOOL=$(usex gtk no yes)
+		-DDISABLE_SNDFILE:BOOL=$(usex sndfile no yes)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}"/loudness
+	use gtk && dobin "${BUILD_DIR}"/loudness-drop-gtk
+	use qt5 && dobin "${BUILD_DIR}"/loudness-drop-qt5
+
+	insinto /usr/$(get_libdir)/loudness-scanner
+	doins "${BUILD_DIR}"/libinput_*.so
+
+	einstalldocs
+}
-- 
2.26.2