From 4f69365c21c009d6937caf8aed92cb8aeccb2af7 Mon Sep 17 00:00:00 2001
From: 0xd34df00d <0xd34df00d@gmail.com>
Date: Sun, 27 Oct 2019 22:23:39 -0400
Subject: [PATCH] net-libs/qxmpp: bump to 1.2.0

Closes: https://bugs.gentoo.org/698704
Signed-off-by: Georg Rudoy <0xd34df00d@gmail.com>
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Closes: https://github.com/gentoo/gentoo/pull/13474
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 net-libs/qxmpp/Manifest           |  1 +
 net-libs/qxmpp/qxmpp-1.2.0.ebuild | 59 +++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)
 create mode 100644 net-libs/qxmpp/qxmpp-1.2.0.ebuild

diff --git a/net-libs/qxmpp/Manifest b/net-libs/qxmpp/Manifest
index 5fd90d72a762..73d8da7a9bd0 100644
--- a/net-libs/qxmpp/Manifest
+++ b/net-libs/qxmpp/Manifest
@@ -1,2 +1,3 @@
 DIST qxmpp-0.9.3.tar.gz 300764 BLAKE2B a98d9bd9ab9c84ce6ac90722cd1f1b1609d345daa0b4e690e44b845408753b006261b293898bf419bea011005558584de24090ac1c8809845ec6f8a5c8bb05b1 SHA512 c6ada4398468b9ce84955ab3a1ca155afe3098dfe39dc952c3675be1a1e3a4f118f8b1e251567bc124faa645d2654252d3e32d94e21aae79547056a10a2d6a71
 DIST qxmpp-1.0.1.tar.gz 259791 BLAKE2B 3687dd8f74db8a995bc37850f6988b1750219b2f683281d26990a430046cd1d7f1957c19604540a56c3110aa5b9a40d037388f9726f684a56a0d15c7de6a4849 SHA512 b6fb5fc0e3edfd978ac47b3ce32d8d0892678247479ba3e30beba3a7e67da1eb053bb95de07306920cf6ca5e744c12fd31f1a72612c5ee5b724a3eac7b8d6c6e
+DIST qxmpp-1.2.0.tar.gz 310801 BLAKE2B a3d1c708fe33e6ecd226e867fc030c6cddb5009c90db46544a0081e1198f69b609239304f56aec00c7b399e7f74fa9bed82eb38db3439e092719a7a68b440a14 SHA512 9b9541dd2ffc689877969bdd1063e7ab21761e5feb7bf911acba3b0a0d953199b8bc08a1ad8c2031b0e135af7a127cbbc108bb3e8dbf1b7712ab8dc8f4cbd371
diff --git a/net-libs/qxmpp/qxmpp-1.2.0.ebuild b/net-libs/qxmpp/qxmpp-1.2.0.ebuild
new file mode 100644
index 000000000000..c9a44c3c89f1
--- /dev/null
+++ b/net-libs/qxmpp/qxmpp-1.2.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="A cross-platform C++ XMPP client library based on the Qt framework"
+HOMEPAGE="https://github.com/qxmpp-project/qxmpp/"
+SRC_URI="https://github.com/${PN}-project/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc opus +speex test theora vpx"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtxml:5
+	opus? ( media-libs/opus )
+	speex? ( media-libs/speex )
+	theora? ( media-libs/libtheora )
+	vpx? ( media-libs/libvpx:= )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	# requires network connection, bug #623708
+	sed \
+		-e "/qxmppiceconnection/d" \
+		-e "/qxmppserver/d" \
+		-e "/qxmpptransfermanager/d" \
+		-i tests/CMakeLists.txt \
+		|| die "failed to drop certain network tests"
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_INTERNAL_TESTS=$(usex test)
+		-DWITH_OPUS=$(usex opus)
+		-DWITH_SPEEX=$(usex speex)
+		-DWITH_THEORA=$(usex theora)
+		-DWITH_VPX=$(usex vpx)
+	)
+
+	cmake_src_configure
+}
-- 
2.26.2