From 54792cd74a1ed9d50c6c335829ee3a6015e17f5f Mon Sep 17 00:00:00 2001
From: Mikle Kolyada <zlogene@gentoo.org>
Date: Thu, 16 Aug 2018 01:00:00 +0300
Subject: [PATCH] net-libs/libtorrent-rasterbar: Version bump (v1.1.9)

- EAPI=7
- Drop versionator
- fix debug logging logic (falls without explicit options)

Package-Manager: Portage-2.3.40, Repoman-2.3.9
---
 net-libs/libtorrent-rasterbar/Manifest        |   1 +
 .../libtorrent-rasterbar-1.1.9.ebuild         | 104 ++++++++++++++++++
 2 files changed, 105 insertions(+)
 create mode 100644 net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.1.9.ebuild

diff --git a/net-libs/libtorrent-rasterbar/Manifest b/net-libs/libtorrent-rasterbar/Manifest
index 3aca11909d45..975eee483f7f 100644
--- a/net-libs/libtorrent-rasterbar/Manifest
+++ b/net-libs/libtorrent-rasterbar/Manifest
@@ -1,2 +1,3 @@
 DIST libtorrent-rasterbar-1.1.5.tar.gz 3942894 BLAKE2B 0a1102e1b74049c1f5d8980363a6b92a3378339349609d64d3b7a38a58baf6c2898a26f70e92b0de0d6a1f4b6725a576a850aacaa5764fe7d96fa0b541dfa2d7 SHA512 d0e7fe944c8a396aaf79ce80c7513be07a855bc8a9eee3bca46ed83d5e190aaa5ea4dc9a8a7208e27e18ae8f15733e6e34eabd375f0bde43d4dc4607840782e7
 DIST libtorrent-rasterbar-1.1.7.tar.gz 3951887 BLAKE2B 4729a718f5ce5bf2a41506f18f48bc588ad863ea8e640dde6f9e0a35bb909ff651fca3c8729668b25507fa3928218be579964c683d9d6bf3dc1c3abcce0f9452 SHA512 e35e95eec55a69b81c1d21f73e230dc4de7502b5adce99193c01b0d89a04b0f484788ff235d3f73cc77eeccba8d8d441fac92aa76a17afb56bafabd318b4a75e
+DIST libtorrent-rasterbar-1.1.9.tar.gz 3903742 BLAKE2B a9f942e7d06e076dec98314bc44e8633731c51e8469095ebff8c9c8084305714ca40663a0d963f16188ba17fa640f273eaa1396784514bc04e4bc4cbcdc3aab2 SHA512 2dcf81fdf34b81790012a6c20dc344dccb89535359cffeb9a2725763f0a1842a00af1ae06b63e4e32054f06ceb14e32031afe479dc36897ddab28494241eb756
diff --git a/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.1.9.ebuild b/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.1.9.ebuild
new file mode 100644
index 000000000000..f9f8a919d1d5
--- /dev/null
+++ b/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.1.9.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_REQ_USE="threads"
+DISTUTILS_OPTIONAL=true
+DISTUTILS_IN_SOURCE_BUILD=true
+
+inherit distutils-r1 flag-o-matic
+
+MY_PV=$(ver_rs 1-2 '_')
+
+DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
+HOMEPAGE="http://libtorrent.org"
+SRC_URI="https://github.com/arvidn/libtorrent/releases/download/libtorrent-${MY_PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/9"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="debug +dht doc examples libressl python +ssl static-libs test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	dev-libs/boost:=[threads]
+	virtual/libiconv
+	examples? ( !net-p2p/mldonkey )
+	python? (
+		${PYTHON_DEPS}
+		dev-libs/boost:=[python,${PYTHON_USEDEP}]
+	)
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+"
+
+src_prepare() {
+	default
+
+	# bug 578026
+	# prepend -L${S}/... to ensure bindings link against the lib we just built
+	sed -i -e "s|^|-L${S}/src/.libs |" bindings/python/link_flags.in || die
+
+	# prepend -I${S}/... to ensure bindings use the right headers
+	sed -i -e "s|^|-I${S}/src/include |" bindings/python/compile_flags.in || die
+
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	append-cxxflags -std=c++11 # bug 634506
+
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable debug logging)
+		$(use_enable debug disk-stats)
+		$(use_enable dht dht $(usex debug logging $(usex ('yes' 'no'))))
+		$(use_enable examples)
+		$(use_enable ssl encryption)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+		--with-libiconv
+	)
+	econf "${myeconfargs[@]}"
+
+	if use python; then
+		python_configure() {
+			econf "${myeconfargs[@]}" \
+				--enable-python-binding \
+				--with-boost-python="${EPYTHON#python}"
+		}
+		distutils-r1_src_configure
+	fi
+}
+
+src_compile() {
+	default
+
+	python_compile() {
+		cd "${BUILD_DIR}/../bindings/python" || die
+		distutils-r1_python_compile
+	}
+	use python && distutils-r1_src_compile
+}
+
+src_install() {
+	use doc && HTML_DOCS+=( "${S}"/docs )
+
+	default
+
+	python_install() {
+		cd "${BUILD_DIR}/../bindings/python" || die
+		distutils-r1_python_install
+	}
+	use python && distutils-r1_src_install
+
+	find "${D}" -name '*.la' -delete || die
+}
-- 
2.26.2