From 4789c8635f3e5ba594a5d810bf3f7a527e5f69f9 Mon Sep 17 00:00:00 2001
From: Thomas Deutschmann <whissi@gentoo.org>
Date: Fri, 22 Sep 2017 23:24:17 +0200
Subject: [PATCH] sys-process/acct: Rename logrotate script (bug #542906)

sys-process/atop checks for "/etc/logrotate.d/psacct" but we named
the script just "acct".

Package-Manager: Portage-2.3.8, Repoman-2.3.3
---
 sys-process/acct/acct-6.6.4-r1.ebuild | 44 +++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 sys-process/acct/acct-6.6.4-r1.ebuild

diff --git a/sys-process/acct/acct-6.6.4-r1.ebuild b/sys-process/acct/acct-6.6.4-r1.ebuild
new file mode 100644
index 000000000000..efc32e5b78de
--- /dev/null
+++ b/sys-process/acct/acct-6.6.4-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools systemd
+
+DESCRIPTION="GNU system accounting utilities"
+HOMEPAGE="https://savannah.gnu.org/projects/acct/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.6.4-cross-compile.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf --enable-linux-multiformat
+}
+
+src_install() {
+	default
+	keepdir /var/account
+	newinitd "${FILESDIR}"/acct.initd-r2 acct
+	newconfd "${FILESDIR}"/acct.confd-r1 acct
+	systemd_dounit "${FILESDIR}"/acct.service
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/acct.logrotate-r1 psacct
+
+	# sys-apps/sysvinit already provides this
+	rm "${ED}"/usr/bin/last "${ED}"/usr/share/man/man1/last.1 || die
+
+	# accton in / is only a temp workaround for #239748
+	dodir /sbin
+	mv "${ED}"/usr/sbin/accton "${ED}"/sbin/ || die
+}
-- 
2.26.2