From 49cbf780a78005f824e8223c73e0594189a43d86 Mon Sep 17 00:00:00 2001
From: Alexey Shvetsov <alexxy@gentoo.org>
Date: Tue, 11 Feb 2020 12:37:45 +0300
Subject: [PATCH] dev-python/flask-babel: Version bump

Package-Manager: Portage-2.3.86, Repoman-2.3.20
Signed-off-by: Alexey Shvetsov <alexxy@gentoo.org>
---
 dev-python/flask-babel/Manifest               |  1 +
 .../flask-babel/flask-babel-0.12.2.ebuild     | 56 +++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 dev-python/flask-babel/flask-babel-0.12.2.ebuild

diff --git a/dev-python/flask-babel/Manifest b/dev-python/flask-babel/Manifest
index b88ecc2eb8cf..977c1199e85a 100644
--- a/dev-python/flask-babel/Manifest
+++ b/dev-python/flask-babel/Manifest
@@ -1 +1,2 @@
 DIST Flask-Babel-0.11.2.tar.gz 41105 BLAKE2B 88cd5f2f72c7533f173a3fef7acdcd9ee882b06111f112da18075ce007f94cb342acd16f35da138ca0548b5bd0fd8070d4b3b7941a136e5490c3b45d1351d239 SHA512 d95947983ff5bc33a28384f000512e85ed64c16555aa03e110a32b7c0c9e91eebc02259bfc69a0dbc84adb6ecf8155cffaecde5726658d64d36435060de3f22b
+DIST Flask-Babel-0.12.2.tar.gz 44567 BLAKE2B a164dd527595412c451ee7bd772c8579f76d0202df3e1cb4c4952dab4aa4225001f5fa35938e72892a6452da1a9b70b2fd661249b2f37953fe3963046631d384 SHA512 c43bf5cf6c66e3a8a52298f52bd6300cf0b0c53a1f0fb5862b1bcf8a9800ea0e043c9f85125bb9eb5c281a3c0583c63f0f9653792204883a6f82080547b37104
diff --git a/dev-python/flask-babel/flask-babel-0.12.2.ebuild b/dev-python/flask-babel/flask-babel-0.12.2.ebuild
new file mode 100644
index 000000000000..775d2c7f5a4b
--- /dev/null
+++ b/dev-python/flask-babel/flask-babel-0.12.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python2_7 python3_{6,7,8} )
+inherit distutils-r1
+
+MY_PN="Flask-Babel"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="i18n and l10n support for Flask based on Babel and pytz"
+HOMEPAGE="https://pythonhosted.org/Flask-Babel/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/flask-sphinx-themes[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	sed -i -e "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	nosetests -v || die "Tests failed under ${EPYTHON}"
+}
-- 
2.26.2