From 34a7529338bb3463fff8bf846c74e29cdff3e68a Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Wed, 25 Dec 2019 12:37:17 +0100
Subject: [PATCH] net-misc/youtube-dl: Version 2019.12.25

Package-Manager: Portage-2.3.83, Repoman-2.3.20
Closes: https://bugs.gentoo.org/703168
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 net-misc/youtube-dl/Manifest                  |  1 +
 .../youtube-dl/youtube-dl-2019.12.25.ebuild   | 77 +++++++++++++++++++
 2 files changed, 78 insertions(+)
 create mode 100644 net-misc/youtube-dl/youtube-dl-2019.12.25.ebuild

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index a1c1aae54715..ccb74312e4e6 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2019.11.28.tar.gz 3148365 BLAKE2B 4fd02a5f134f9efce133273539303de6700f02414a216085f444ee68751b94affc092a2960920660e29345848ae924b022d1e9e436827cfeb93bf94f1eed0517 SHA512 fd3fc9658428ecf96d681dd699db49e02f94343e5c49e370cb68a5764e8ecebc14b3ce5bc44db0a829b0d3c4fbffc96a1f8288fb24cbd21add6e9c7852b0915d
+DIST youtube-dl-2019.12.25.tar.gz 3153090 BLAKE2B c86aa3f905c2cea84b6083cba215e6404d8dc25689290aaac6a642d5da61df162609d52bcf578b6463cd1898b282a15245efc8a3cc36f26f163170427c3174cb SHA512 951219648597d5e19fd3bcb3c64d8641bffd63cf3c6b4b30332d9148ad8b12c1be252e4cacbcd8169ce502b0fe20b2ff7163620382769b5e83e82d155e4f38c8
diff --git a/net-misc/youtube-dl/youtube-dl-2019.12.25.ebuild b/net-misc/youtube-dl/youtube-dl-2019.12.25.ebuild
new file mode 100644
index 000000000000..1aa88fc9ca52
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2019.12.25.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python{2_7,3_{5,6,7,8}})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+SLOT="0"
+IUSE="test"
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	|| (
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+	)
+"
+S=${WORKDIR}/${PN}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake offlinetest
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}
-- 
2.26.2