From 55ae3aadc8805c151eca047c662e0b56828299c4 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Thu, 9 Apr 2020 13:22:06 +0200
Subject: [PATCH] net-libs/libssh: Security bump to version 0.9.4

Bug: https://bugs.gentoo.org/716788
Package-Manager: Portage-2.3.97, Repoman-2.3.22
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 net-libs/libssh/Manifest            |   1 +
 net-libs/libssh/libssh-0.9.4.ebuild | 119 ++++++++++++++++++++++++++++
 2 files changed, 120 insertions(+)
 create mode 100644 net-libs/libssh/libssh-0.9.4.ebuild

diff --git a/net-libs/libssh/Manifest b/net-libs/libssh/Manifest
index 46c2c2c9b3f2..5c688658993d 100644
--- a/net-libs/libssh/Manifest
+++ b/net-libs/libssh/Manifest
@@ -1 +1,2 @@
 DIST libssh-0.9.3.tar.xz 500068 BLAKE2B 9532db5f0fd9a6f4167f57dc25a1131f7483aff2f0fa659d967b21a7eff8507843c09dae1fe8161c9b41aed1bb1dae6d619a35122812d3d9b4c71f78ff1817e2 SHA512 6e59718565daeca6d224426cc1095a112deff9af8e0b021917e04f08bb7409263c35724de95f591f38e26f0fb3bbbbc69b679b6775edc21dec158d241b076c6f
+DIST libssh-0.9.4.tar.xz 500776 BLAKE2B 56b21faac5d24f38c4fe695b31ec879ebab74f7cbfb8b8d336dee37766b7b0802ccac9b02726515ee29d44e18e832cfa322085d5669de1df94e5a428cf9add0f SHA512 38705c19c293ea5e6d286d22eb17021dbe58d88c1e647b699933aa0db9ca1174d43d1ff76c1a1b17bf2cc1a8297ec02f1a67dd9e969676dd69cf6fbdae9bc8d4
diff --git a/net-libs/libssh/libssh-0.9.4.ebuild b/net-libs/libssh/libssh-0.9.4.ebuild
new file mode 100644
index 000000000000..a57cb41c47e9
--- /dev/null
+++ b/net-libs/libssh/libssh-0.9.4.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib
+
+DESCRIPTION="Access a working SSH implementation by means of a library"
+HOMEPAGE="https://www.libssh.org/"
+
+if [[ "${PV}" == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.libssh.org/projects/libssh.git"
+else
+	SRC_URI="https://www.libssh.org/files/$(ver_cut 1-2)/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0/4" # subslot = soname major version
+IUSE="debug doc examples gcrypt gssapi libressl mbedtls pcap server +sftp static-libs test zlib"
+# Maintainer: check IUSE-defaults at DefineOptions.cmake
+
+REQUIRED_USE="?? ( gcrypt mbedtls )"
+
+BDEPEND="
+	doc? ( app-doc/doxygen[dot] )
+"
+RDEPEND="
+	!gcrypt? (
+		!mbedtls? (
+			!libressl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
+			libressl? ( dev-libs/libressl:=[${MULTILIB_USEDEP}] )
+		)
+	)
+	gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
+	gssapi? ( >=virtual/krb5-0-r1[${MULTILIB_USEDEP}] )
+	mbedtls? ( net-libs/mbedtls[${MULTILIB_USEDEP}] )
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-util/cmocka-0.3.1[${MULTILIB_USEDEP}] )
+"
+
+DOCS=( AUTHORS README ChangeLog )
+
+PATCHES=( "${FILESDIR}/${PN}-0.8.0-tests.patch" )
+
+RESTRICT+=" !test? ( test )"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# just install the examples, do not compile them
+	cmake_comment_add_subdirectory examples
+
+	# keyfile torture test is currently broken
+	sed -e "/torture_keyfiles/d" \
+		-i tests/unittests/CMakeLists.txt || die
+
+	# disable tests that take too long (bug #677006)
+	if use sparc; then
+		sed -e "/torture_threads_pki_rsa/d" -e "/torture_pki_dsa/d" \
+			-i tests/unittests/CMakeLists.txt || die
+	fi
+
+	sed -e "/^check_include_file.*HAVE_VALGRIND_VALGRIND_H/s/^/#DONT /" \
+		-i ConfigureChecks.cmake || die
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DWITH_NACL=OFF
+		-DWITH_STACK_PROTECTOR=OFF
+		-DWITH_STACK_PROTECTOR_STRONG=OFF
+		-DWITH_DEBUG_CALLTRACE="$(usex debug)"
+		-DWITH_DEBUG_CRYPTO="$(usex debug)"
+		-DWITH_GCRYPT="$(usex gcrypt)"
+		-DWITH_GSSAPI="$(usex gssapi)"
+		-DWITH_MBEDTLS="$(usex mbedtls)"
+		-DWITH_PCAP="$(usex pcap)"
+		-DWITH_SERVER="$(usex server)"
+		-DWITH_SFTP="$(usex sftp)"
+		-DBUILD_STATIC_LIB="$(usex static-libs)"
+		-DUNIT_TESTING="$(usex test)"
+		-DWITH_ZLIB="$(usex zlib)"
+	)
+
+	multilib_is_native_abi || mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON )
+
+	cmake_src_configure
+}
+
+multilib_src_compile() {
+	cmake_src_compile
+	multilib_is_native_abi && use doc && cmake_src_compile docs
+}
+
+multilib_src_install() {
+	cmake_src_install
+	multilib_is_native_abi && use doc && HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
+
+	use static-libs && dolib.a src/libssh.a
+
+	# compatibility symlink until all consumers have been updated
+	# to no longer use libssh_threads.so
+	dosym libssh.so /usr/$(get_libdir)/libssh_threads.so
+}
+
+multilib_src_install_all() {
+	use mbedtls && DOCS+=( README.mbedtls )
+	einstalldocs
+
+	if use examples; then
+		docinto examples
+		dodoc examples/*.{c,h,cpp}
+	fi
+}
-- 
2.26.2