From 3b522ecb7c9890373b69c816de567e0296842c76 Mon Sep 17 00:00:00 2001
From: Tim Harder <radhermit@gentoo.org>
Date: Fri, 23 Mar 2018 18:46:33 -0400
Subject: [PATCH] dev-python/pycairo: drop xcb use flag and related deps

Closes: https://bugs.gentoo.org/649926
---
 dev-python/pycairo/pycairo-1.16.3-r1.ebuild | 53 +++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-python/pycairo/pycairo-1.16.3-r1.ebuild

diff --git a/dev-python/pycairo/pycairo-1.16.3-r1.ebuild b/dev-python/pycairo/pycairo-1.16.3-r1.ebuild
new file mode 100644
index 000000000000..01ca0c905906
--- /dev/null
+++ b/dev-python/pycairo/pycairo-1.16.3-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="https://www.cairographics.org/pycairo/ https://github.com/pygobject/pycairo"
+SRC_URI="https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=x11-libs/cairo-1.13.1[svg]
+"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx )
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Fix pkgconfig path
+	sed -i -e "/libdir =/s:\"lib\":\"$(get_libdir)\":" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/. )
+
+	if use examples; then
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}
-- 
2.26.2