From 483e759909341ab0c649c23befa59d4892bed1be Mon Sep 17 00:00:00 2001
From: Julian Ospald <hasufell@gentoo.org>
Date: Wed, 30 Sep 2015 13:29:17 +0200
Subject: [PATCH] net-libs/libesmtp: add libressl support

---
 net-libs/libesmtp/libesmtp-1.0.6-r2.ebuild | 44 ++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 net-libs/libesmtp/libesmtp-1.0.6-r2.ebuild

diff --git a/net-libs/libesmtp/libesmtp-1.0.6-r2.ebuild b/net-libs/libesmtp/libesmtp-1.0.6-r2.ebuild
new file mode 100644
index 000000000000..4c0472e5b53a
--- /dev/null
+++ b/net-libs/libesmtp/libesmtp-1.0.6-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit libtool
+
+DESCRIPTION="lib that implements the client side of the SMTP protocol"
+HOMEPAGE="http://www.stafford.uklinux.net/libesmtp/"
+SRC_URI="http://www.stafford.uklinux.net/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1 GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-macos"
+IUSE="debug libressl ntlm ssl static-libs threads"
+
+RDEPEND="
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable static-libs static) \
+		--enable-all \
+		$(use_enable ntlm) \
+		$(use_enable threads pthreads) \
+		$(use_enable debug) \
+		$(use_with ssl openssl)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog NEWS Notes README TODO
+	insinto /usr/share/doc/${PF}/xml
+	doins doc/api.xml
+}
-- 
2.26.2