From 5a661b210f142ab1017d69a3c149583aa0277aea Mon Sep 17 00:00:00 2001
From: Justin Lecher <jlec@gentoo.org>
Date: Sun, 27 Sep 2015 16:56:26 +0200
Subject: [PATCH] net-im/gajim: Version Bump

Package-Manager: portage-2.2.22
Signed-off-by: Justin Lecher <jlec@gentoo.org>
---
 net-im/gajim/Manifest            |   1 +
 net-im/gajim/gajim-0.16.4.ebuild | 127 +++++++++++++++++++++++++++++++
 2 files changed, 128 insertions(+)
 create mode 100644 net-im/gajim/gajim-0.16.4.ebuild

diff --git a/net-im/gajim/Manifest b/net-im/gajim/Manifest
index 7f81a86208f8..a579898f86f1 100644
--- a/net-im/gajim/Manifest
+++ b/net-im/gajim/Manifest
@@ -1,2 +1,3 @@
 DIST gajim-0.16.3.tar.bz2 4596437 SHA256 a1c85879cb43f80a5a4ece91c5571012bb08c3878b28105db246599e1c4c4515 SHA512 815275c0abbc18ff7309a4142186952f4d46acedeb29c14ab90ab4e60935d427248eedcf6392cf6f197b24928763a58c0a52ccdfb112f28e9c9c727c3f3e45c9 WHIRLPOOL f6f7098ae5098d7f3ade834773002aa62a53d6e43a2c52d07cc1bad29e9b83741a616f1e50953063c060881f1d5a3e8cef87ea2ac0b0f667ee9b330bd995f827
+DIST gajim-0.16.4.tar.bz2 4593307 SHA256 2116ad3a5635c54b575ff53eed72fe4651fc50582f5094bfc6113d1cf0d1ce7f SHA512 e8c046aa711207d71080c83d4827400392354eaadb4b431a474fcd94d56bb0fac9f163606a6f7e8abd68c7509158f8e8101b0cc2ecb439443e2966deb707bfdb WHIRLPOOL c6a496f9c02fabbaf76b52e930e5d79f6fad2557e8b458654c538c82041b8ba65bb6f8d75f18438fbabb8aa0e52493494a5847833cc49b70444720b15d6d86a5
 DIST gajim-0.16.tar.bz2 4575445 SHA256 7abd8dfb22522d3a2f0345da2a86b99fb9917bfd97310124df8601fab82ca193 SHA512 af2fd6b750e3ffa5770913a93ac5e61e6dab5688a28a26484ba4a097d73cc38b820797b1fedc60a67bf94e9a641cc80264210d0c4cf997047068c6dcb056ca75 WHIRLPOOL 6d5374bcc574bf851f6dde184f52ef8ca517869b96a85a9598b4c37953c2bc7849ccfdb106d975da80a394555f7ed7486cf356dad06dc11f545d375745e983be
diff --git a/net-im/gajim/gajim-0.16.4.ebuild b/net-im/gajim/gajim-0.16.4.ebuild
new file mode 100644
index 000000000000..edf6fd6f7edc
--- /dev/null
+++ b/net-im/gajim/gajim-0.16.4.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite,xml"
+
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils python-r1 versionator
+
+MY_PV=${PV/_/-}
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="http://www.gajim.org/"
+SRC_URI="
+	http://www.gajim.org/downloads/$(get_version_component_range 1-2)/${MY_P}.tar.bz2"
+#	test? ( https://dev.gentoo.org/~jlec/distfiles/${PN}-tests-${PV}.tar.xz )"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="avahi crypt dbus gnome gnome-keyring kde idle jingle libnotify networkmanager nls spell +srv test X xhtml"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	libnotify? ( dbus )
+	avahi? ( dbus )
+	gnome? ( gnome-keyring )"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	dev-python/pygtk:2[${PYTHON_USEDEP}]
+	x11-libs/gtk+:2"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.1
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+	>=dev-python/python-nbxmpp-0.5.3[${PYTHON_USEDEP}]
+	crypt? (
+		app-crypt/gnupg
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+		)
+	dbus? (
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-libs/dbus-glib
+		libnotify? ( dev-python/notify-python[${PYTHON_USEDEP}] )
+		avahi? ( net-dns/avahi[dbus,gtk,python,${PYTHON_USEDEP}] )
+		)
+	gnome? (
+		dev-python/libgnome-python[${PYTHON_USEDEP}]
+		dev-python/egg-python[${PYTHON_USEDEP}]
+		)
+	gnome-keyring? ( dev-python/gnome-keyring-python[${PYTHON_USEDEP}] )
+	idle? ( x11-libs/libXScrnSaver )
+	jingle? ( net-libs/farstream:0.1[python,${PYTHON_USEDEP}] )
+	kde? ( kde-apps/kwalletmanager )
+	networkmanager? (
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+			net-misc/networkmanager
+		)
+	spell? ( app-text/gtkspell:2 )
+	srv? (
+		|| (
+			dev-python/libasyncns-python[${PYTHON_USEDEP}]
+			net-dns/bind-tools
+			)
+		)
+	xhtml? ( dev-python/docutils[${PYTHON_USEDEP}] )"
+
+RESTRICT="test"
+
+S="${WORKDIR}"/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.16-desktop.patch
+	)
+
+src_prepare() {
+	autotools-utils_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	configuration() {
+		local myeconfargs=(
+			$(use_enable nls)
+			$(use_with X x)
+			--docdir="/usr/share/doc/${PF}"
+			--libdir="$(python_get_sitedir)"
+			--enable-site-packages
+		)
+		run_in_build_dir autotools-utils_src_configure
+	}
+	python_foreach_impl configuration
+}
+
+src_compile() {
+	compilation() {
+		run_in_build_dir autotools-utils_src_compile
+	}
+	python_foreach_impl compilation
+}
+
+src_test() {
+	testing() {
+		run_in_build_dir ${PYTHON} test/runtests.py --verbose 3 || die
+	}
+	python_foreach_impl testing
+}
+
+src_install() {
+	installation() {
+		run_in_build_dir autotools-utils_src_install
+		python_optimize
+	}
+	python_foreach_impl installation
+
+	rm "${ED}/usr/share/doc/${PF}/README.html" || die
+	dohtml README.html
+}
-- 
2.26.2