From 5991a554575265092e4d5016d2081a83006d13c8 Mon Sep 17 00:00:00 2001
From: Matthew Thode <prometheanfire@gentoo.org>
Date: Sat, 26 Aug 2017 22:59:41 -0500
Subject: [PATCH] dev-python/pycadf: 2.6.0 bup2.6.0 bup

Package-Manager: Portage-2.3.6, Repoman-2.3.3
---
 dev-python/pycadf/Manifest            |  1 +
 dev-python/pycadf/pycadf-2.6.0.ebuild | 62 +++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 dev-python/pycadf/pycadf-2.6.0.ebuild

diff --git a/dev-python/pycadf/Manifest b/dev-python/pycadf/Manifest
index 32a0a51d055a..ffa875258146 100644
--- a/dev-python/pycadf/Manifest
+++ b/dev-python/pycadf/Manifest
@@ -1 +1,2 @@
 DIST pycadf-2.5.0.tar.gz 247779 SHA256 a5cbf899266ea25e62e927a31dbf13607f9ebfe1525b4ec95256afc42f43be70 SHA512 af3d7676e671ed702a84052589be7146406c2c53ebfb1ee5922bec93664fac461514c832ce9f225d52a9c6b08ec330e17c5763bee6eda7a931b5dc0af6e57ed5 WHIRLPOOL 75116d8b5d669132d33bdb9f4648c4ce276b25f41dd81e10efa1e0521a0fe7cd4dc3dd95f1786aaf84014534f30cf98544df3800bfe86062db4ed5f2adf944f9
+DIST pycadf-2.6.0.tar.gz 249411 SHA256 75b0e70f4c4fa46fef65671beb562c4bef1007541a38b5f724689209fcbf4b4e SHA512 a581b54a8dae088e015d639f14eb46b3c41bdbfdd55b671e79f34b7392af49e3e8dbb2fd85a43e5f8e010cbcdba1d9a330972b5cb6f7f2c5179c00b6f135b4ec WHIRLPOOL 374fcc4211c69a70c12571ca645c64e36d9ac30e3cbc26a527a533a545aff455724a9a0395464c1f71e1a327a5a46a22c7a43441c6882d789ff8b779fe193a66
diff --git a/dev-python/pycadf/pycadf-2.6.0.ebuild b/dev-python/pycadf/pycadf-2.6.0.ebuild
new file mode 100644
index 000000000000..56d40ee7e833
--- /dev/null
+++ b/dev-python/pycadf/pycadf-2.6.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_4 python3_5 )
+
+inherit distutils-r1
+
+DESCRIPTION="python implementation of DMTF Cloud Audit (CADF) data model"
+HOMEPAGE="https://pypi.python.org/pypi/pycadf"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND=">=dev-python/pbr-1.8.0[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/coverage-4.0[${PYTHON_USEDEP}]
+		!~dev-python/coverage-4.4[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testtools-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-sphinx-4.7.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.6.2[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/oslo-sphinx-4.7.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.4[${PYTHON_USEDEP}]
+	)"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/oslo-config-3.22.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && "${PYTHON}" setup.py build_sphinx
+}
+
+python_test() {
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+}
-- 
2.26.2