From 4d0b6d76f1ea04171f00b7854ded56bebc95c3a1 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Thu, 20 Apr 2017 15:03:09 +0300
Subject: [PATCH] dev-libs/libgdata: bump to 0.17.8, should fix google
 calendars/task sync

---
 dev-libs/libgdata/Manifest               |  1 +
 dev-libs/libgdata/libgdata-0.17.8.ebuild | 62 ++++++++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 dev-libs/libgdata/libgdata-0.17.8.ebuild

diff --git a/dev-libs/libgdata/Manifest b/dev-libs/libgdata/Manifest
index ca06ba6fde18..9aa58d6fa85a 100644
--- a/dev-libs/libgdata/Manifest
+++ b/dev-libs/libgdata/Manifest
@@ -1,2 +1,3 @@
 DIST libgdata-0.17.6.tar.xz 1526804 SHA256 8b6a3ff1db23bd9e5ebbcc958b29b769a898f892eed4798222d562ba69df30b0 SHA512 940e5155b0cda0604e09efcdeabbfcb54ebe97b40d1086823802d3a49fdb7fcfc97749ae218c15d30e4981d01e34d1ae3bed01c1ee9a283063761527a9405731 WHIRLPOOL d3d36ae14e2e6502a42766f3efd75001d50c8376cfe4c3e3addbbe30e2455323f399f813eb18d78f88a83353507f01fe0d8e312e8f05dc6bf2d28a38e5ba73f0
 DIST libgdata-0.17.7.tar.xz 1448528 SHA256 8a663ef314a6d20b73c762072e0c1353fa7ec1ca3c2dee6fb85927cbda0d44fd SHA512 92ded8480262f59b6b2f8271fbb77b9b75905ca53f80a24bcf239fd06ead219ffa8af4b576b38368297c1a4f49722b3960202b8ea2b03011781d5fdfa77bbfd6 WHIRLPOOL 73ca7fad7c444f9bd8fe0e31082f79c99bf7091aa142071df70384fdc48649b15ff1b4d772dafdcdc1ec702cda2ad49cec3a67c4e80a56cd0a11ea05aff3cea7
+DIST libgdata-0.17.8.tar.xz 1464812 SHA256 e5e735bfac219c6cbe4a14df481cb3cb4b1c4b8b5e70f9a105a884035bc3a161 SHA512 dfc4c825a7053a6fd7659d04c7077bed8539b4cf3ef3da1d5ece4da3ce17941900e960a300a50b284010ed890dcab87e4c4726403f04481c672832fd34b975b0 WHIRLPOOL e0772008cdf0816efe118f69f9bcc86d85de2a26fc2fd5127bcdb942af264536764da130ccb194a01f0bb97ad9bb070eec84c659e9e82b64a4f7eeb6b0602797
diff --git a/dev-libs/libgdata/libgdata-0.17.8.ebuild b/dev-libs/libgdata/libgdata-0.17.8.ebuild
new file mode 100644
index 000000000000..461d36db68b1
--- /dev/null
+++ b/dev-libs/libgdata/libgdata-0.17.8.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
+HOMEPAGE="https://wiki.gnome.org/Projects/libgdata"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/22" # subslot = libgdata soname version
+
+IUSE="+crypt gnome-online-accounts +introspection static-libs test vala"
+REQUIRED_USE="
+	gnome-online-accounts? ( crypt )
+	vala? ( introspection )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# configure checks for gtk:3, but only uses it for demos which are not installed
+RDEPEND="
+	>=dev-libs/glib-2.38.0:2
+	>=dev-libs/json-glib-0.15
+	>=dev-libs/libxml2-2:2
+	>=net-libs/liboauth-0.9.4
+	>=net-libs/libsoup-2.55.90:2.4[introspection?]
+	>=x11-libs/gdk-pixbuf-2.14:2
+	crypt? ( app-crypt/gcr:= )
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.25
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	test? ( >=net-libs/uhttpmock-0.5 )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable crypt gnome) \
+		$(use_enable gnome-online-accounts goa) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(use_enable static-libs static) \
+		$(use_enable test always-build-tests)
+}
+
+src_test() {
+	unset ORBIT_SOCKETDIR
+	export GSETTINGS_BACKEND="memory" #486412
+	dbus-launch emake check
+}
-- 
2.26.2